XSLT сортировка и группировка по дочернему элементу

Question

`У меня есть XML-файл, который содержит много узлов 'Entry'.Внутри каждого узла «Вступление» обычно есть дочерние элементы «Год» и «Заголовок».

Я пытаюсь сгенерировать вывод HTML, который выглядит следующим образом:

2012
    Title
    Title

2011
    Title

2010
    Title
    Title

Этот шаблон должен продолжаться до тех пор, пока существует запись с уникальным годом.У меня проблемы с тем, чтобы напечатать год только один раз.Я могу заставить его печатать каждый год один раз, но он напечатает только заголовок одной (при условии первой) записи.Я могу заставить его напечатать каждую запись с указанием года, но он покажет год для каждой записи.Я использовал комбинацию переменных, generate-id и ключей, но столкнулся с проблемами, описанными (я мог бы ошибиться).

• Нет ограниченийна количество лет, количество записей или количество записей в год / группу.
• Каждый год должен отображаться только один раз.

С точки зрения HTML, я быхотелось бы, чтобы каждая подгруппа (которая разделяет год) была в своем собственном упорядоченном списке, но если это невозможно, я не удивлюсь!

.

Общая схема XMLФайл, с которым я работаю, выглядит следующим образом:

root
    Entry
        Title
        Year

<root>
    <Entry>
        <Title>Num 1</Title>
        <Year>1991</Year>
    </Entry>
    <Entry>
        <Title>Num 2</Title>
        <Year>2011</Year>
    </Entry>
    <Entry>
        <Title>Num 3</Title>
        <Year>2012</Year>
    </Entry>
    <Entry>
        <Title>Num 4</Title>
        <Year>2012</Year>
    </Entry>
</root>

XSL версии 1.0 или 2.0 в порядке.

Вот соответствие шаблона для Entry (Он просто берет элементы и помещает все воднострочный элемент списка).

    <xsl:if test="Download">
  <xsl:text disable-output-escaping="yes">&lt;a href="http://thisisnot.real/publications/</xsl:text>
  <xsl:value-of select="Download"/>
  <xsl:text disable-output-escaping="yes">"&gt;</xsl:text>
    </xsl:if>
    <xsl:value-of select="Title"/>
    <xsl:if test="Download">
  <xsl:text disable-output-escaping="yes">&lt;/a&gt;</xsl:text>
    </xsl:if>
    <xsl:text>, </xsl:text>

 <!-- Add the handling for (possibly multiple) Authors -->
 <xsl:for-each select="Author">
     <xsl:value-of select="."/>,
 </xsl:for-each>




    <xsl:text>In </xsl:text>
    <EM>
      <xsl:value-of select="Booktitle"/>
    </EM>
    <xsl:text>, </xsl:text>

 <!-- Add the handling for Page -->
 <xsl:if test="Page">
      page <xsl:value-of select="Page"/>,
 </xsl:if>

 <!-- Add the handling for Address -->
 <xsl:if test="Address">
    <xsl:value-of select="Address"/>,
 </xsl:if>

 <!-- Add the handling for Year-Convert numeric Month to letters: eg, from 1 to January -->
 <xsl:for-each select="Month">
    <xsl:choose>
       <xsl:when test=".=1">January <xsl:value-of select="../Year"/></xsl:when>
       <xsl:when test=".=2">February <xsl:value-of select="../Year"/></xsl:when>
       <xsl:when test=".=3">March <xsl:value-of select="../Year"/></xsl:when>
       <xsl:when test=".=4">April <xsl:value-of select="../Year"/></xsl:when>
       <xsl:when test=".=5">&gt;May <xsl:value-of select="../Year"/></xsl:when>
       <xsl:when test=".=6">June <xsl:value-of select="../Year"/></xsl:when>
       <xsl:when test=".=7">July <xsl:value-of select="../Year"/></xsl:when>
       <xsl:when test=".=8">August <xsl:value-of select="../Year"/></xsl:when>
       <xsl:when test=".=9">September <xsl:value-of select="../Year"/></xsl:when>
       <xsl:when test=".=10">October <xsl:value-of select="../Year"/></xsl:when>
       <xsl:when test=".=11">November <xsl:value-of select="../Year"/></xsl:when>
       <xsl:when test=".=12">December <xsl:value-of select="../Year"/></xsl:when>
    </xsl:choose>
 </xsl:for-each>

 <!-- Add the handling for Note -->
 <xsl:if test="Note">
         <em>(<xsl:value-of select="Note"/>)</em>
 </xsl:if>

 <!-- Add the handling for AcceptRate in the grey color: #333333 -->
 <xsl:if test="AcceptRate">
     <font color="#333333"><small>  Acceptance Rate: <xsl:value-of select="AcceptRate"/></small></font>
 </xsl:if>

 <!-- Add the handling for Award in the red color: #ff0000 -->
 <xsl:if test="Award">
     <font color="#ff0000"><strong> (<xsl:value-of select="Award"/>)</strong></font>
 </xsl:if>

  </LI>

Answer 1

Вот вариант 2.0 ...

Ввод XML

<root>
  <Entry>
    <Title>Title B</Title>
    <Year>2010</Year>
  </Entry>
  <Entry>
    <Title>Title A</Title>
    <Year>2010</Year>
  </Entry>
  <Entry>
    <Title>Title B</Title>
    <Year>2012</Year>
  </Entry>
  <Entry>
    <Title>Title A</Title>
    <Year>2011</Year>
  </Entry>
  <Entry>
    <Title>Title A</Title>
    <Year>2012</Year>
  </Entry>
</root>

XSLT 2.0

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output indent="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:template match="root">
    <html>
      <xsl:for-each-group select="Entry" group-by="Year">
        <xsl:sort select="Year" data-type="number" order="descending"/>
        <p><xsl:value-of select="Year"/></p>
        <ol>
          <xsl:apply-templates select="current-group()/Title">
            <xsl:sort select="." data-type="text" order="ascending"/>
          </xsl:apply-templates>
        </ol>
      </xsl:for-each-group>
    </html>
  </xsl:template>

  <xsl:template match="Title">
    <li><xsl:value-of select="."/></li>
  </xsl:template>

</xsl:stylesheet>

Вывод HTML (код)

<html>
   <p>2012</p>
   <ol>
      <li>Title A</li>
      <li>Title B</li>
   </ol>
   <p>2011</p>
   <ol>
      <li>Title A</li>
   </ol>
   <p>2010</p>
   <ol>
      <li>Title A</li>
      <li>Title B</li>
   </ol>
</html>

Вывод HTML (отображение)

2012

1. Название A
2. Название B

2011

1. Название A

2010

1. Название A
2. Название B