XSL поиск узла по значению другого узла + многоуровневая сортировка - PullRequest
Новая
       0

XSL поиск узла по значению другого узла + многоуровневая сортировка

3 голосов
/ 07 марта 2012

В основном есть две вещи, которые мне нужно выяснить:

  1. многоуровневая сортировка
  2. на третьем уровне, где я ставлю ???: как выбрать другой <term> с <title>, равным <narrowerterm> текущего <term>.

Надеюсь, это достаточно ясно. Некоторое время я не мог найти то, что мне нужно.

Мой XML (отрывок): 

<thesaurus>
    <term>
        <title>defense</title>
         <narrowerterm>defense skills</narrowerterm>
         <narrowerterm>defense actions</narrowerterm>
    </term>
    <term>
        <title>defense skills</title>
        <broaderterm>defense</broaderterm>
        <narrowerterm>skill cd</narrowerterm>
        <narrowerterm>skill xy</narrowerterm>
        <narrowerterm>skill ab</narrowerterm>
    </term>
    <term>
        <title>defense actions</title>
        <broaderterm>defense</broaderterm>
        <narrowerterm>actions against xy</narrowerterm>
        <narrowerterm>actions against ab</narrowerterm>
    </term>
</thesaurus>

Мой XSL: 

<xsl:template match="thesaurus">
<html>
<body> 
<xsl:for-each-group select="term" group-by="title">
    <xsl:sort select="title"/>
    <xsl:choose>
        <xsl:when test="broaderterm"> 
        </xsl:when>
        <xsl:otherwise>
            <xsl:choose>
                <xsl:when test="use"> 
                </xsl:when>
                <xsl:otherwise>
                    <p>
                        <xsl:value-of select="current-grouping-key()"/><br/>
                        <xsl:for-each select="narrowerterm">
                            .<xsl:value-of select="."/><br/>
                            <xsl:for-each select="???"/>
                                ..<xsl:value-of select="narrowerterm"/><br/>
                            </xsl:for-each>
                        </xsl:for-each>
                    </p>
                </xsl:otherwise> 
            </xsl:choose>
        </xsl:otherwise> 
    </xsl:choose>
</xsl:for-each-group> 
</body>
</html>
</xsl:template>

То, что я хочу, это: 

defense
.defense actions
..actions against ab
..actions against xy
.defense skills
..skill ab
..skill cd
..skill xy

Где я нахожусь: 

defense
.defense skills
.defense actions

1 Ответ

3 голосов
/ 07 марта 2012

Я не думаю, что это групповая задача или для нее требуется XSLT 2.0.

Это преобразование: 

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="/*">
  <xsl:apply-templates select="term[not(broaderterm)]">
    <xsl:with-param name="pIndent" select="''"/>
    <xsl:sort select="title"/>
  </xsl:apply-templates>
 </xsl:template>

 <xsl:template match="term">
  <xsl:param name="pIndent"/>
  <xsl:value-of select="concat($pIndent, title, '&#xA;')"/>

  <xsl:variable name="vSubterms" select=
      "../term[broaderterm = current()/title]"/>

  <xsl:variable name="vLeafSubterms" select=
  "narrowerterm[not(. = /*/term[broaderterm = current()/title]/title)]"/>

  <xsl:apply-templates select="$vSubterms | $vLeafSubterms">
   <xsl:with-param name="pIndent" select="concat($pIndent, '.')"/>
   <xsl:sort select="concat(self::term/title, self::narrowerterm/text())"/>
  </xsl:apply-templates>
 </xsl:template>

 <xsl:template match="narrowerterm">
  <xsl:param name="pIndent"/>
  <xsl:value-of select="concat($pIndent, ., '&#xA;')"/>
 </xsl:template>
</xsl:stylesheet>

при применении кпредоставленный XML-документ : 

<thesaurus>
    <term>
        <title>defense</title>
        <narrowerterm>defense skills</narrowerterm>
        <narrowerterm>defense actions</narrowerterm>
    </term>
    <term>
        <title>defense skills</title>
        <broaderterm>defense</broaderterm>
        <narrowerterm>skill cd</narrowerterm>
        <narrowerterm>skill xy</narrowerterm>
        <narrowerterm>skill ab</narrowerterm>
    </term>
    <term>
        <title>defense actions</title>
        <broaderterm>defense</broaderterm>
        <narrowerterm>actions against xy</narrowerterm>
        <narrowerterm>actions against ab</narrowerterm>
    </term>
</thesaurus>

дает требуемый, правильный результат : 

defense
.defense actions
..actions against ab
..actions against xy
.defense skills
..skill ab
..skill cd
..skill xy
Добро пожаловать на сайт PullRequest, где вы можете задавать вопросы и получать ответы от других членов сообщества.

Нет похожих вопросов

...