как определить конфиг в файле Pro? - PullRequest
Новая
       4

как определить конфиг в файле Pro?

0 голосов
/ 18 апреля 2011

как определить конфиг в pro файле?

по умолчанию у нас есть два config, debug и release. Я хочу добавить еще 2 конфига, но не в pro.user ! в pro file .

Ответы [ 2 ]

5 голосов
/ 19 апреля 2011

Ваш вопрос немного неясен. Похоже, что вы в настоящий момент собираете с помощью «debug» и «release» из командной строки, и вы хотите добавить свои собственные варианты сборки, подобные этому.

Если это так ... механизм для этого addExclusiveBuilds. Вот пример. Я бы не советовал возиться с этим, если вам неудобно читать код qmake. 

TEMPLATE = app
SOURCES = main.cpp

# Adds two build variants.
# One of them builds the app with optimal compiler flags,
# the other one builds the app with support for collecting coverage data.
# For the first one, CONFIG will contain `optimized' and a Makefile.Optimized will be     generated.
# For the second, CONFIG will contain `coverage' and a Makefile.Coverage will be generated.
# There will also be a top-level Makefile which invokes both the sub-makefiles.
addExclusiveBuilds(optimized, Optimized, coverage, Coverage)

CONFIG(optimized, coverage|optimized) {
    message(I am in the optimized build variant)
    QMAKE_CXXFLAGS += -O3

    TARGET = myapp-optimized
}
else:CONFIG(coverage, coverage|optimized) {
    message(I am in the coverage build variant)
    QMAKE_CXXFLAGS += --coverage
    QMAKE_LFLAGS += --coverage

    TARGET = myapp-coverage
}
else {
    message(I am in the glue project which contains the build variants)

    # This will cause a `make' to build both optimized and coverage
    # variants by default.
    CONFIG += build_all
}
0 голосов
/ 19 апреля 2011

Если я понимаю, что вы говорите, вы добавляете то, что хотите, в переменную CONFIG: 

CONFIG += user_setting
...
user_setting: message( "compiling with user_setting" )

См. Руководство qmake , где говорится о CONFIGпеременная, особенно в конце секции.

...