Используйте код макроса только для одного конкретного столбца - PullRequest
Новая
       8

Используйте код макроса только для одного конкретного столбца

1 голос
/ 29 ноября 2011

Я все еще новичок в программировании в Excel, и у меня возникают проблемы с внесением небольших изменений в мой код. Мой код позволяет пользователю выбирать ячейку, а затем использовать стрелки вверх и вниз для выбора определенного значения. Глядя на приведенный ниже код, я вызываю функции «UpOne» и «DownOne» на своем рабочем листе, а затем сохраняю значения своих сохраненных строк в модуле.

Код листа 

Private Sub Worksheet_Open()
    Application.OnKey "{UP}", "UpOne"
    Application.OnKey "{DOWN}", "DownOne"
End Sub

Код модуля 

Sub DownOne()
    Select Case ActiveCell.Value
    Case ""
        ActiveCell.Value = "PASS"
    Case "PASS"
        ActiveCell.Value = "FAIL"
    Case "FAIL"
        ActiveCell.Value = "Unknown"
 End Sub
 Sub UpOne()
    Select Case ActiveCell.Value
    Case "Unknown"
        ActiveCell.Value = "FAIL"
    Case "FAIL"
        ActiveCell.Value = "PASS"
    Case "PASS"
        ActiveCell.Value = ""
 End Sub

У меня вопрос: как заставить этот код работать только для всех ячеек в одном конкретном столбце? И как бы я имел разные значения, когда пользователь выбирает другой столбец. Поэтому, если пользователь выбирает пустую ячейку в столбце «J», он / она может перемещаться с помощью клавиш со стрелками через такие значения, как «A», «B», «C», но когда он / она выбирает пустую ячейку в столбце «N» "он / она может перемещаться по другому набору значений, например," E "," F "," G "и т. д. спасибо за любую помощь!

Ответы [ 2 ]

3 голосов
/ 29 ноября 2011

Вместо того, чтобы отключать / включать код каждый раз, когда вы выбираете ячейку (плюс вам придется обслуживать выбор из нескольких ячеек), вам будет проще использовать проверку данных.Вы могли бы настроить списки, которые могли бы применяться к определенным ячейкам

Дебра Далглиш имеет отличное обсуждение проверки данных на Contextures enter image description here

1 голос
/ 29 ноября 2011

Грубый код, основанный на вашем оригинальном подходе: 

Sub DownOne()
   CycleValue Selection, -1
End Sub
Sub UpOne()
   CycleValue Selection, 1
End Sub

Sub CycleValue(rng As Range, GoDir As Integer)

    Dim arrA, arrB
    Dim arrVals, val
    Dim c As Range, m, indx As Integer
    Dim lb As Integer, ub As Integer
    Dim ProcessThis As Boolean

    arrA = Array("Fail", "Pass", "")
    arrB = Array("Eggs", "Bacon", "Toast", "Beans", "")

    For Each c In rng.Cells
        ProcessThis = True

        'what values are we cycling through?
        'based on column position
        If c.Column = 1 Then
            arrVals = arrA
        ElseIf c.Column = 5 Then
            arrVals = arrB
        Else
            ProcessThis = False 'not checking this column
        End If

        If ProcessThis Then
            lb = LBound(arrVals)
            ub = UBound(arrVals)
            val = Trim(c.Value)
            m = Application.Match(val, arrVals, 0)

            If IsError(m) Then
                indx = lb
            Else
                m = m - 1 '1-based
                indx = m + GoDir
                If indx < lb Then indx = ub
                If indx > ub Then indx = lb
            End If
            c.Value = arrVals(indx)
         End If
    Next c
End Sub
...