Генерация отчета в Base SAS, который НЕ находится в макете таблицы - PullRequest
Новая
       16

Генерация отчета в Base SAS, который НЕ находится в макете таблицы

0 голосов
/ 27 февраля 2009

Я работаю над отчетом в Base SAS 8.1 (OpenVMS). Мне нужно, чтобы на 1 наблюдении было по 1 странице ... как показано ниже. Я не могу найти ничего, что показывает, как это сделать с помощью PROC PRINT или PROC REPORT. Есть ли способ сделать это, кроме как с помощью оператора PUT? Обновление или добавление модулей, к сожалению, не вариант. Любая помощь приветствуется.

Идентификатор текстового заголовка 1

Текст строки 1 ---------------- переменная 1

Текст строки 2 ---------------- переменная 2

Текст строки 3 ---------------- переменная 3

- разрыв страницы -

Идентификатор текстового заголовка 2

Текст строки 1 ---------------- переменная 1

Текст строки 2 ---------------- переменная 2

Текст строки 3 ---------------- переменная 3

- разрыв страницы -

1 Ответ

5 голосов
/ 27 февраля 2009

Если вы перенесете набор данных по номеру наблюдения, то proc report справится с этим без проблем. НТН. 

/* test data -- each obs is identified by obsId */
data class;
  set sashelp.class;
  obsId = _n_;
run;

/* transpose the data */
proc transpose 
  data=class 
  out=report(rename=(_name_=var col1=value));
  var _all_;
  by obsId;
run;

/* change the varaible name into "Line 1 text ..." */
data report;
  drop line cLine dashes;
  length var cLine $30;
  dashes = repeat("-", 20-1);
  /* usual DoW */
  do line = 1 by 1 until (last.obsId);
    set report;
    by obsId;
    cLine = put(line, best.-l);
    var = "Line "||trim(cline)||" text "||dashes;
    output;
  end;
run;

/* print out one obs per page */
options nocenter;
proc report data=report nowd;
  column obsId var value;
  define obsId / " " group noprint;
  define var / " " display left;
  define value / " " display left;
  break after obsId / page;
  compute before obsId;
    id = put(obsId, best.-l);
    len = length(id);
    line @2 "Header Text Observation Id " iD $varying. len;
    line " ";
  endcomp;
run;

/* on lst, in part. 
Header Text Observation Id 1

 Line 1 text ------------------  Alfred
 Line 2 text ------------------  M
 Line 3 text ------------------            14
 Line 4 text ------------------            69
 Line 5 text ------------------         112.5
 Line 6 text ------------------             1

(new page)
Header Text Observation Id 2

 Line 1 text ------------------  Alice
 Line 2 text ------------------  F
 Line 3 text ------------------            13
 Line 4 text ------------------          56.5
 Line 5 text ------------------            84
 Line 6 text ------------------             2

(new page)
...
*/
...