Электронная почта 2 или более книг Excel с Vba

Question

Я не могу понять, как отправить более 1 рабочей книги за мою жизнь! Я знаю несколько разных способов отправить 1 рабочую книгу по электронной почте, я размещаю их здесь.

Sub SendActiveWorkbook()
                ActiveWorkbook.SendMail _
    Recipients:=Array("MyEmail@123.com", "AnotherEmail@123.com"), _
    Subject:="Write subject here"                 
End Sub

А

Sub RouteActiveWorkbook()   
    With ActiveWorkbook
           .HasRoutingSlip = True
               With .RoutingSlip
                    .Delivery = xlAllAtOnce
                    .Recipients = Array("MyEmail@123.com", "AnotherEmail@123.com")
                    .Subject = "CSAM Lux BIEO and BCF breakdown"
                    .Message = "Attached are the breakdowns as of " & Date
               End With
            .Route
     End With
End Sub

Кажется, что я могу отправить только 1 рабочую книгу в данном письме. (это не решит мою проблему, превратив мои 2 книги в 1 книгу). Кто-нибудь имел успех с отправкой более 1 книги по электронной почте?

Answer 1

Надеюсь, это поможет?

Это основной пример отправки электронного письма с более чем 1 вложением. Пожалуйста, внесите изменения в соответствии с реалистичным сценарием. Дайте мне знать, если у вас есть какие-либо вопросы. Также я не позаботился об обработке ошибок в приведенном ниже примере.

ПРОВЕРЕНО И ИСПЫТАНО

Option Explicit

Sub Sample()
    Dim OutApp As Object
    Dim OutMail As Object
    Dim MyFileList(1) As String
    Dim i As Long

    '~~> Change/Add the file names here
    MyFileList(0) = "C:\Sample1.xlsm"
    MyFileList(1) = "C:\Sample2.xlsm"

    Set OutApp = CreateObject("Outlook.Application")
    Set OutMail = OutApp.CreateItem(0)

    With OutMail
        .To = "MyEmail@123.com"
        .Subject = "Example for attaching 2 files"
        .Body = "Hi Ommit :)"

        For i = LBound(MyFileList) To UBound(MyFileList)
            .Attachments.Add MyFileList(i)
        Next i

        .Display
    End With
End Sub