Преобразование элементов XML в атрибуты XML с использованием XSLT

Question

У нас есть текущая система, которая выводит файл XML в следующем формате:

<INVENTORY>
   <ITEM>
      <SERIALNUMBER>something</SERIALNUMBER>
      <LOCATION>something</LOCATION>
      <BARCODE>something</BARCODE>
   </ITEM>
</INVENTORY>

Мне нужно использовать эти данные для загрузки в стандартную сетку .NET 2.0. Но сетке нужен XML в следующем формате:

<INVENTORY>
   <ITEM serialNumber="something" location="something" barcode="something">
   </ITEM>
</INVENTORY>

т.е. дочерние узлы элемента необходимо преобразовать в атрибуты узла элемента.

Кто-нибудь знает, как это можно сделать с помощью XSLT?

Answer 1

Это должно работать:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:template match="INVENTORY">
    <INVENTORY>
      <xsl:apply-templates/>
    </INVENTORY>
  </xsl:template>

  <xsl:template match="ITEM">
    <ITEM>
      <xsl:for-each select="*">
        <xsl:attribute name="{name()}">
          <xsl:value-of select="text()"/>
        </xsl:attribute>

      </xsl:for-each>
    </ITEM>
  </xsl:template>
</xsl:stylesheet>

НТН

Answer 2

Вот, пожалуй, самое простое решение , которое преобразует любые дочерние элементы ITEM в его атрибуты и воспроизводит все остальное, как есть, при преобразовании имен элементов в любые нужные имена атрибутов:

<xsl:stylesheet version="1.0" 
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
<!--                                              --> 
  <xsl:strip-space elements="*"/>

  <xsl:variable name="vrtfNameMapping">
    <item name="SERIALNUMBER" newName="serialNumber"/>
    <item name="LOCATION" newName="location"/>
    <item name="BARCODE" newName="barcode"/>
  </xsl:variable>
 <!--                                              --> 
  <xsl:variable name="vNameMapping" select=
  "document('')/*/xsl:variable[@name='vrtfNameMapping']"/>
<!--                                              --> 

  <xsl:template match="node()|@*">
    <xsl:copy>
      <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
  </xsl:template>
<!--                                              --> 
  <xsl:template match="ITEM/*">
    <xsl:attribute name=
     "{$vNameMapping/*[@name=name(current())]/@newName}">
      <xsl:value-of select="."/>
    </xsl:attribute>
  </xsl:template>
</xsl:stylesheet>

когда вышеуказанное преобразование применяется к предоставленному документу XML :

<INVENTORY>
    <ITEM>
        <SERIALNUMBER>something</SERIALNUMBER>
        <LOCATION>something</LOCATION>
        <BARCODE>something</BARCODE>
    </ITEM>
</INVENTORY>

желаемый результат получен :

<INVENTORY>
   <ITEM serialNumber="something" location="something" barcode="something"/>
</INVENTORY>

Обратите внимание на следующее:

1. Использование правила идентификации

2. Использование <xsl:strip-space elements="*"/>

3. Использование переменной vrtfNameMapping без какой-либо xxx:node-set() функции расширения.

4. Тот факт, что мы обрабатываем любое сопоставление между именем и новым именем, а не только простые строчные буквы.

Answer 3

Эти два шаблона должны сделать это: -

<xsl:template match="ITEM">
   <ITEM serialNumber="{SERIALNUMBER}" location="{LOCATION}" barcode="{BARCODE}" />
</xsl:template>

<xsl:template match="INVENTORY">
   <INVENTORY>
      <xsl:apply-templates />
   </INVENTORY>
</xsl:template>

Answer 4

Если ваш источник выглядит так:

<row><a>1</a><b>2</b></row>

и вы хотите, чтобы это выглядело так:

<row a="1" b="2" />

тогда этот XSLT должен работать:

<xsl:template match="row">
    <row a="{a}" b="{b}" />
</xsl:template>

Answer 5

Это должно сделать это:

  <xsl:for-each select="//ITEM">
    <xsl:element name="ITEM">
      <xsl:attribute name="serialNumber">
        <xsl:value-of select="SERIALNUMBER"/>
      </xsl:attribute>
      <xsl:attribute name="location">
        <xsl:value-of select="LOCATION"/>
      </xsl:attribute>
      <xsl:attribute name="barcode">
        <xsl:value-of select="BARCODE"/>
      </xsl:attribute>
    </xsl:element>
  </xsl:for-each>

Или используя ярлык Дэвида:

<xsl:for-each select="//ITEM">
  <ITEM serialNumber="{SERIALNUMBER}" location="{LOCATION}" barcode="{BARCODE}"/>
</xsl:for-each>