Уровень ошибки команды «Выбор» командного файла возвращает 0 - PullRequest
Новая
       37

Уровень ошибки команды «Выбор» командного файла возвращает 0

7 голосов
/ 23 декабря 2011

Я пытаюсь создать командный файл, который выполняет другую команду «выбор» в зависимости от версии Windows, на которой выполняется. Синтаксис команды выбора отличается в Windows 7 и Windows XP.

Команда выбора возвращает 1 для Y и 2 для N. Следующая команда возвращает правильный уровень ошибки:

Windows 7: 

choice /t 5 /d Y /m "Do you want to automatically shutdown the computer afterwards "
echo %errorlevel%
if '%errorlevel%'=='1' set Shutdown=T
if '%errorlevel%'=='2' set Shutdown=F

Windows XP: 

choice /t:Y,5 "Do you want to automatically shutdown the computer afterwards "
echo %ERRORLEVEL%
if '%ERRORLEVEL%'=='1' set Shutdown=T
if '%ERRORLEVEL%'=='2' set Shutdown=F

Однако, когда он комбинируется с командой для определения версии ОС Windows, уровень ошибки возвращает 0 перед AN после команды выбора в моих блоках кода как для Windows XP, так и для Windows 7. 

REM Windows XP
ver | findstr /i "5\.1\." > nul
if '%errorlevel%'=='0' (
set errorlevel=''
echo %errorlevel%
choice /t:Y,5 "Do you want to automatically shutdown the computer afterwards "
echo %ERRORLEVEL%
if '%ERRORLEVEL%'=='1' set Shutdown=T
if '%ERRORLEVEL%'=='2' set Shutdown=F
echo.
)

REM Windows 7
ver | findstr /i "6\.1\." > nul
if '%errorlevel%'=='0' (
set errorlevel=''
echo %errorlevel%
choice /t 5 /d Y /m "Do you want to automatically shutdown the computer afterwards "
echo %errorlevel%
if '%errorlevel%'=='1' set Shutdown=T
if '%errorlevel%'=='2' set Shutdown=F
echo.
)

Как видите, я даже пытался очистить уровень ошибки var перед выполнением команды выбора, но уровень ошибки остается равным 0 после выполнения команды выбора.

Какие-нибудь советы? Спасибо!

1 Ответ

14 голосов
/ 23 декабря 2011

Вы столкнулись с классической проблемой - Вы пытаетесь развернуть %errorlevel% в заключенном в скобки блоке кода. Эта форма расширения происходит во время разбора, но вся конструкция IF анализируется сразу, поэтому значение %errorlevel% не изменится.

Решение простое - отсроченное расширение. Вам нужно SETLOCAL EnableDelayedExpansion вверху, а затем использовать !errorlevel!. Отложенное расширение происходит во время выполнения, поэтому вы можете увидеть изменения значения в круглых скобках.

Справка по SET (SET /?) описывает проблему и решение в отношении оператора FOR, но концепция та же.

У вас есть другие варианты.

Вы можете переместить код из тела IF в помеченные разделы кода без скобок и использовать GOTO или CALL для доступа к коду. Тогда вы можете использовать %errorlevel%. Мне не нравится эта опция, потому что CALL и GOTO относительно медленные, а код менее элегантный.

Другой вариант - использовать IF ERRORLEVEL N вместо IF !ERRORLEVEL!==N. (См. IF /?). Так как IF ERRORLEVEL N проверяет, равен ли уровень ошибки> = N, вам необходимо выполнять тесты в порядке убывания. 

REM Windows XP
ver | findstr /i "5\.1\." > nul
if '%errorlevel%'=='0' (
  choice /t:Y,5 "Do you want to automatically shutdown the computer afterwards "
  if ERRORLEVEL 2 set Shutdown=F
  if ERRORLEVEL 1 set Shutdown=T
)
...