Как открыть текстовый файл с разделителями табуляции в Excel, используя Perl и OLE? - PullRequest
Новая
       18

Как открыть текстовый файл с разделителями табуляции в Excel, используя Perl и OLE?

0 голосов
/ 15 февраля 2011

Первоначально я пытался открыть файл XML в Excel. Но так как это занимает много времени, я сам анализировал XML в текстовый файл с разделителями табуляции. Я думал, что нашел правильный синтаксис в интернете. Я попробовал приведенный ниже код, используя значения, которые я записал в макросе Excel. У меня есть 18 столбцов файл с разделителями табуляции. Ошибка возникает в последней строке кода ниже при вызове метода «Рабочие листы».

Сообщение об ошибке: Невозможно вызвать метод «Рабочие листы» без ссылки на пакет или объект в строке ./PostProcessingDev.pl 70. 

use Win32::OLE;
use Win32::OLE::Const 'Microsoft Excel';
Win32::OLE->Option(Warn => 3);

use strict;

my $Excel;
my $Sheet;
my $Workbook;


$Excel = CreateObject OLE "Excel.Application";

$Workbook =  $Excel->Workbooks->OpenText({Filename =>"$inSelf->{'TXT'}",
  Origin => xlMSDOS,
  StartRow => 1,
  DataType => xlDelimited, 
  TextQualifier => xlDoubleQuote, 
  ConsecutiveDelimiter => "False", 
  Tab => "True",
  Semicolon => "False",
  Comma => "False",
  Space => "False",
  Other => "False",
  FieldInfo => [[1, xlTextFormat],
    [2, xlTextFormat],
    [3, xlTextFormat],
    [4, xlTextFormat],
    [5, xlTextFormat],
    [6, xlTextFormat],
    [7, xlTextFormat],
    [8, xlTextFormat],
    [9, xlTextFormat],
    [10, xlTextFormat],
    [11, xlTextFormat],
    [12, xlTextFormat],
    [13, xlTextFormat],
    [14, xlTextFormat],
    [15, xlTextFormat],
    [16, xlTextFormat],
    [17, xlTextFormat],
    [18, xlTextFormat]],
  TrailingMinusNumbers => "True"});

$Sheet = $Workbook->Worksheets(1);

Ответы [ 3 ]

2 голосов
/ 15 февраля 2011

Вам действительно нужно анализировать TSV с помощью Excel?Если в ваших файлах нет ничего необычного, вы можете использовать что-то вроде этого: 

my $file = 'some tsv file';
{
    open my $in,"<",$file  or die "$file: $!";
    while(<$in>) {
        chomp;
        my @cols = split /\t/;
        # do something with columns in @cols array
    }
}

Если Excel необходим по причине, которую я не вижу, проблема в том, что метод OpenText возвращает True / False ине Workbook объект.Это работает: 

use strict;

use Win32::OLE;
use Win32::OLE::Const 'Microsoft Excel';
use Data::Dump;     # for dd

Win32::OLE->Option(Warn => 3);

my $Excel = Win32::OLE->new("Excel.Application");
$Excel->Workbooks->OpenText({
    Filename             => 'enter the full path to file',
    Origin               => xlMSDOS,
    StartRow             => 1,
    DataType             => xlDelimited,
    TextQualifier        => xlDoubleQuote,
    Tab                  => "True",
    TrailingMinusNumbers => "True"
});

my $Sheet = $Excel->ActiveWorkbook->Worksheets(1);
my $Data = $Sheet->UsedRange()->{Value};

dd $Data;    # arrayref (rows) of arrayrefs (columns)
0 голосов
/ 16 февраля 2011

Спасибо за ваши ответы.Это решило мою проблему.Все, что я хотел сделать с помощью метода OpenText, это преобразовать файл TSV в Excel, так как это требуемый формат результата.Поскольку я не мог найти решение в Интернете, прежде чем я хотел бы предоставить полный код: 

use Win32::OLE;
use Win32::OLE::Const 'Microsoft Excel';
use strict;

Win32::OLE->Option(Warn => 3);

my $FileName = "Complete Path of TSV File";

my $Excel = Win32::OLE->new("Excel.Application");

# Open Tab separated Text file in Excel, all 18 columns are "Text" formated
$Excel->Workbooks->OpenText({
  Filename      => $FileName,
  Origin        => xlMSDOS,
  StartRow      => 1,
  DataType      => xlDelimited,
  TextQualifier => xlDoubleQuote,
  Tab           => "True",
  FieldInfo     => [[1, xlTextFormat],
    [2, xlTextFormat],
    [3, xlTextFormat],
    [4, xlTextFormat],
    [5, xlTextFormat],
    [6, xlTextFormat],
    [7, xlTextFormat],
    [8, xlTextFormat],
    [9, xlTextFormat],
    [10, xlTextFormat],
    [11, xlTextFormat],
    [12, xlTextFormat],
    [13, xlTextFormat],
    [14, xlTextFormat],
    [15, xlTextFormat],
    [16, xlTextFormat],
    [17, xlTextFormat],
    [18, xlTextFormat]],
  TrailingMinusNumbers => "True"
});

my $Sheet = $Excel->ActiveWorkbook->Worksheets(1);
$Sheet->Activate;

my $Workbook = $Excel->ActiveWorkbook;

# Replace the "*.txt" file extension by "*.xls" for Excel
$FileName =~ s/txt$/xls/;

# Turn off the "This file already exists" message.
$Excel->{DisplayAlerts} = 0;
# Save file as Excel 2000-2003 Workbook (command for Excel 2007)
$Workbook->SaveAs({Filename => $FileName, FileFormat => xlExcel8});
$Excel->Quit;
0 голосов
/ 15 февраля 2011

попробуйте использовать Text :: CSV .он поддерживает определенные пользователем разделители.См. Описание модуля.

...