Разделенный запятыми синтаксический анализ строки XSLT для каждого узла

Question

У меня есть входная строка, которая имеет значения CSV. Например, 1,2,3 Мне нужно отделить каждое значение и назначить его целевому узлу в цикле for-each.

Я получил этот шаблон ниже, который разбивает входную строку на основе разделителя. Как можно назначить каждое из значений с разделителями для целевого элемента в цикле for-each.

<xsl:template name="output-tokens">
<xsl:param name="list"/>
<xsl:param name="delimiter"/>
<xsl:variable name="newlist">
  <xsl:choose>
    <xsl:when test="contains($list, $delimiter)">
      <xsl:value-of select="normalize-space($list)"/>
    </xsl:when>
    <xsl:otherwise>
      <xsl:value-of select="concat(normalize-space($list), $delimiter)"/>
    </xsl:otherwise>
  </xsl:choose>
</xsl:variable>
<xsl:variable name="first" select="substring-before($newlist, $delimiter)"/>
<xsl:variable name="remaining"
              select="substring-after($newlist, $delimiter)"/>
<xsl:variable name="count" select="position()"/>
<num>
  <xsl:value-of select="$first"/>
</num>
<xsl:if test="$remaining">
  <xsl:call-template name="output-tokens">
    <xsl:with-param name="list" select="$remaining"/>
    <xsl:with-param name="delimiter">
      <xsl:value-of select="$delimiter"/>
    </xsl:with-param>
  </xsl:call-template>
</xsl:if>
</xsl:template>

Ввод xml:

<out1:AvailableDates>
<out1:AvailableDate>15/12/2011,16/12/2011,19/12/2011,20/12/2011,21/12/2011</out1:AvailableDate>
</out1:AvailableDates>

Ожидаемый результат:

<tns:AvailableDates>
<tns:AvailableDate>15/12/2011</tns:AvailableDate>
<tns:AvailableDate>16/12/2011</tns:AvailableDate>
<tns:AvailableDate>120/12/2011</tns:AvailableDate>
</tns:AvailableDates>

Answer 1

Вот полное и краткое, истинное решение XSLT 1.0 :

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:out1="undefined" xmlns:tns="tns:tns"
  exclude-result-prefixes="out1 tns">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="out1:AvailableDate">
  <tns:AvailableDates>
    <xsl:apply-templates/>
  </tns:AvailableDates>
 </xsl:template>

 <xsl:template match="text()" name="split">
  <xsl:param name="pText" select="."/>
  <xsl:param name="pItemElementName" select="'tns:AvailableDate'"/>
  <xsl:param name="pItemElementNamespace" select="'tns:tns'"/>

    <xsl:if test="string-length($pText) > 0">
     <xsl:variable name="vNextItem" select=
      "substring-before(concat($pText, ','), ',')"/>

      <xsl:element name="{$pItemElementName}"
                   namespace="{$pItemElementNamespace}">
       <xsl:value-of select="$vNextItem"/>
      </xsl:element>

      <xsl:call-template name="split">
        <xsl:with-param name="pText" select=
                       "substring-after($pText, ',')"/>
        <xsl:with-param name="pItemElementName" select="$pItemElementName"/>
        <xsl:with-param name="pItemElementNamespace" select="$pItemElementNamespace"/>
      </xsl:call-template>
    </xsl:if>
 </xsl:template>
</xsl:stylesheet>

при применении к предоставленному документу XML (исправлено, чтобы оно было правильно оформлено):

<out1:AvailableDates xmlns:out1="undefined">
    <out1:AvailableDate>15/12/2011,16/12/2011,19/12/2011,20/12/2011,21/12/2011</out1:AvailableDate>
</out1:AvailableDates>

желаемый, правильный результат получается :

<tns:AvailableDates xmlns:tns="tns:tns">
   <tns:AvailableDate>15/12/2011</tns:AvailableDate>
   <tns:AvailableDate>16/12/2011</tns:AvailableDate>
   <tns:AvailableDate>19/12/2011</tns:AvailableDate>
   <tns:AvailableDate>20/12/2011</tns:AvailableDate>
   <tns:AvailableDate>21/12/2011</tns:AvailableDate>
</tns:AvailableDates>

Answer 2

В XSLT 2.0 вы можете использовать функцию tokenize(string, separator) вместо именованного шаблона.

А это xsl:

<xsl:stylesheet version="2.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:tns="http://tnsnamespace">

    <xsl:template match="AvailableDate">
        <tns:AvailableDates>
            <xsl:for-each select="tokenize(current(), ',')">
                <tns:AvailableDate>
                    <xsl:value-of select="."/>
                </tns:AvailableDate>
            </xsl:for-each>
        </tns:AvailableDates>
    </xsl:template>
</xsl:stylesheet>

дает следующий результат:

<?xml version="1.0" encoding="UTF-8"?>
<tns:AvailableDates xmlns:tns="http://tnsnamespace">
    <tns:AvailableDate>15/12/2011</tns:AvailableDate>
    <tns:AvailableDate>16/12/2011</tns:AvailableDate>
    <tns:AvailableDate>19/12/2011</tns:AvailableDate>
    <tns:AvailableDate>20/12/2011</tns:AvailableDate>
    <tns:AvailableDate>21/12/2011</tns:AvailableDate>
</tns:AvailableDates>

Обновление :

При использовании процессора Xslt 2.0 в режиме обратной совместимости следующий шаблон дает тот же результат:

<xsl:template match="AvailableDate">
    <tns:AvailableDates>
        <xsl:variable name="myValue">
            <xsl:call-template name="output-tokens">
                <xsl:with-param name="list" select="."/>
                <xsl:with-param name="delimiter" select="','"/>
            </xsl:call-template>
        </xsl:variable>

        <xsl:for-each select="$myValue/node()">
            <tns:AvailableDate>
                <xsl:value-of select="."/>
            </tns:AvailableDate>
        </xsl:for-each>
    </tns:AvailableDates>
</xsl:template>

Для Xslt 1.0 - невозможен простой (со стандартными функциями) доступ к узлам через переменную - см. @Dimitre Novatchev answer XSLT 1.0 - Создать набор узлов и передать в качестве параметра

Для этого процессоры XSLT 1.0 содержат функцию расширения: node-set(...)

Для Saxon 6.5 node-set() функция определена в <a href="http://icl.com/saxon" rel="nofollow noreferrer">http://icl.com/saxon</a> пространстве имен

Таким образом, в случае процессоров XSLT 1.0 было бы:

<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:exslt="http://exslt.org/common"
    xmlns:out1="http://out1namespace"
    xmlns:tns="http://tnsnamespace"
    exclude-result-prefixes="out1 exslt">
    <xsl:output omit-xml-declaration="yes" indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:template match="out1:AvailableDate">
        <tns:AvailableDates>
            <xsl:variable name="myValue">
                <xsl:call-template name="output-tokens">
                    <xsl:with-param name="list" select="."/>
                    <xsl:with-param name="delimiter" select="','"/>
                </xsl:call-template>
            </xsl:variable>
            <xsl:for-each select="exslt:node-set($myValue)/node()">
                <tns:AvailableDate>
                    <xsl:value-of select="."/>
                </tns:AvailableDate>
            </xsl:for-each>
        </tns:AvailableDates>
    </xsl:template>

    <xsl:template name="output-tokens">
        <xsl:param name="list"/>
        <xsl:param name="delimiter"/>
        <xsl:variable name="newlist">
            <xsl:choose>
                <xsl:when test="contains($list, $delimiter)">
                    <xsl:value-of select="normalize-space($list)"/>
                </xsl:when>
                <xsl:otherwise>
                    <xsl:value-of select="concat(normalize-space($list), $delimiter)"/>
                </xsl:otherwise>
            </xsl:choose>
        </xsl:variable>
        <xsl:variable name="first" select="substring-before($newlist, $delimiter)"/>
        <xsl:variable name="remaining"
            select="substring-after($newlist, $delimiter)"/>
        <xsl:variable name="count" select="position()"/>
        <num>
            <xsl:value-of select="$first"/>
        </num>
        <xsl:if test="$remaining">
            <xsl:call-template name="output-tokens">
                <xsl:with-param name="list" select="$remaining"/>
                <xsl:with-param name="delimiter">
                    <xsl:value-of select="$delimiter"/>
                </xsl:with-param>
            </xsl:call-template>
        </xsl:if>
    </xsl:template>

</xsl:stylesheet>

Спасибо @Dimitre Novatchev, чтобы исправить меня и его ответ о доступе к наборам узлов из переменной.

Answer 3

Лично я предпочитаю этот вариант, основанный на пользовательских функциях расширения.Этот метод компактен и чист и прекрасно работает в XSLT 1.0 (по крайней мере, в XALAN 2.7, как встроено в любую недавнюю JVM).

1) объявляет класс со статическим методом, возвращающим org.w3c.dom.Узел

package com.reverseXSL.util;

import org.w3c.dom.*;
import java.util.regex.*;
import javax.xml.parsers.DocumentBuilderFactory;

public class XslTools {

  public static Node splitToNodes(String input, String regex) throws Exception {
    Document doc = DocumentBuilderFactory.newInstance().newDocumentBuilder().newDocument();
    Element item, list = doc.createElement("List");
    Pattern p = Pattern.compile(regex);
    Matcher m = p.matcher(input);
    while (m.find()) {
      item = doc.createElement("Item");
      StringBuffer sb = new StringBuffer();
      for (int i=1; i<=m.groupCount(); ++i) if (m.start(i)>=0) sb.append(m.group(i));
      Text txt = doc.createTextNode(sb.toString());
      item.appendChild(txt);
      list.appendChild(item);
    }
    return list; 
  }

}

Эта функция разбивает входную строку на шаблон регулярного выражения и создает фрагмент документа вида A B C .Регулярное выражение сопоставляется последовательно, каждое совпадение дает элемент Item, значение которого состоит из групп захвата (некоторые, возможно, пустые) внутри каждого совпадения регулярного выражения.Это позволяет избавиться от разделителей и других синтаксических символов.

Например, разбить разделенный запятыми список, такой как " A, B ,, C", пропустить пустые значения и обрезать лишние пробелы (следовательно, получить приведенный выше список узлов),используйте регулярное выражение, например '\s*([^,]+?)\s*(?:,|$)', - это круто!Если вместо этого вы хотите разделить входной текст на фиксированный размер (здесь 10 символов), чтобы последний элемент занял все остальное, используйте регулярное выражение, например '(.{10}|.+)' - любите его!

Затем можно использовать функцию вXSLT 1.0 выглядит следующим образом (довольно компактно!):

<xsl:stylesheet version="1.0" xmlns:var="com.reverseXSL.util.XslTools" extension-element-prefixes="var" ...
...
<xsl:template ...
  ...
  <xsl:for-each select="var:splitToNodes(Detail/CsvText,'\s*([^,]+?)\s*(?:,|$)')/Item">
    <Loop><xsl:value-of select="."/></Loop>
  </xsl:for-each>
...

Выполняется на совпадении шаблона с получением входного фрагмента <Detail><CsvText>a, b ,c </CsvText></Detail>, который вы сгенерируете <Loop>a</Loop><Loop>b</Loop><Loop>c</Loop>

Хитрость не забываетследуйте вызову функции, который генерирует Node / Item с помощью XPath "/ Item" (или "/ *"), как вы должны заметить, так что последовательность Node возвращается в цикл for-each.