Как применить фильтр к двум шаблонам - PullRequest
Новая
       0

Как применить фильтр к двум шаблонам

0 голосов
/ 10 января 2012

В другой теме другой разработчик помог мне, предоставив отличный ответ ниже.

В основном два шаблона используются для извлечения всех данных, которые мне нужно представить в моей таблице.

Теперь у меня вопрос: как применить фильтр, который будет фильтровать оба шаблона?Я могу успешно использовать xsl:value-of select="@Name[contains(.,NameIWant1)]" в xsl:template match="SubGroup", но не могу понять, как применить его к xsl:template match="Data".Я пытался использовать различные способы имен безрезультатно.

Заранее спасибо, ребята, вы мне очень помогли в изучении XSLT !!кг

Пример XML 

<?xml-stylesheet type="text/xsl" href="Sample.xsl"?>
<DataView Client="Client1" ID="1000" TimeStamp="12/7/2011 5:35:09 PM">
<Group ID="5000" Name="GroupName1">
<SubGroup ID="7000" Order="0" Name="NameIWant1">
<Data ID="1" Name="DataName1" Order="0">1</Data>
<Data ID="2" Name="DataName2" Order="0">2</Data>
<Data ID="3" Name="DataName3" Order="0">3</Data>
<Data ID="12" Name="DataName4" Order="0">4</Data>
</SubGroup>
<SubGroup ID="8000" Order="0" Name="NameIWant2">
<Data ID="1" Name="DataName1" Order="0">6</Data>
<Data ID="2" Name="DataName2" Order="0">7</Data>
<Data ID="3" Name="DataName3" Order="0">8</Data>
<Data ID="12" Name="DataName4" Order="0">9</Data>
</SubGroup>
</Group>
</DataView>

Sample.xslt: 

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" indent="yes" omit-xml-declaration="yes"/>
    <xsl:strip-space elements="*"/>
    <xsl:template match="/">
        <html>
            <body>
                <h2>My Data</h2>
                <table border="1">
                    <tr bgcolor="#9acd32">
                        <th>Subgroup</th>
                        <th>DataName1</th>
                        <th>DataName2</th>
                        <th>DataName3</th>
                        <th>DataName4</th>
                    </tr>
                    <xsl:apply-templates/>
                </table>
            </body>
        </html>
    </xsl:template>
    <xsl:template match="SubGroup">
        <tr>
            <td><xsl:value-of select="@Name"/></td>
            <xsl:apply-templates/>
        </tr>
    </xsl:template>
    <xsl:template match="Data">
        <td><xsl:apply-templates/></td>
    </xsl:template>
</xsl:stylesheet>

Я получил это ... 

____________________________
NameIWant1 | 1 | 2 | 3 | 4 |
           | 6 | 7 | 8 | 9 |

Я хотел быполучить .. 

____________________________
NameIWant1 | 1 | 2 | 3 | 4 |

1 Ответ

0 голосов
/ 11 января 2012

Самый простой способ отфильтровать SubGroup по имени - переместить выражение в шаблон совпадения, например: 

<xsl:template match="SubGroup[contains(@Name, 'NameIWant1')]">
    <tr>
        <td><xsl:value-of select="@Name"/></td>
        <xsl:apply-templates/>
    </tr>
</xsl:template>

И затем игнорируйте все другие SubGroup элементы с пустым шаблоном: 

<xsl:template match="SubGroup"/>

Полная таблица стилей: 

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" indent="yes" omit-xml-declaration="yes"/>
    <xsl:strip-space elements="*"/>
    <xsl:template match="/">
        <html>
            <body>
                <h2>My Data</h2>
                <table border="1">
                    <tr bgcolor="#9acd32">
                        <th>Subgroup</th>
                        <th>DataName1</th>
                        <th>DataName2</th>
                        <th>DataName3</th>
                        <th>DataName4</th>
                    </tr>
                    <xsl:apply-templates/>
                </table>
            </body>
        </html>
    </xsl:template>
    <xsl:template match="SubGroup[contains(@Name, 'NameIWant1')]">
        <tr>
            <td><xsl:value-of select="@Name"/></td>
            <xsl:apply-templates/>
        </tr>
    </xsl:template>
    <xsl:template match="SubGroup"/>
    <xsl:template match="Data">
        <td><xsl:apply-templates/></td>
    </xsl:template>
</xsl:stylesheet>
Добро пожаловать на сайт PullRequest, где вы можете задавать вопросы и получать ответы от других членов сообщества.

Нет похожих вопросов

...