В Фортране 90 нужно ли объявлять размеры массивов заранее? - PullRequest
Новая
       7

В Фортране 90 нужно ли объявлять размеры массивов заранее?

5 голосов
/ 28 июня 2011

Нужно ли объявлять размеры массива перед любым другим кодом? Например, я написал следующий упрощенный пример кода: 

PROGRAM mytest
  IMPLICIT NONE
  INTEGER :: i, j, k, mysum

  ! Let array c be a k-by-k**2 array
  ! Determine k within the program by some means...for example,
  mysum=0
  DO i=1, 3
    mysum=mysum+1
  END DO
  k=mysum

  REAL, DIMENSION(k, k**2) :: c

  WRITE(*,*) "k=", k
  WRITE(*,*) "k**2=", k**2
  WRITE(*,*)
  DO i=1,size(c,1)
    WRITE(*,"(100(3X,F3.1))") (c(i,j), j=1,size(c,2))
  END DO
END PROGRAM mytest

Я хочу подчеркнуть, что я хотел бы создать массив c размером k -by- k**2, а k определяется только другими вычислениями в коде. ; k неизвестно в самом начале.

Но приведенный выше код выдает мне следующее сообщение об ошибке во время компиляции: 

mytest.f90:13.31:

  REAL, DIMENSION(k, k**2) :: c
                               1
Error: Unexpected data declaration statement at (1)

где строка 13 в моем коде - это строка, где я наконец объявляю c: REAL, DIMENSION(k, k**2) :: c.

С другой стороны, если я вместо этого объявлю k и укажу его размеры заранее, 

PROGRAM mytest
  IMPLICIT NONE
  INTEGER :: i, j, k, mysum
  REAL, DIMENSION(3,9) :: c

  ! Let array c be a k-by-k**2 array
  ! Determine k within the program by some means...for example,
  mysum=0
  DO i=1, 3
    mysum=mysum+1
  END DO
  k=mysum

  WRITE(*,*) "k=", k
  WRITE(*,*) "k**2=", k**2
  WRITE(*,*)
  DO i=1,size(c,1)
    WRITE(*,"(100(3X,F3.1))") (c(i,j), j=1,size(c,2))
  END DO
END PROGRAM mytest

Я получаю правильный вывод: 

 k=           3
 k**2=           9

   0.0   0.0   0.0   0.0   0.0   0.0   0.0   0.0   0.0
   0.0   0.0   0.0   0.0   0.0   0.0   0.0   0.0   0.0
   0.0   0.0   0.0   0.0   0.0   0.0   0.0   0.0   0.0

Но, поскольку я не знаю k заранее, я не могу сделать именно это в моем реальном коде. Есть ли какой-то способ «объявить» массив c изначально, без указания его размеров, а затем позже указать размеры, как только значение k станет известно?

1 Ответ

11 голосов
/ 28 июня 2011

Вы хотите использовать размещаемые массивы: 

PROGRAM mytest
  IMPLICIT NONE
  INTEGER :: i, j, k, mysum
  REAL, DIMENSION(:,:), allocatable :: c   !<-  c is allocatable, rank 2

  ! Let array c be a k-by-k**2 array
  ! Determine k within the program by some means...for example,
  mysum=0
  DO i=1, 3
    mysum=mysum+1
  END DO
  k=mysum

  WRITE(*,*) "k=", k
  WRITE(*,*) "k**2=", k**2
  WRITE(*,*)

  allocate(c(k,k**2))                  ! <-- allocate array c with supplied shape

  DO i=1,size(c,1)
    WRITE(*,"(100(3X,F3.1))") (c(i,j), j=1,size(c,2))
  END DO

  deallocate(c)                        ! <-- deallocate when done
END PROGRAM mytest
...