разница между свободным идентификатором =?и связанный идентификатор =? - PullRequest
Новая
       53

разница между свободным идентификатором =?и связанный идентификатор =?

9 голосов
/ 23 июля 2011

Пытаетесь понять free-identifier =? и связанный идентификатор = ?. Может кто-нибудь дать мне эквивалентные примеры кода, где используется free-identifier =? вернул бы true и используя bound-identifier =? вернул бы ложь.

Спасибо

1 Ответ

6 голосов
/ 28 июля 2011

Вот пример: 

(define-syntax (compare-with-x stx)
  (syntax-case stx ()
    [(_ x-in)
     (with-syntax ([free=? (free-identifier=? #'x-in #'x)]
                   [bound=? (bound-identifier=? #'x-in #'x)])
       #'(list free=? bound=?))]))

(define-syntax go
  (syntax-rules ()
    [(go) (compare-with-x x)]))

(go) ;; => '(#t #f)

У x, введенного go, есть отметка из этого шага расширения, но x в compare-with-x нет, поэтому bound-identifier=? считает их разными.

Вот еще один пример: 

(define-syntax (compare-xs stx)
  (syntax-case stx ()
    [(_ x1 x2)
     (with-syntax ([free=? (free-identifier=? #'x2 #'x2)]
                   [bound=? (bound-identifier=? #'x1 #'x2)])
       #'(list free=? bound=?))]))

(define-syntax go2
  (syntax-rules ()
    [(go2 x-in) (compare-xs x-in x)]))

(go2 x) ;; => '(#t #f)

Здесь go2 также вводит x со знаком, тогда как x, данный go2 какаргумент не имеет отметки.Та же история.

...