Нужна функция SQL для последовательной последовательности

Question

Может ли кто-нибудь предоставить функцию SQL, которая вводит строку и выводит следующую инкрементную строку в соответствии со следующей последовательностью?

000000
000001
.
.
000009
00000A
.
.
00000Z
.
.
.
000010
000011
.
.
000019
00001A
.
.
zzzzzz

Answer 1

Если вы можете использовать функцию PL / SQL, вы можете попробовать что-то вроде функции next_step в этом блоке, которая увеличивается на произвольный набор цифр.

DECLARE
    i integer;
    seqnum varchar2(20) := '00';
    ----------------------------------------
    function next_step(seq_num varchar2) return varchar2 is
        digits varchar2(20) := '012ABC';
        last_digit   varchar2(1) := substr(seq_num, length(seq_num), 1);
        other_digits varchar2(20) := substr(seq_num, 1, length(seq_num) -1);
        -- value of last digit
        last_digit_value number(5) := instr(digits, last_digit) - 1;
    BEGIN
        if seq_num is null then
           return substr(digits, 2, 1);
        end if;
        -- increment the digit; roll if needed.
        last_digit_value := last_digit_value + 1;
        -- "digits||digits" makes the roll easy.
        last_digit := substr(digits||digits, last_digit_value + 1, 1);
        if last_digit_value >= length(digits) then
          -- roll over
          other_digits := next_step(other_digits);
        end if;
        return other_digits||last_digit;
    END next_step;
    ----------------------------------------
BEGIN
    dbms_output.enable(null);
    dbms_output.put_line(seqnum);
    for i in 1 .. 50 loop
        seqnum := next_step(seqnum);
        dbms_output.put_line(' -> '||seqnum);
    end loop;
END;
/

Это дает следующее:

00
 -> 01
 -> 02
 -> 0A
 -> 0B
 -> 0C
 -> 10
 -> 11
 -> 12
 -> 1A
 -> 1B
 -> 1C
 -> 20
 -> 21
 -> 22
...
 -> C2
 -> CA
 -> CB
 -> CC
 -> 100
 -> 101
 -> 102
 ...
 -> 121
 -> 122