Как я могу изменить свои данные, чтобы они были (x, y) координатами для GD :: Graph?

Question

Я пишу программу, которая принимает входной файл от пользователя. В файле есть куча чисел, и я прочитаю числа в файле и создам график на основе этих чисел, используя GD :: Graph .

Первая строка файла - это ось X, вторая строка - значения Y, соответствующие оси X, а также третья, четвертая и т. Д. Например:

1 2 3 4 5 
2 4 5 10 14
5 6 8 12 13

Таким образом, в приведенном выше примере первая строка - это ось x, вторая - значения y, соответствующие оси x, поэтому будет получено 10 точек. (1, 2) (1, 5) (2, 4) (2, 6) .... (4,10) (4,12) (5,14) (5, 13)

Я планирую прочитать каждую строку массива, а затем разбить строку на пробелы или табуляции и сохранить значения в массиве. Итак, массив 1 будет иметь ось X, массив 2 будет иметь ось Y, но как мне сохранить строки 3, 4, 5, ... и т. Д. В массиве, чтобы они стали (x, y)?

Кроме того, как я могу найти наибольшее значение для первой и второй строк (2 массива), чтобы я мог создать ограничение для моих осей X и Y?

Answer 1

Не совсем ответ на ваш вопрос, но не пропустите GD :: Graph :: Data .

Если вы не уверены , что первый и последний в каждой строке самые маленькие / самые большие, вам нужно использовать что-то вроде List :: Util '* min() и max().

---

Я не совсем понимаю, что вы подразумеваете под "первой строкой файла является ось X, второй строкой файла является ось Y, а третьей, четвертой, ... и т. Д. Являются соответствующие точки оси X".

Answer 2

Вы можете увеличивать свои массивы x и y по мере продвижения.

#!/usr/bin/perl

use Data::Dumper;
use warnings;
use strict;

my @xs = ();
my @ys = ();
my $expecting_xs = 1;
my $last_xs_count;

while(<>) {
  chomp;
  my @values = split(/\s+/);
  if($expecting_xs) {
    push(@xs, @values);
    $last_xs_count = @values;
    $expecting_xs = 0;
  } else {
    if(@values != $last_xs_count) {
      die "Count mismatch";
    } 
    push(@ys, @values);
    $expecting_xs = 1;
  }
}

if(!$expecting_xs) {
  die("Odd number of lines");
}

my($xmin, $xmax) = extremes(@xs);
my($ymin, $ymax) = extremes(@ys);

print "xmin: $xmin xmax: $xmax ymin: $ymin ymax: $ymax\n";
print Dumper(\@xs), Dumper(\@ys);

sub extremes {
  my(@values) = @_;
  return undef unless @values;
  my $min = shift(@values);
  my $max = $min;
  for my $value (@values) {
    $max = $value if $value > $max;
    $min = $value if $value < $min;
  }
  return $min, $max;
}

Answer 3

Ой, неправильно прочитайте вопрос, вам нужен либо AoAoH, либо AoH, в зависимости от того, представляет ли каждая линия после первой линию или все это просто точки, которые должны быть построены соответственно. Вот как бы я написал это, если бы каждая строка в файле стала строкой на графике:

#!/usr/bin/perl

use strict;
use warnings;
use List::Util qw/min max/;

my @x_points         = split " ", scalar <>; #read in the x axis labels
my ($x_min, $x_max)  = (sort { $a <=> $b } @x_points)[0,-1];
my ($y_min, $y_max)  = (0, 0);

#lines is an AoAoH, first layer are the lines to be drawn
#second layer is a list of coords
#third layer are the x and y coords
my @lines;
while (<>) {
    my @y_points = split;
    #if the two arrays are not the same size, we have a problem
    die "invalid file\n" unless @y_points == @x_points;

    $y_min = max($y_min, @y_points);
    $y_max = min($y_max, @y_points);

    push @lines, [ 
        map { { x => $x_points[$_], y => $y_points[$_] } }  
    0 .. $#x_points 
    ];
}

use Data::Dumper;

print "x min and max $x_min $x_max\n",
      "y min and max $y_min $y_max\n",
      "data:\n",
      Dumper(\@lines);

my $i;
for my $line (@lines) {
    $i++;
    print "line $i is made up of points: ",
        (map { "($_->{x}, $_->{y}) " } @$line), "\n";
}

А вот как бы я справился с этим, если бы это были просто точки, которые нужно построить:

#!/usr/bin/perl

use strict;
use warnings;
use List::Util qw/min max/;

my @x_points         = split " ", scalar <>; #read in the x axis labels
my ($x_min, $x_max)  = (sort { $a <=> $b } @x_points)[0,-1];
my ($y_min, $y_max)  = (0, 0);

#lines is an AoAoH, first layer are the lines to be drawn
#second layer is a list of coords
#third layer are the x and y coords
my @points;
while (<>) {
    my @y_points = split;
    #if the two arrays are not the same size, we have a problem
    die "invalid file\n" unless @y_points == @x_points;

    $y_min = max($y_min, @y_points);
    $y_max = min($y_max, @y_points);

    push @points,
        map { { x => $x_points[$_], y => $y_points[$_] } }
        0 .. $#x_points;
}

use Data::Dumper;

print "x min and max $x_min $x_max\n",
      "y min and max $y_min $y_max\n",
      "data:\n",
      Dumper(\@points);

print "Here are the points: ", 
    (map { "($_->{x}, $_->{y}) " } @points), "\n";