Facebook Войти используя flex4 - PullRequest
Новая
       6

Facebook Войти используя flex4

0 голосов
/ 07 июля 2011

Я пытаюсь интегрировать свое приложение с Facebook. Я следовал официальному руководству по Adobe http://www.adobe.com/devnet/facebook/articles/flex_fbgraph_pt3.html Я не получаю ошибок или предупреждений.Но когда я запускаю свое приложение, при входе в систему окно входа в систему вообще не появляется .. поскольку ничего не происходит ... Никаких ошибок ..

Может кто-нибудь сказать мне, что происходит неправильноПожалуйста, укажите на какой-нибудь рабочий учебник

Спасибо !!

1 Ответ

1 голос
/ 07 июля 2011

это способ подключения к Facebook с помощью Graph API.Все объясняется в комментариях.Это на самом деле подключение к Facebook, никаких постов на стенах или что-то еще.Эта часть может быть найдена ниже этого класса. 

package com.DAL 
{
    import com.facebook.graph.Facebook;
    import flash.events.Event;
    import com.facebook.graph.data.FacebookSession;
    import flash.events.EventDispatcher;
    import flash.events.MouseEvent;
    import com.fbLoginButton;
    import com.adobe.serialization.json.JSON;

    public class FBConnect extends EventDispatcher
    {
        /******************************************
        *   Variables
        ******************************************/
        private var _applicationID:String;
        private var _extendedPermissions:Object;

        /******************************************
        *   Constants
        ******************************************/
        public static const CONNECTED:String = "CONNECTED";

        /******************************************
        *   Properties
        ******************************************/             
        public function get ApplicationID():String
        {
            return _applicationID;
        }

        /******************************************
        *   Constructor
        ******************************************/
        public function FBConnect() 
        {
            super();

            //Set applicationid
            _applicationID = "YOUR_ID";

            //Set permissions to ask for
            _extendedPermissions = {perms:"read_stream, publish_stream, user_about_me, read_friendlists, user_photos"};

            //Initialize facebook
            Facebook.init(_applicationID);
        }

        /******************************************
        *   Methods
        ******************************************/     
        public function login(e:MouseEvent):void
        {           
            Facebook.login(handleLogin, _extendedPermissions);
        }

        private function handleLogin(response:Object, fail:Object):void
        {
            dispatchEvent(new Event(CONNECTED));
        }
    }
}

Это должно позаботиться о подключении к Facebook.Если вы хотите разместить на стене или что-то еще, вы можете найти небольшой пример ниже. 

        /******************************************
        *   Constructor
        ******************************************/
        public function FBLogic() 
        {
            super();

            _connect = new FBConnect();
            _connect.addEventListener(FBConnect.CONNECTED, startLoaders);

            initLoaders();
        }

        /******************************************
        *   Methods
        ******************************************/

        ...

        public function post(message:String):void
        {
            var _params:Object = new Object();

            _params.access_token = Facebook.getSession().accessToken;
            _params.message = message;

            Facebook.api("/" + _userID + "/feed", messagePosted, _params, "POST");
        }

        public function messagePosted(response:Object, fail:Object):void
        {
            dispatchEvent(new Event(MESSAGEPOSTED));
        }

        public function login(e:MouseEvent):void
        {
            var _loginButton:fbLoginButton = e.target as fbLoginButton;
            _loginButton.alpha = 0;
            _loginButton.visible = false;

            _connect.login(e);
        }

Если это не поможет, вы, возможно, забыли добавить некоторый код в свой HTML-файл.Обязательно добавьте следующий код в заголовок вашего html-файла: 

<script type="text/javascript" src="http://connect.facebook.net/en_US/all.js"></script>

И вам также нужен div с именем fb-root, объявленный так: 

<body>
    <div id="fb-root"></div>
    <div id="flashContent">
    </div>
</body>
...