Настройка netrw как NERDTree

Question

1. Я использовал nmap <silent> <f2> :NERDTreeToggle<cr> для переключения окна ботанического дерева. Как я могу сделать то же самое с netrw?

2. Окно nerdtree не отображается в списке буферов (:ls). netrw указан в списке буферов. Как я могу сделать это не в списке?

3. :bn работает, но команда :bp не работает в окне netrw. Это ошибка?

Answer 1

Команда Vexplore открывает браузер вертикальных каталогов. Вы можете использовать это, добавив следующий код в ваш файл .vimrc, чтобы переключать вертикальный браузер с помощью Ctrl-E (например):

" Toggle Vexplore with Ctrl-E
function! ToggleVExplorer()
  if exists("t:expl_buf_num")
      let expl_win_num = bufwinnr(t:expl_buf_num)
      if expl_win_num != -1
          let cur_win_nr = winnr()
          exec expl_win_num . 'wincmd w'
          close
          exec cur_win_nr . 'wincmd w'
          unlet t:expl_buf_num
      else
          unlet t:expl_buf_num
      endif
  else
      exec '1wincmd w'
      Vexplore
      let t:expl_buf_num = bufnr("%")
  endif
endfunction
map <silent> <C-E> :call ToggleVExplorer()<CR>

Приведенный выше код пытается постоянно открывать окно проводника с левой стороны экрана; Я использую его с несколькими разделенными вертикальными окнами.

[ДОПОЛНИТЕЛЬНО] Вы можете добавить следующие строки в ваш .vimrc, чтобы улучшить работу с браузером:

" Hit enter in the file browser to open the selected
" file with :vsplit to the right of the browser.
let g:netrw_browse_split = 4
let g:netrw_altv = 1

" Change directory to the current buffer when opening files.
set autochdir

Answer 2

Начиная с netrw v150, есть :Lexplore, который будет переключать окно netrw с левой стороны.

Answer 3

Я только что сделал некоторые улучшения в решении Ника , которое исправляет:

• открывает окно с высотой 100% (независимо от разбиений окна)
• :Lexplore открываетэто слева, :Lexplore! справа
• список каталога текущего файла ( даже в удаленных каталогах )

Поместите эти строки вконец вашего .vimrc:

com!  -nargs=* -bar -bang -complete=dir  Lexplore  call netrw#Lexplore(<q-args>, <bang>0)

fun! Lexplore(dir, right)
  if exists("t:netrw_lexbufnr")
  " close down netrw explorer window
  let lexwinnr = bufwinnr(t:netrw_lexbufnr)
  if lexwinnr != -1
    let curwin = winnr()
    exe lexwinnr."wincmd w"
    close
    exe curwin."wincmd w"
  endif
  unlet t:netrw_lexbufnr

  else
    " open netrw explorer window in the dir of current file
    " (even on remote files)
    let path = substitute(exists("b:netrw_curdir")? b:netrw_curdir : expand("%:p"), '^\(.*[/\\]\)[^/\\]*$','\1','e')
    exe (a:right? "botright" : "topleft")." vertical ".((g:netrw_winsize > 0)? (g:netrw_winsize*winwidth(0))/100 : -g:netrw_winsize) . " new"
    if a:dir != ""
      exe "Explore ".a:dir
    else
      exe "Explore ".path
    endif
    setlocal winfixwidth
    let t:netrw_lexbufnr = bufnr("%")
  endif
endfun

Предлагаемые варианты поведения как NERDTree:

" absolute width of netrw window
let g:netrw_winsize = -28

" do not display info on the top of window
let g:netrw_banner = 0

" tree-view
let g:netrw_liststyle = 3

" sort is affecting only: directories on the top, files below
let g:netrw_sort_sequence = '[\/]$,*'

" use the previous window to open file
let g:netrw_browse_split = 4

Answer 4

На самом деле,

let g:netrw_browse_split = 4
let g:netrw_altv = 1

лучше всего работает для меня.

 *g:netrw_browse_split* when browsing, <cr> will open the file by:
                =0: re-using the same window
                =1: horizontally splitting the window first
                =2: vertically   splitting the window first
                =3: open file in new tab
                =4: act like "P" (ie. open previous window)
                    Note that |g:netrw_preview| may be used
                    to get vertical splitting instead of
                    horizontal splitting.

Я думаю, что лучшее поведение описывается вариантом 4. При нажатии клавиши ввода файл открывается в другом разделении, избегая перенаселения расколов.

Answer 5

Функция переключения

Вот моя версия функции переключения, основанная на ответе Ника. Теперь вы можете использовать горячую клавишу на любой панели , а не только на панели netrw. В версии Ника это вызывает ошибку, также я сделал некоторую очистку кода и переназначил его на Ctrl-O, потому что Ctrl-E по умолчанию используется для прокрутки вниз на одну строку.

" Toggle Vexplore with Ctrl-O
function! ToggleVExplorer()
    if exists("t:expl_buf_num")
        let expl_win_num = bufwinnr(t:expl_buf_num)
        let cur_win_num = winnr()

        if expl_win_num != -1
            while expl_win_num != cur_win_num
                exec "wincmd w"
                let cur_win_num = winnr()
            endwhile

            close
        endif

        unlet t:expl_buf_num
    else
         Vexplore
         let t:expl_buf_num = bufnr("%")
    endif
endfunction

map <silent> <C-O> :call ToggleVExplorer()<CR>

Переменная «t: expl_buf_num» является глобальной для текущей вкладки, поэтому вы можете иметь один проводник для каждой вкладки. Вы можете изменить его на "w: expl_buf_num", если хотите иметь возможность открывать Проводник в каждом окне.

Сохраняйте фокус в Проводнике

Также мне нравится иметь это в моем .vimrc:

" Open file, but keep focus in Explorer
autocmd filetype netrw nmap <c-a> <cr>:wincmd W<cr>