Как искать и заменять в документе odt Open Office? - PullRequest
Новая
       52

Как искать и заменять в документе odt Open Office?

5 голосов
/ 18 октября 2011

В моем приложении Delphi в настоящее время я выполняю поиск и замену программно для документов doc и docx word, используя офисную автоматизацию.У кого-нибудь есть код, чтобы сделать то же самое (для doc, docs, odt) в OpenOffice?

Я также задал связанный вопрос о сохранении в pdf .

1 Ответ

7 голосов
/ 18 октября 2011

Вы должны сосредоточиться на XReplaceable интерфейсе. Вот пример. Обратите внимание, что нет обработки ошибок. Я проверил его с помощью LibreOffice Writer, и он отлично работает для меня. 

uses
  ComObj;

procedure OpenOfficeReplace(const AFileURL: string; ASearch: string; const AReplace: string);
var
  StarOffice: Variant;
  StarDesktop: Variant;
  StarDocument: Variant;
  FileReplace: Variant;
  FileParams: Variant;
  FileProperty: Variant;

begin
  StarOffice := CreateOleObject('com.sun.star.ServiceManager');
  StarDesktop := StarOffice.CreateInstance('com.sun.star.frame.Desktop');

  FileParams := VarArrayCreate([0, 0], varVariant);
  FileProperty := StarOffice.Bridge_GetStruct('com.sun.star.beans.PropertyValue');
  FileProperty.Name := 'Hidden';
  FileProperty.Value := False;
  FileParams[0] := FileProperty;

  StarDocument := StarDesktop.LoadComponentFromURL(AFileURL, '_blank', 0, FileParams);

  FileReplace := StarDocument.CreateReplaceDescriptor;
  FileReplace.SearchCaseSensitive := False;
  FileReplace.SetSearchString(ASearch);
  FileReplace.SetReplaceString(AReplace);

  StarDocument.ReplaceAll(FileReplace);

  ShowMessage('Replace has been finished');

  StarDocument.Close(True);
  StarDesktop.Terminate;
  StarOffice := Unassigned;
end;

И использование примера 

procedure TForm1.Button1Click(Sender: TObject);
begin
  OpenOfficeReplace('file:///C:/File.odt', 'Search', 'Replace');
end;

Есть также несколько параметров поиска / замены для SearchDescriptor .

...