Как мне прочитать текстовый файл и распечатать его в файл в Прологе? - PullRequest
Новая
       28

Как мне прочитать текстовый файл и распечатать его в файл в Прологе?

1 голос
/ 13 ноября 2011

У меня есть текстовый файл, и я хочу прочитать его, распечатать на экране и записать в новый выходной файл. Так что я до сих пор сделал 

main :-
    open('text.txt', read, ID),  % open a stream
    repeat,             % try again forever
    read(ID, X),        % read from the stream
    write(X), nl,       % write to current output stream
    X == end_of_file,   % fail (backtrack) if not end of 
    !,
    close(ID).

Но я получил только сообщение об ошибке типа 

ERROR: text.txt:1:0: Syntax error: Operator expected

Что мне делать?

Ответы [ 3 ]

2 голосов
/ 13 ноября 2011

read/2 читает действительный текст Пролога. Сообщение предполагает, что в строке 1 text.txt у вас есть недопустимый текст Prolog. Может быть, пара слов, разделенных пробелами.

Если вы хотите читать обычный текст, вы можете сделать это на низком уровне, используя get_char/2, или вы можете захотеть сделать это на более высоком уровне, используя грамматики. У SWI-Prolog для этого есть library(pio).

Вот эквивалент программиста Пролога grep -q. 

?- phrase_from_file((...,"root",...),'/etc/passwd').
true ;
true ;
true ;
false.

На самом деле, это скорее grep -c.

Вам нужно загрузить для него следующее определение: 

... --> [] | [_], ... .
1 голос
/ 14 ноября 2011

Если вы хотите использовать повторно используемый фрагмент: 

%%  file_atoms(File, Atom) is nondet.
%
%   read each line as atom on backtrack
%
file_atoms(File, Atom) :-
    open(File, read, Stream),
    repeat,
    read_line_to_codes(Stream, Codes),
    (   Codes \= end_of_file
    ->  atom_codes(Atom, Codes)
    ;   close(Stream), !, fail
    ).

Это вызывает read_line_to_codes, встроенный SWI-Prolog.

0 голосов
/ 13 ноября 2011 
is_eof(FlHndl, CharCode, CurrentLine, FileAkku, FileContent) :-
        CharCode == -1,
        append(FileAkku, [CurrentLine], FileContent),
        close(FlHndl), !.

is_newline(FlHndl, CharCode, CurrentLine, FileAkku, FileContent) :-
        CharCode == 10,
        append(FileAkku, [CurrentLine], NextFileAkku),
        read_loop(FlHndl, '', NextFileAkku, FileContent).

append_char(FlHndl, CharCode, CurrentLine, FileAkku, FileContent) :-
        char_code(Char, CharCode),
        atom_concat(CurrentLine, Char, NextCurrentLine),
         read_loop(FlHndl, NextCurrentLine, FileAkku, FileContent).

read_file(FileName, FileContent) :-
        open(FileName, read, FlHndl),
        read_loop(FlHndl, '', [], FileContent), !.

read_loop(FlHndl, CurrentLine, FileAkku, FileContent) :-
        get_code(FlHndl, CharCode),
        ( is_eof(FlHndl, CharCode, CurrentLine, FileAkku, FileContent)
        ; is_newline(FlHndl, CharCode, CurrentLine, FileAkku, FileContent)
        ; append_char(FlHndl, CharCode, CurrentLine, FileAkku, FileContent)).

main(InputFile, OutputFile) :-
    open(OutputFile, write, OS),
    (   read_file(InputFile,InputLines),
        member(Line, InputLines),
        write(Line), nl,
        write(OS,Line),nl(OS),
        false
        ;
        close(OS)
    ).

Итак, вы можете использовать его как main('text.txt', 'output.txt').

...