TWebBrowser вылетает со встроенными клипами Youtube - PullRequest
Новая
       33

TWebBrowser вылетает со встроенными клипами Youtube

5 голосов
/ 20 ноября 2011

Вот мой код: 

type
  TForm1 = class(TForm)
    WebBrowser1: TWebBrowser;
    Button1: TButton;
    Button2: TButton;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  end;

implementation
uses ActiveX;

procedure TForm1.Button1Click(Sender: TObject); // method 1
var
  HtmlFile: string;
begin
  HtmlFile := ExtractFilePath(Application.ExeName) + 'test.html';
  WebBrowser1.Navigate(HtmlFile);
end;

procedure LoadHtml(wb: TWebBrowser; HTMLStr: string);
var
  aStream: TMemoryStream;
begin
  wb.Navigate('about:blank'); // reset the webbrowser
  while wb.ReadyState < READYSTATE_INTERACTIVE do // wait to load the empty page
    Application.ProcessMessages;
  if Assigned(wb.Document) then
  begin
    aStream := TMemoryStream.Create;
    try
      aStream.WriteBuffer(Pointer(HTMLStr)^, Length(HTMLStr));
      aStream.Seek(0, soFromBeginning);
      (wb.Document as IPersistStreamInit).Load(TStreamAdapter.Create(aStream));
    finally
      aStream.Free;
    end;
  end;
end;

procedure TForm1.Button2Click(Sender: TObject); // method 2
begin
  LoadHtml(WebBrowser1,
    '<html><head></head><body>'+
    '  <object width="640" height="390"> '+
    '  <param name="movie" value="http://www.youtube.com/v/L7NWdxFAHdY&hl=en_US&feature=player_embedded&version=3"> '+
    '  </param><param name="allowFullScreen" value="true"> '+
    '  </param><param name="allowScriptAccess" value="always"> '+
    '  </param><embed src="http://www.youtube.com/v/L7NWdxFAHdY&hl=en_US&feature=player_embedded&version=3" type="application/x-shockwave-flash" allowfullscreen="true" allowScriptAccess="always" width="640" height="390"> '+
    '  </embed></object> '+
    '</body></html>'
    );
end;

test.html 

<object width="425" height="349">
<param name="movie" value="http://www.youtube.com/v/1hPxGmTGarM?version=3&amp;hl=iw_IL">
</param><param name="allowFullScreen" value="true"></param>
<param name="allowscriptaccess" value="always"></param>
<embed src="http://www.youtube.com/v/1hPxGmTGarM?version=3&amp;hl=iw_IL" type="application/x-shockwave-flash" width="425" height="349" allowscriptaccess="always" allowfullscreen="true">
</embed></object>

У меня происходит сбой приложения в обоих методах.Я получаю необработанное исключение win32 (вызванное Flash player Exception EInvalidOp in module Flash10u.ocx at 00108657. Invalid floating point operation).

  • Я пробовал этот код на D5, D7, D9.
  • Я пытался повторно импортировать SHDocVw.dll.
  • Я также пытался использовать элемент управления EmbeddedWB вместо TWebBroser ...
  • У Internet Explorer / Avant / Maxthon нет проблем с этим HTML (все основано на IE ActiveX).

Любые предложения или исправления?

Как я могу поймать эту ошибку или даже подавить ее?

Есть ли способ манипулировать или изменять HTML на лету черезСобытие TWebBrowser, поэтому я могу отображать изображение вместо Flash-плеера, так же, как работает Ad-Blockers?(Мои клиенты размещают этот код на своих сайтах через Интернет, и мое приложение Delphi обеспечивает быстрый предварительный просмотр)

ОБНОВЛЕНИЕ

Я использовалTTimer для включения / выключения FPU (на основе идеи Арьена): 

function Get8087CW: Word; // for D5
asm
        PUSH    0
        FNSTCW  [ESP].Word
        POP     EAX
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  Timer1.Enabled := False;
  Timer1.Interval := 5000; // 5 sec
  Saved8087CW := Get8087CW;
end;

procedure TForm1.WebBrowser1BeforeNavigate2(Sender: TObject;
  const pDisp: IDispatch; var URL, Flags, TargetFrameName, PostData,
  Headers: OleVariant; var Cancel: WordBool);
begin
  Timer1.Enabled := False;
  System.Set8087CW($133F); // Disable all fpu exceptions
end;

procedure TForm1.WebBrowser1DocumentComplete(Sender: TObject;
  const pDisp: IDispatch; var URL: OleVariant);
begin
   Timer1.Enabled := True;
end;

procedure TForm1.Timer1Timer(Sender: TObject);
begin
  Timer1.Enabled := False;
  Set8087CW(Saved8087CW);
end;

ОБНОВЛЕНИЕ (2)

Я закончилмаскировка исключения FPU при запуске приложения.с тех пор (мое) влияние на мое приложение не оказывалось.

Ответы [ 2 ]

5 голосов
/ 20 ноября 2011

Чуть более красивое решение: 

Math.SetExceptionMask([exInvalidOp, exDenormalized, exZeroDivide, exOverflow,
  exUnderflow, exPrecision]);

Если я правильно прочитал документацию, Math.SetExceptionMask заставляет замолчать каждое упомянутое исключение .

Однако, это просто чище и красивее версия подхода @ Арьена.

4 голосов
/ 20 ноября 2011

Попробуйте временно отключить исключение FPU с помощью Set8087CW (0x133f); информация

...