Как конвертировать int в строку на Arduino?

Question

Как преобразовать int, n, в строку, чтобы при отправке через последовательный порт она отправлялась как строка?

Это то, что я имею до сих пор:

int ledPin=13;
int testerPin=8;
int n=1;

char buf[10];

void setup()
{
    pinMode(ledPin, OUTPUT);
    pinMode(testerPin, OUTPUT);
    Serial.begin(115200);
}

void loop()
{
    digitalWrite(ledPin, HIGH);
    sprintf(buf, "Hello!%d", n);
    Serial.println(buf);
    delay(500);
    digitalWrite(ledPin, LOW);
    delay(500);

    n++;
}

Answer 1

Используйте как это:

String myString = String(n);

Вы можете найти больше примеров здесь .

Answer 2

используйте функцию itoa(), включенную в stdlib.h

char buffer[7];         //the ASCII of the integer will be stored in this char array
itoa(-31596,buffer,10); //(integer, yourBuffer, base)

Answer 3

Вы можете просто сделать:

Serial.println(n);

, которая автоматически преобразует n в строку ASCII.См. документацию для Serial.println().

Answer 4

Вам просто нужно обернуть его вокруг объекта String следующим образом:

String numberString = String(n);

Вы также можете сделать:

String stringOne = "Hello String";                     // using a constant String
String stringOne =  String('a');                       // converting a constant char into a String
String stringTwo =  String("This is a string");        // converting a constant string into a String object
String stringOne =  String(stringTwo + " with more");  // concatenating two strings
String stringOne =  String(13);                        // using a constant integer
String stringOne =  String(analogRead(0), DEC);        // using an int and a base
String stringOne =  String(45, HEX);                   // using an int and a base (hexadecimal)
String stringOne =  String(255, BIN);                  // using an int and a base (binary)
String stringOne =  String(millis(), DEC);             // using a long and a base

Answer 5

Это оптимизированное по скорости решение для преобразования int (16-разрядное целое число со знаком) в строку.

В этой реализации не используется деление, поскольку 8-разрядный AVR, используемый для Arduino, не имеет аппаратной инструкции DIV, переводит компиляторделение на трудоемкие повторяющиеся вычитания.Таким образом, самым быстрым решением является использование условных ветвей для построения строки.

Фиксированный 7-байтовый буфер, подготовленный с начала в ОЗУ, чтобы избежать динамического выделения.Поскольку это всего 7 байт, стоимость использования фиксированной оперативной памяти считается минимальной.Чтобы помочь компилятору, мы добавляем модификатор регистра в объявление переменной для ускорения выполнения.

char _int2str[7];
char* int2str( register int i ) {
  register unsigned char L = 1;
  register char c;
  register boolean m = false;
  register char b;  // lower-byte of i
  // negative
  if ( i < 0 ) {
    _int2str[ 0 ] = '-';
    i = -i;
  }
  else L = 0;
  // ten-thousands
  if( i > 9999 ) {
    c = i < 20000 ? 1
      : i < 30000 ? 2
      : 3;
    _int2str[ L++ ] = c + 48;
    i -= c * 10000;
    m = true;
  }
  // thousands
  if( i > 999 ) {
    c = i < 5000
      ? ( i < 3000
          ? ( i < 2000 ? 1 : 2 )
          :   i < 4000 ? 3 : 4
        )
      : i < 8000
        ? ( i < 6000
            ? 5
            : i < 7000 ? 6 : 7
          )
        : i < 9000 ? 8 : 9;
    _int2str[ L++ ] = c + 48;
    i -= c * 1000;
    m = true;
  }
  else if( m ) _int2str[ L++ ] = '0';
  // hundreds
  if( i > 99 ) {
    c = i < 500
      ? ( i < 300
          ? ( i < 200 ? 1 : 2 )
          :   i < 400 ? 3 : 4
        )
      : i < 800
        ? ( i < 600
            ? 5
            : i < 700 ? 6 : 7
          )
        : i < 900 ? 8 : 9;
    _int2str[ L++ ] = c + 48;
    i -= c * 100;
    m = true;
  }
  else if( m ) _int2str[ L++ ] = '0';
  // decades (check on lower byte to optimize code)
  b = char( i );
  if( b > 9 ) {
    c = b < 50
      ? ( b < 30
          ? ( b < 20 ? 1 : 2 )
          :   b < 40 ? 3 : 4
        )
      : b < 80
        ? ( i < 60
            ? 5
            : i < 70 ? 6 : 7
          )
        : i < 90 ? 8 : 9;
    _int2str[ L++ ] = c + 48;
    b -= c * 10;
    m = true;
  }
  else if( m ) _int2str[ L++ ] = '0';
  // last digit
  _int2str[ L++ ] = b + 48;
  // null terminator
  _int2str[ L ] = 0;  
  return _int2str;
}

// Usage example:
int i = -12345;
char* s;
void setup() {
  s = int2str( i );
}
void loop() {}

Этот эскиз скомпилирован в 1082 байта кода с использованием avr-gcc, который связан с Arduino v1.0.5 (размер самой функции int2str составляет 594 байта).По сравнению с решением, использующим объект String, который скомпилирован в 2398 байт, эта реализация может уменьшить размер вашего кода на 1,2 Кб (предполагается, что вам не нужен другой метод объекта String, а ваш номер строго соответствует типу int со знаком).

Эту функцию можно оптимизировать, написав ее в соответствующем коде ассемблера.

Answer 6

Решение слишком велико.Попробуйте это просто.Пожалуйста, предоставьте 7+ ​​символьный буфер, проверка не сделана.

char *i2str(int i, char *buf){
  byte l=0;
  if(i<0) buf[l++]='-';
  boolean leadingZ=true;
  for(int div=10000, mod=0; div>0; div/=10){
    mod=i%div;
    i/=div;
    if(!leadingZ || i!=0){
       leadingZ=false;
       buf[l++]=i+'0';
    }
    i=mod;
  }
  buf[l]=0;
  return buf;
}

Может быть легко изменен, чтобы получить конец буфера, если вы отбросите индекс 'l' и увеличите буфер напрямую.

Answer 7

Serial.println(val) 
Serial.println(val, format)

подробнее вы можете посетить на сайте Arduino https://www.arduino.cc/en/Serial/Println

желаю, чтобы это тебе помогло. спасибо!

Answer 8

Здесь ниже - самосоставленный myitoa (), который намного меньше в коде и резервирует массив FIXED из 7 (включая завершающий 0) в char * mystring, что часто желательно.Очевидно, что вместо этого можно создать код с символьным сдвигом, если нужна выходная строка переменной длины.

void myitoa(int number, char *mystring) {
  boolean negative = number>0;

  mystring[0] = number<0? '-' : '+';
  number = number<0 ? -number : number;
  for (int n=5; n>0; n--) {
     mystring[n] = ' ';
     if(number > 0) mystring[n] = number%10 + 48;
     number /= 10;
  }  
  mystring[6]=0;
}

Answer 9

в первом примере используется классическая строка C: это просто массив символов, оканчивающихся на ноль (символ NUL). другие примеры используют класс String, класс C ++, от которого я буду руководствоваться далеко, за исключением игрушечных примеров и крошечных демонстраций. Это приводит к утечке памяти способами, которые не так легко предсказать, и приводит к таинственным блокировкам платы.