Шифрование / дешифрование XML в отдельных файлах - PullRequest
Новая
       11

Шифрование / дешифрование XML в отдельных файлах

1 голос
/ 27 апреля 2011

Мне нужно зашифровать файл XML, отправить его в другое место и расшифровать его там. Как видно из приведенных ниже кодов, я использую тот же ключ, но он не будет работать (сейчас я просто использую два локальных файла).

Я получаю следующую ошибку:

Заполнение недопустимо и не может быть удалено.

в этой строке в Decrypt.aspx: Dim xReader As XmlTextReader

Я думаю, что это может быть на фактической стадии шифрования, вызывающей ошибки, например, файл не сохраняется правильно.

Encrypt.aspx 

 Dim rijnAlg As RijndaelManaged
 rijnAlg = RijndaelManaged.Create()

 rijnAlg.Key = {118, 123, 23, 17, 161, 152, 35, 68, 126, 213, 16, 115, 68, 217, 58, 108, 56, 218, 5, 78, 28, 128, 113, 208, 61, 56, 10, 87, 187, 162, 233, 38}
 rijnAlg.IV = {33, 241, 14, 16, 103, 18, 14, 248, 4, 54, 18, 5, 60, 76, 16, 191}
 Dim encryptor As ICryptoTransform
 encryptor = rijnAlg.CreateEncryptor(rijnAlg.Key, rijnAlg.IV)

 Dim wStream As FileStream
 wStream = File.Open("C:\test.xml", FileMode.Create)

 Dim cStream As CryptoStream
 cStream = New CryptoStream(wStream, encryptor, CryptoStreamMode.Write)

 Dim sWriter As StreamWriter
 sWriter = New StreamWriter(cStream)

 XMLDoc.Save(sWriter)

 'Clear memory'
 wStream.Flush()
 wStream.Close()

Decrypt.aspx 

 Dim rijnAlg As RijndaelManaged
 rijnAlg = RijndaelManaged.Create()

 rijnAlg.Key = {118, 123, 23, 17, 161, 152, 35, 68, 126, 213, 16, 115, 68, 217, 58, 108, 56, 218, 5, 78, 28, 128, 113, 208, 61, 56, 10, 87, 187, 162, 233, 38}
 rijnAlg.IV = {33, 241, 14, 16, 103, 18, 14, 248, 4, 54, 18, 5, 60, 76, 16, 191}
 Dim decryptor As ICryptoTransform
 decryptor = rijnAlg.CreateDecryptor(rijnAlg.Key, rijnAlg.IV)

 Response.Write(rijnAlg.Key)
 Response.Write(rijnAlg.IV)

 Dim rStream As FileStream
 rStream = File.OpenRead("C:\test.xml")

 Dim cStream As CryptoStream
 cStream = New CryptoStream(rStream, decryptor, CryptoStreamMode.Read)

 Dim xReader As XmlTextReader
 xReader = New XmlTextReader(cStream)

 Dim xDoc As XDocument
 xDoc = XDocument.Load(xReader)

 xDoc.Save("C:\test.xml")

И ради интереса, вот код создания XML, который я использую: 

Dim XMLDoc As XDocument
    XMLDoc = New XDocument(
        New XDeclaration("1.0", "utf-8", "yes"),
        New XElement("user",
            New XElement("details",
                New XElement("firstname", Firstname.Text),
                New XElement("surname", Lastname.Text)
            )
        )
    )

 XMLDoc.Save("C:\test.xml")

Ответы [ 2 ]

2 голосов
/ 27 апреля 2011

Вы только закрываете / сбрасываете FileStream, а не CryptoStream или StreamWriter.Это не дает CryptoStream шанса сбросить свой последний блок.

Лично я бы использовал Using операторы для всех них, после чего все будет закрыто автоматически, и я подозреваю вас 'Я найду это работает отлично.Это также означает, что ваши ресурсы будут освобождены, если есть исключение - в настоящий момент вы ничего не закрываете, например, при сбое записи.

Я бы также не стал бы беспокоиться оStreamWriter - просто сохраните прямо в CryptoStream.В противном случае вы получите XML и StreamWriter, которые пытаются контролировать используемую кодировку.

0 голосов
/ 28 апреля 2011

Большое спасибо Джону Скиту, который указал на лучшее решение моих проблем. Итоговый код (и улучшения):

Encrypt.aspx 

Using ra As RijnDaelManaged = RijndaelManaged.Create()

    ra.Key = {118, 123, 23, 17, 161, 152, 35, 68, 126, 213, 16, 115, 68, 217, 58, 108, 56, 218, 5, 78, 28, 128, 113, 208, 61, 56, 10, 87, 187, 162, 233, 38}
    ra.IV = {33, 241, 14, 16, 103, 18, 14, 248, 4, 54, 18, 5, 60, 76, 16, 191}

    encrypt = ra.CreateEncryptor(ra.Key, ra.IV)

    Using ws As FileStream = File.Open("C:\test1.xml", FileMode.Create)

        Using cs As CryptoStream = New CryptoStream(ws, encrypt, CryptoStreamMode.Write)

            XMLDoc.Save(cs)

        End Using

    End Using

End Using

Decrypt.aspx 

Using ra As RijndaelManaged = RijndaelManaged.Create()

    ra.Key = {118, 123, 23, 17, 161, 152, 35, 68, 126, 213, 16, 115, 68, 217, 58, 108, 56, 218, 5, 78, 28, 128, 113, 208, 61, 56, 10, 87, 187, 162, 233, 38}
    ra.IV = {33, 241, 14, 16, 103, 18, 14, 248, 4, 54, 18, 5, 60, 76, 16, 191}

    decrypt = ra.CreateDecryptor(ra.Key, ra.IV)

    Using rs As FileStream = File.OpenRead("C:\test1.xml")

        Using cs As CryptoStream = New CryptoStream(rs, decrypt, CryptoStreamMode.Read)

            Using xr As XmlTextReader = New XmlTextReader(cs)

                xDoc = XDocument.Load(xr)
                xDoc.Save("C:\test2.xml")

            End Using

        End Using

    End Using

End Using
...