Совместное использование учетных данных входа между серверами ColdFusion? - PullRequest
Новая
       9

Совместное использование учетных данных входа между серверами ColdFusion?

3 голосов
/ 03 апреля 2009

Если у меня несколько серверов CF8, может ли пользователь войти в систему на одном сервере, но совместно использовать учетные данные для входа на всех серверах (повторный вход не требуется)?

1 Ответ

7 голосов
/ 03 апреля 2009

Может быть, вопрос о том, чтобы поделиться сессией? Это можно сделать с помощью сериализованных J2EE-сессий или с помощью общих клиентских переменных .

Например, это можно сделать следующим образом.

Создать пустую базу данных на одном из серверов (я создал MySQL один). Создайте источники данных, указывающие на эту БД на всех серверах CF. Используйте этот источник данных как Параметры сервера> Переменные клиента> Хранилище клиентских сессий с именем SharedSessions (мы будем использовать его позже).

Если мы используем cflogin в Application.cfm на всех серверах , его код может выглядеть (упрощенно) следующим образом: 

<cfapplication
    name="shared_session_test"
    sessionManagement="true"
    clientmanagement="true"
    clientstorage="SharedSessions" />

<cflogin>

    <cfif IsDefined( "cflogin" ) and cflogin.name eq "admin" and cflogin.password eq "admin">
        <cfset user_roles = "administrators" />
        <cfset user_name = cflogin.name />
        <cfset user_password = cflogin.password />
    </cfif>

    <cfif IsDefined( "user_roles" )>
        <!--- push login params into shared client scope --->
        <cfset CLIENT.user_roles = user_roles />
        <cfset CLIENT.user_name = user_name />
        <cfset CLIENT.user_password = user_password />
    <cfelseif IsDefined( "CLIENT.user_roles" )>
        <!--- restore login params from shared client scope --->
        <cfset user_roles = CLIENT.user_roles />
        <cfset user_name = CLIENT.user_name  />
        <cfset user_password = CLIENT.user_password  />
    </cfif>

    <cfif IsDefined( "user_roles" )>
        <cfloginuser name="#user_name#" password="#user_password#" roles="#user_roles#">
    <cfelse>
        <!--- authentication failed - send back 401 --->
        <cfsetting enablecfoutputonly="yes" showdebugoutput="no">
        <cfheader statuscode="401">
        <cfheader name="WWW-Authenticate" value="Basic realm=""MySecurity""">
        <cfoutput>Not authorized</cfoutput>
        <cfabort />
    </cfif>

</cflogin>

<cfoutput><p><a href="http://other.server.com/index.cfm?#CLIENT.urltoken#">other.server.com</a></p></cfoutput>

Теперь они отображаются одинаково на обоих серверах: 

<cfdump var="#getAuthUser()#">
<cfdump var="#CLIENT#">

Конечно, здесь многое предстоит сделать, чтобы сделать процесс лучше и безопаснее, просто описал общую идею.

Надеюсь, это поможет.

...