Кратко создавая IDictionary <_, obj>

Question

Есть ли более короткий способ создания IDictionary<_,obj>, возможно, без упаковки каждого значения?Это то, что у меня есть.

let values =
  [ "a", box 1
    "b", box "foo"
    "c", box true ]
  |> dict

Dictionary<_,obj>.Add можно назвать без бокса, но я не мог найти способ использовать его, который короче, чем у меня.

IЯ надеюсь на что-то иное, чем определение оператора бокса.

EDIT

Основываясь на предложении Брайана, вот один из способов сделать это, но у него есть свои проблемы.

let values =
  Seq.zip ["a"; "b"; "c"] ([1; "foo"; true] : obj list) |> dict

Answer 1

Вот решение, следуя предложению kvb (возможно, самое краткое и ясное из всех):

let inline (=>) a b = a, box b

let values =
  [ "a" => 1
    "b" => "foo"
    "c" => true ]
  |> dict

Answer 2

Вот самая приятная вещь, которую мне удалось поднять. В нем больше символов, чем в вашей версии для бокса, но, возможно, он выглядит немного менее грязным. Обратите внимание, что ^ является ассоциативным справа (это оператор строки concat, унаследованный от ocaml), что позволяет ему работать как ::, и имеет более сильный приоритет, чем ,, поэтому круглые скобки необходимы для кортежей .

let inline (^+) (x1:'a,x2:'b) (xl:('a*obj) list) = 
    (x1,box x2)::xl

let values =
  ("a", 1) ^+  ("b", "foo") ^+ ("c", true) ^+ []
  |> dict

Answer 3

Вот еще одно «решение», которое вдохновлено предложением Брайана, но использует отражение, так что это требует затрат времени и безопасности.

let unboxPair (pair:obj) =
    let ty = pair.GetType()
    let x = ty.GetProperty("Item1").GetValue(pair,null) :?> string
    let y = ty.GetProperty("Item2").GetValue(pair,null)
    x,y

let unboxPairs (pairs:obj list) =
  pairs |> List.map unboxPair  

let values =
  unboxPairs
    ["a", 1
     "b", "foo"
     "c", true]
  |> dict

Answer 4

У меня была похожая проблема в FsSql, и я просто убрал бокс в функцию:

let inline T (a,b) = a, box b
let values = dict [T("a",1); T("b","foo"); T("c",true)]

Answer 5

Вариант идеи Стивена:

open System
open System.Collections.Generic

type Dictionary<'a,'b> with
  member this.Add([<ParamArray>] args:obj[]) =
    match args.Length with
    | n when n % 2 = 0 ->
      for i in 1..2..(n-1) do
        this.Add(unbox args.[i-1], unbox args.[i])
    | _ -> invalidArg "args" "even number of elements required"

let d = Dictionary<string,obj>()
d.Add(
  "a", 1,
  "b", "foo",
  "c", true
)

Answer 6

Еще одно решение, просто определите группу перегруженных членов расширения на Dictionary<'a,'b>:

open System.Collections.Generic
type Dictionary<'a,'b> with
    member this.Add(x1,y1,x2,y2) =
        this.Add(x1,y1)
        this.Add(x2,y2)
    member this.Add(x1,y1,x2,y2,x3,y3) =
        this.Add(x1,y1,x2,y2)
        this.Add(x3,y3)
    member this.Add(x1,y1,x2,y2,x3,y3,x4,y4) =
        this.Add(x1,y1,x2,y2,x3,y3)
        this.Add(x4,y4)
    member this.Add(x1,y1,x2,y2,x3,y3,x4,y4,x5,y5) =
        this.Add(x1,y1,x2,y2,x3,y3,x4,y4)
        this.Add(x5,y5)
    member this.Add(x1,y1,x2,y2,x3,y3,x4,y4,x5,y5,x6,y6) =
        this.Add(x1,y1,x2,y2,x3,y3,x4,y4,x5,y5)
        this.Add(x6,y6)
    //etc.

let values = 
    let d = Dictionary<_,obj>()
    d.Add("a", 1, 
          "b", "foo", 
          "c", true)
    d

Конечно values здесь не неизменным, как в вашем вопросе, ноЯ уверен, что вы могли бы использовать ту же стратегию для этой цели.

Answer 7

let v : (string*obj) list = [...]
let values = dict v

Это один из способов, подпись типа слева от литерала списка будет автоматически обновлять каждый элемент.