- исходный ответ удален -
Исходя из вашего комментария к моему первоначальному ответу, теперь существует подразумеваемое предположение, что Category_ID является внешним ключом, возможно, в таблице соединений, который не может (по какой-либо причине) быть включенным в начальный запрос отображения - или, что вы просто хотите включить динамическую переменную в сетку, которая будет включена во встроенные вставки, без вмешательства пользователя (то есть физически не позволяя им выбрать самим Category_ID, но этов каком-то качестве он все равно будет динамическим, скажем ... при подаче с URL-адреса var.)
Если все верно, я полагаю, что истинный вопрос ближе к:
МожетCFGRID обновить несколько таблиц / динамических столбцов через CFGRIDUPDATE?
Краткий ответ: Нет
Длинный ответ: Да, но не через CFGRIDUPDATE - скорее, черезCFQUERY и немного больше работы над CFGRID, через привязки CFC и CFAJAXPROXY.
Решение:
1) Вам понадобятся два файла дляэто решение.Файл № 1 - это ваш Компонент, который включает в себя функциональность запроса;мы назовем это cfgrid.cfc
<cfcomponent>
<cfset this.dsn = "gridexample" />
<cffunction name="getUsers" returntype="any" access="remote" output="false">
<cfargument name="page" />
<cfargument name="pageSize" />
<cfargument name="gridsortcolumn" />
<cfargument name="gridsortdirection" />
<cfset var getUsers = 0 />
<cfquery name="getUsers" datasource="#this.dsn#">
SELECT Users.UserID, Users.FirstName, UserCategories.Category_ID
FROM Users
INNER JOIN UserCategories ON (Users.User_ID = UserCategories.UserID)
<cfif arguments.gridsortcolumn neq "" or arguments.gridsortdirection neq "">
order by #arguments.gridsortcolumn# #arguments.gridsortdirection#
</cfif>
</cfquery>
<cfreturn QueryConvertForGrid(getUsers, page, pageSize) />
</cffunction>
<cffunction name="addNewUser" returntype="string" access="remote" output="false">
<cfargument name="fullname" type="string" required="true" />
<cfargument name="category_id" type="numeric" required="true" />
<cfquery datasource="#this.dsn#">
INSERT INTO Users
(
fullname
)
VALUES
(
<cfqueryparam cfsqltype="cf_sql_varchar" value="#arguments.fullname#">
)
</cfquery>
<cfquery name="getPkey" datasource="#this.dsn#">
SELECT Max(User_ID) as PKey
FROM Users
</cfquery>
<cfquery datasource="#this.dsn#">
INSERT INTO UserCategories
(
User_ID,
Category_ID
)
VALUES
(
<cfqueryparam cfsqltype="cf_sql_integer" value="#getPKey.PKey#" />
<cfqueryparam cfsqltype="cf_sql_integer" value="#arguments.category_id#" />
)
</cfquery>
<cfreturn "User Added" />
</cffunction>
<cffunction name="editUser" access="remote">
<cfargument name="gridaction">
<cfargument name="gridrow">
<cfargument name="gridchanged">
</cffunction>
</cfcomponent>
Обратите внимание на следующие ключевые элементы CFC:
a) getUsers () возвращает текущие пользовательские данные вместе с их CategoryID.Вам придется переписать этот запрос, чтобы он соответствовал вашей схеме, но главное - это запрос на заполнение данных, поэтому все данные, необходимые для создания пользователя, также должны присутствовать для его обновления.Это также предполагает, что у вас есть только 1 CategoryID на пользователя (который многие разработчики отменяют, оставляя CategoryID в таблице Users - я оставлю это на ваше усмотрение).
b) addNewUser () принимает ожидаемыеотправка формы / сетки для передачи нового имени - а также category_id - но мы знаем заранее, что не будем просить, чтобы Category_ID был заполнен человеком, вводящим данные формы / сетки-Мы сделаем это программно.Однако конечный результат остается прежним - запрос должен знать оба значения.Для краткости я прекратил <CFTRANSACTION> вызовов, но имейте это в виду - вы собираетесь выполнить три запроса подряд, один из которых (третий) зависит от динамических данных другого (1-й и 2-й)) - так что вам нужно помнить о параллелизме, когда вы будете двигаться вперед с этим типом дизайна.
c) На данный момент игнорируйте editUser () - вам нужно будет заполнить его в какой-то момент--он просто должен существовать, чтобы эта демонстрация работала.
2) Второй файл, который вам понадобится, это внешний интерфейс - сама сетка, назовем ее cfgrid.cfm.
Мы пройдем этот процесс сверху вниз, так как он довольно большой, и каждый кусок кода будет нуждаться в объяснении:
<cfparam name="URL.Category_ID" default=4 />
Первая строка шаблона параметризует переменную URL, которую мы хотимиспользовать для программного обеспечения скрытого назначения новых пользователей.Используйте свой собственный механизм для предоставления динамического Category_ID по мере необходимости.
<cfajaxproxy cfc="cfgrid" jsclassname="dataproxy">
Эта строка заставляет ColdFusion создать объект javascript с именем 'dataproxy' и обернуть его в контейнер, необходимый для обеспечения доступа к основным функциям, которые существуют вCFC, на который вы указываете ... и в этом случае вы указываете на 'cfgrid', который является нашим первым файлом, упомянутым выше (cfgrid.cfc).Следовательно, теперь вы можете с комфортом ожидать, что у вас есть объект javascript с методами getUsers () и addNewUser ().
<html>
<head>
<script type="text/javascript" src="/CFIDE/scripts/ajax/ext/package/toolbar/toolbar.js"></script>
Здесь вы начинаете теги HTML-документа и включаете ссылку на один из Ajaxбиблиотеки, включенные в ColdFusion, файл toolbar.js.
<script type="text/javascript">
var dataproxy = new dataproxy();
dataproxy.setCallbackHandler(handleResult);
function handleResult(response)
{
alert(response);
}
Здесь вы создаете локальный экземпляр объекта dataproxy (помните выше, из вызова <CFAJAXPROXY>) и назначаете обработчик обратного вызова, который указываетв другую функцию JavaScript 'handleResult'.Это процесс, который вы используете при работе с асинхронной связью - фундаментальная часть работы в Ajax.
function init()
{
grid = ColdFusion.Grid.getGridObject("UserGrid");
var gridHead = grid.getView().getHeaderPanel(true);
var tbar = new Ext.Toolbar(gridHead);
tbar.addButton({text:"Add User", handler:onAdd });
}
Эта функция init () создает объекты javascript, необходимые для связи с cfgrid.Вы получаете ссылку на cfgrid через ColdFusion.Grid.getGridObject и оттуда получаете доступ к заголовку сетки, который позволяет вам ориентироваться на панель инструментов, и добавляете кнопку «Добавить пользователя», которую затем программно решаете вызвать новой функцией.когда она нажата ... эта функция называется "onAdd" ...
function onAdd(button,event)
{
ColdFusion.Window.show('addUserWin');
}
Неудивительно, что вот эта функция onAdd (), которая отображает новое окно для добавления пользователя (это окно, котороесодержит поле ввода для полного имени пользователя).
Наконец, для нового окна AddUserWin, описанного выше, потребуется собственная функция для добавления пользователя, поскольку нам нужно будет динамически предоставлять Category_ID - вместо того, чтобыпользователь поставляет его.Итак, addUser () будет делать именно это:
function addUser()
{
var f = document.frmUser;
dataproxy.addNewUser(
f.txtFullname.value,
f.txtCategory_ID.value
);
ColdFusion.Window.hide('addUserWin');
grid.refresh();
}
</script>
</head>
В addUser () мы ссылаемся на <FORM> ниже по его имени (frmUser) и вызываем метод addNewUser () нашего прокси-объекта javascript--который сопоставляет с КФК.Как и ожидалось, ему нужно будет узнать значения нового пользователя, поэтому мы передадим ему значения txtFullname и txtCategory_ID.Мы заканчиваем, пряча окно и обновляя сетку.
Помните, мы теперь асинхронны, поэтому нам не нужно читать результат и отображать его - этот результат будет запущен через обработчик обратного вызова, назначенный выше.в методе handleResult ().
Теперь создайте аргументы, которые будут заполнять совокупность CFGRID:
<cfset args = StructNew() />
<cfset args.name = "UserGrid" />
<cfset args.format = "html" />
<cfset args.bindOnLoad = "true" />
<cfset args.bind = "cfc:cfgrid.getUsers({cfgridpage},{cfgridpagesize},{cfgridsortcolumn},{cfgridsortdirection})" />
<cfset args.selectmode = "edit" />
<cfset args.onchange = "cfc:cfgrid.editUser({cfgridaction},{cfgridrow},{cfgridchanged})" />
Здесь мы: 1. Назовем сетку "UserGrid" (как мы уже говорили по этому имени в javascript выше), 2. Сделать так, чтобы он отображался с использованием html, 3. Сказать, чтобы он связывал свои данные при загрузке страницы, 4. Привязать эти данные через cfgrid.cfc, вызывая getUsers () метод (и передача текущих параметров cfgrid через значения страницы, размера страницы, sortcolumn и sortdirection), 5. сделать его редактируемым и 6. назначить обработчик onChange, если мы также хотим разрешить пользователямизм.Эта последняя часть (к сожалению) необходима, поэтому я не смог ее раздеть для этого примера.
Теперь создайте <CFFORM> и <CFGRID>:
<cfform>
<cfgrid attributeCollection="#args#">
<cfgridcolumn name="User_ID" display="false">
<cfgridcolumn name="Category_ID" display="false">
<cfgridcolumn name="FullName" header="Full Name">
</cfgrid>
</cfform>
Здесь,мы заполняем сетку нашими аргументами, указанными выше, и вы заметите, что мы отображаем только поле «FullName» в сетке, но User_ID и Category_ID все еще присутствуют, и часть набора данных;они просто не отображаются во внешнем интерфейсе.
И последнее, но не менее важное: окно, которое открывается, когда пользователь нажимает кнопку «Добавить нового пользователя», что обеспечивает интерфейс, который нам необходим дляпользовательский ввод, в то же время контролируя (за кулисами), что динамически предоставляется Category_ID:
<cfwindow name="addUserWin" modal="true" resizable="false" title="Add New User">
<form name="frmUser">
<input type="hidden" name="txtCategory_ID" value="<cfoutput>#URL.Category_ID#</cfoutput>" />
<table width="100%">
<tr>
<td>Fullname</td>
<td><input type="text" name="txtFullname" value=""></td>
</tr>
<tr>
<td colspan="2"><input type="button" value="Add User" onclick="javascript:addUser();"></td>
</tr>
</form>
</cfwindow>
Этот вызов CFWINDOW обеспечивает необходимое «всплывающее окно» для инкапсуляции формы.Обратите внимание, что имя формы - frmUser, как мы упоминали выше в коде.Также обратите внимание, что имена полей совпадают (включая их регистр) с тем, что указано в javascript.Эта форма отображает поле Fullname для заполнения пользователем, в то время как Category_ID остается скрытым, но все еще программно управляется вами - через ваш параметр URL в верхней части этого примера кода.Наконец, при нажатии кнопки запускается метод addUser (), который, как вы помните, взаимодействует с объектом javascript, который, в свою очередь, обращается к CFC, и передает ваши данные в базу данных.
Наконец, перед тем, как завершить этот шаблон, не забудьте запустить функцию javascript init ()!
<cfset ajaxOnLoad("init")>
</html>
Надеюсь, это поможет.
Адаптировано из CRUD с форматом cfgrid html (Источник: Анудж Гахар)