XSLT для каждого цикла, фильтр на основе переменной - PullRequest
Новая
       12

XSLT для каждого цикла, фильтр на основе переменной

0 голосов
/ 19 апреля 2011

У меня есть следующий XSLT 

<xsl:param name="productsId" select="/macro/productsId" />
<xsl:param name="type" select="/macro/type" /> <!-- value1, value2, value3 -->

<xsl:template match="/">
    <xsl:if test="$productsId > 0">
        <xsl:variable name="products" select="umbraco.library:GetXmlNodeById($productsId)" />
        <div id="carousel-wrap">
          <ul id="carousel">
          <xsl:for-each select="$products/Product [select only Product with attribute value1, value2 or value3 based on /macro/type]">
            <li id="p-{@id}">
              <xsl:variable name="title">
                <xsl:choose>
                  <xsl:when test="string-length(productHeading) > 0">
                    <xsl:value-of select="productHeading" />
                  </xsl:when>
                  <xsl:otherwise>
                    <xsl:value-of select="@nodeName" />
                  </xsl:otherwise>
                </xsl:choose>
              </xsl:variable>
              <a href="{umbraco.library:NiceUrl(@id)}">
                <!-- Image -->
                <xsl:if test="productImage > 0">
                  <xsl:variable name="productImage" select="umbraco.library:GetMedia(productImage, 0)" />
                  <img src="/ImageGen.ashx?image={$productImage/umbracoFile}&amp;height=131" />
                </xsl:if>

                <!-- Title -->
                <span><xsl:value-of select="$title" disable-output-escaping="yes" /></span>
              </a>
            </li>
          </xsl:for-each>
          </ul>
        </div>
    </xsl:if>
</xsl:template>

По сути, каждый продукт содержит 3 атрибута со значениями true / false. 

value1 = true
value2 = false
value3 = true

Теперь я передаю в таблицу стилей параметр, который будет одним из этих значений, т. Е. Value3.

Я хотел бы выбрать все узлы, для которых value3 установлено в true . Что-то вроде: 

<xsl:for-each 
    select="$products/Product [$type = 'true' (or $type = '1' in XSLT terms)]">

Есть идеи о том, как это можно сделать?

1 Ответ

6 голосов
/ 19 апреля 2011

Я думаю, вы ищете что-то вроде этого: 

<xsl:for-each select=
    "$products/Product[@*[name()=$type and (.='true' or .='1')]]">

Обратите внимание, что использование for-each редко необходимо.Рассмотрим следующую таблицу стилей: 

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:param name="type" select="'value3'" />
    <xsl:template match="/">
        <xsl:apply-templates
            select="/*/product[@*[name()=$type and (.='true' or .='1')]]" />
    </xsl:template>
    <xsl:template match="product">
        <xsl:value-of select="@id" />
        <xsl:text>&#xA;</xsl:text>
    </xsl:template>
</xsl:stylesheet>

Применяется к этому входу: 

<products>
    <product id="1" value1="false" value2="false" value3="false"/>
    <product id="2" value1="false" value2="true" value3="false"/>
    <product id="3" value1="false" value2="false" value3="true"/>
    <product id="4" value1="false" value2="false" value3="true"/>
    <product id="5" value1="true" value2="false" value3="false"/>
    <product id="6" value1="false" value2="false" value3="true"/>
</products>

Производит: 

3
4
6
...