Воспроизведение звука, передача URL на флэш

Question

Если у меня есть URL-адрес в mp3, могу ли я каким-то образом передать его во флэш-файл, чтобы он воспроизводил его?Как я мог это сделать?

Answer 1

Пример из ActionScript Reference :

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.media.Sound;
    import flash.media.SoundChannel;
    import flash.net.URLRequest;

    public class SoundExample extends Sprite {
        private var url:String = "MySound.mp3";
        private var song:SoundChannel;

        public function SoundExample() {
            var request:URLRequest = new URLRequest(url);
            var soundFactory:Sound = new Sound();
            soundFactory.addEventListener(Event.COMPLETE, completeHandler);
            soundFactory.addEventListener(Event.ID3, id3Handler);
            soundFactory.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            soundFactory.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            soundFactory.load(request);
            song = soundFactory.play();
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function id3Handler(event:Event):void {
            trace("id3Handler: " + event);
        }

        private function ioErrorHandler(event:Event):void {
            trace("ioErrorHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler: " + event);
        }
    }
}

Вы можете комбинировать вышеприведенное с параметрами LoaderInfo : это flashvars, переданный html илиПараметры в URL используются для вызова SWF.

В ссылке много хороших примеров, в основном я узнал Actionscript от gotoandlearn.com и ссылка .

Answer 2

Вы можете установить передачу URL в SWF при загрузке, установив flashvar.Вы можете установить flashvars двумя способами .. используя элемент param в вашем коде для встраивания или вы можете просто добавить их к URL-адресу swf, результат будет таким же.

http://blog.six4rty.ch/tutorials/flash-flashvars-in-as3/

Если вы не знаете URL-адрес mp3 при загрузке SWF-файла, вы должны использовать методы ActionScript ExternalInterface для регистрации некоторых функций ActionScript, чтобы вы могли вызывать их из JavaScript веб-страницы.Таким образом, в вашем флэш-фильме вы могли бы

function setSrc( mp3URL ) { ... }
function play(){ ... }
function stop(){ ... }

зарегистрировать каждый из них с помощью внешнего интерфейса

ExternalInterface.addCallback( 'setSrc', setSrc ); 
ExternalInterface.addCallback( 'play', play ); 
ExternalInterface.addCallback( 'stop', stop ); 

Теперь вы можете использовать их из JavaScript.