Как отправить и обработать Http Post в ASP?

Question

httpRequest.Open "POST", "www.example.com/handle.asp", False
httpRequest.setRequestHeader "Content-Type", "application/x-www-form-urlencoded"
httpRequest.send data
postResponse = httpRequest.response

Как мне справиться с постом приведенного выше кода.в handle.asp.В дескрипторе я хочу взять отправляемые данные и добавить к ним, а затем отправить что-то обратно на страницу вызова?

Answer 1

@ Узи: Вот пример -

somefile.asp вызов handle.asp, который является сценарием обработки:

Option Explicit

Dim data, httpRequest, postResponse

data = "var1=somevalue"
data = data & "&var2=someothervalue"
data = data & "&var3=someothervalue"

Set httpRequest = Server.CreateObject("MSXML2.ServerXMLHTTP")
httpRequest.Open "POST", "http://www.example.com/handle.asp", False
httpRequest.SetRequestHeader "Content-Type", "application/x-www-form-urlencoded"
httpRequest.Send data

postResponse = httpRequest.ResponseText

Response.Write postResponse ' or do something else with it

Пример handle.asp:

Option Explicit

Dim var1, var2, var3

var1 = Request.Form("var1")
var2 = Request.Form("var2")
var3 = Request.Form("var3")

' Silly example of a condition / test '
If var1 = "somecondition" Then
    var1 = var1 & " - extra text"
End If

' .. More processing of the other variables .. '

' Processing / validation done... '
Response.Write var1 & vbCrLf
Response.Write var2 & vbCrLf
Response.Write var3 & vbCrLf

Answer 2

Точно так же, как если бы вы обрабатывали опубликованные данные обычно в ASP, используя Request.Form("parameter") для считывания значений POST и выполнения с ними всего, что вам нужно.

Вам просто нужно убедиться, что вы вернули данные из обработкисценарий в формате, легко декодируемом / используемом сценарием, который отправляет запрос POST.