Простой анализ JSON с использованием Perl

Question

Я пытаюсь проанализировать результаты Facebook Graph API JSON, и у меня возникли некоторые проблемы с этим.

Я надеялся напечатать номеракций:

my $trendsurl = "https://graph.facebook.com/?ids=http://www.filestube.com";
my $json;
{
  local $/; #enable slurp
  open my $fh, "<", $trendsurl;
  $json = <$fh>;
}

my $decoded_json = @{decode_json{shares}};
print $decoded_json;

Answer 1

Часть приведенного выше кода чрезвычайно озадачивает.Я только что переписал его с аннотациями для вас.

#!/usr/bin/perl

use LWP::Simple;                # From CPAN
use JSON qw( decode_json );     # From CPAN
use Data::Dumper;               # Perl core module
use strict;                     # Good practice
use warnings;                   # Good practice

my $trendsurl = "https://graph.facebook.com/?ids=http://www.filestube.com";

# open is for files.  unless you have a file called
# 'https://graph.facebook.com/?ids=http://www.filestube.com' in your
# local filesystem, this won't work.
#{
#  local $/; #enable slurp
#  open my $fh, "<", $trendsurl;
#  $json = <$fh>;
#}

# 'get' is exported by LWP::Simple; install LWP from CPAN unless you have it.
# You need it or something similar (HTTP::Tiny, maybe?) to get web pages.
my $json = get( $trendsurl );
die "Could not get $trendsurl!" unless defined $json;

# This next line isn't Perl.  don't know what you're going for.
#my $decoded_json = @{decode_json{shares}};

# Decode the entire JSON
my $decoded_json = decode_json( $json );

# you'll get this (it'll print out); comment this when done.
print Dumper $decoded_json;

# Access the shares like this:
print "Shares: ",
      $decoded_json->{'http://www.filestube.com'}{'shares'},
      "\n";

Запустите его и проверьте вывод.Вы можете закомментировать строку print Dumper $decoded_json;, когда поймете, что происходит.

Answer 2

Как насчет использования команды CURL вместо этого?(PS: это работает в Windows; внесите изменения CURL для систем Unix).

   $curl=('C:\\Perl64\\bin\\curl.exe -s http://graph.facebook.com/?ids=http://www.filestube.com');
    $exec=`$curl`;
    print "Output is::: \n$exec\n\n";

    ## match the string "shares": in the CURL output
    if ($exec=~/"shares":?/)
    { 
        print "Output is::: \n$exec\n\n";
        ## string after the match (any string on the right side of "shares":)
        $shares=$'; 
        ## delete all non-Digit characters after the share number
        $shares=~s/(\D.*)//; 
        print "Number of Shares is: ".$shares."\n";
    } else {
        print "No Share Information available.\n"
    }

---

ВЫХОД:

---

Вывод: ::: {"http://www.msn.com":{"id":"http://www.msn.com","shares":331357,"comments":19}}

Количество акций: 331357

---