Как обрабатывать escape-последовательности в строковых литералах в ANTLR 3?

Question

Я просматривал документацию по ANTLR v3 (и мою достоверную копию "The Definitive ANTLR reference"), и я не могу найти чистый способ реализации escape-последовательностей в строковых литералах (сейчас я используя цель Java). Я надеялся, что смогу сделать что-то вроде:

fragment 
ESCAPE_SEQUENCE
    : '\\' '\'' { setText("'"); }
    ;

STRING  
    : '\'' (ESCAPE_SEQUENCE | ~('\'' | '\\'))* '\''
      { 
        // strip the quotes from the resulting token
        setText(getText().substring(1, getText().length() - 1));
      } 
    ;

Например, я бы хотел, чтобы входной токен "'Foo\'s House'" стал строкой "Foo's House".

К сожалению, вызов setText(...) во фрагменте ESCAPE_SEQUENCE устанавливает текст для всего токена STRING, что явно не то, что я хочу.

Есть ли способ реализовать эту грамматику без добавления метода, позволяющего вернуться назад к полученной строке и вручную заменить escape-последовательности (например, на что-то вроде setText(escapeString(getText())) в правиле STRING)?

Answer 1

Вот как я это сделал в парсере JSON, который я написал.

STRING      
@init{StringBuilder lBuf = new StringBuilder();}
    :   
           '"' 
           ( escaped=ESC {lBuf.append(getText());} | 
             normal=~('"'|'\\'|'\n'|'\r')     {lBuf.appendCodePoint(normal);} )* 
           '"'     
           {setText(lBuf.toString());}
    ;

fragment
ESC
    :   '\\'
        (   'n'    {setText("\n");}
        |   'r'    {setText("\r");}
        |   't'    {setText("\t");}
        |   'b'    {setText("\b");}
        |   'f'    {setText("\f");}
        |   '"'    {setText("\"");}
        |   '\''   {setText("\'");}
        |   '/'    {setText("/");}
        |   '\\'   {setText("\\");}
        |   ('u')+ i=HEX_DIGIT j=HEX_DIGIT k=HEX_DIGIT l=HEX_DIGIT
                   {setText(ParserUtil.hexToChar(i.getText(),j.getText(),
                                                 k.getText(),l.getText()));}

        )
    ;

Answer 2

Для ANTLR4, Java target и стандартной экранированной строковой грамматики я использовал выделенный одноэлементный класс: CharSupport для перевода строки. Доступно в antlr API:

STRING          :   '"' 
                (   ESC  
                |   ~('"'|'\\'|'\n'|'\r') 
                )* 
                    '"' { 
                        setText( 
                            org.antlr.v4.misc.CharSupport.getStringFromGrammarStringLiteral(
                                getText()
                            )
                        ); 
                    }
                ;

Как я видел в документации V4 и экспериментально, @init больше не поддерживается в лексере!

Answer 3

Другая (возможно, более эффективная) альтернатива - использовать аргументы правила:

STRING
@init { final StringBuilder buf = new StringBuilder(); }
:
    '"'
    (
    ESCAPE[buf]
    | i = ~( '\\' | '"' ) { buf.appendCodePoint(i); }
    )*
    '"'
    { setText(buf.toString()); };

fragment ESCAPE[StringBuilder buf] :
    '\\'
    ( 't' { buf.append('\t'); }
    | 'n' { buf.append('\n'); }
    | 'r' { buf.append('\r'); }
    | '"' { buf.append('\"'); }
    | '\\' { buf.append('\\'); }
    | 'u' a = HEX_DIGIT b = HEX_DIGIT c = HEX_DIGIT d = HEX_DIGIT { buf.append(ParserUtil.hexChar(a, b, c, d)); }
    );

Answer 4

Мне нужно было сделать именно это, но моя цель была C, а не Java. Вот как я это сделал на основе ответа № 1 (и комментария), если кому-то нужно что-то похожее:

QUOTE   :      '\'';
STR
@init{ pANTLR3_STRING unesc = GETTEXT()->factory->newRaw(GETTEXT()->factory); }
        :       QUOTE ( reg = ~('\\' | '\'') { unesc->addc(unesc, reg); }
                        | esc = ESCAPED { unesc->appendS(unesc, GETTEXT()); } )+ QUOTE { SETTEXT(unesc); };

fragment
ESCAPED :       '\\'
                ( '\\' { SETTEXT(GETTEXT()->factory->newStr8(GETTEXT()->factory, (pANTLR3_UINT8)"\\")); }
                | '\'' { SETTEXT(GETTEXT()->factory->newStr8(GETTEXT()->factory, (pANTLR3_UINT8)"\'")); }
                )
        ;

НТН.