Получить конкретное слово в тексте на странице HTML - PullRequest
Новая
       49

Получить конкретное слово в тексте на странице HTML

1 голос
/ 07 июля 2011

Если у меня есть следующая HTML-страница 

<div>
 <p> 
  Hello world!
 </p>
 <p> <a href="example.com"> Hello and Hello again this is an example</a></p>
</div>

Я хочу получить определенное слово, например, «привет», и изменить его на «добро пожаловать», где бы они ни находились в документе

Есть ли у вас предложения?Я буду рад получить ваши ответы независимо от того, какой тип парсера вы используете?

1 Ответ

1 голос
/ 08 июля 2011

Это легко сделать с помощью XSLT.

Решение XSLT 1.0 : 

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:xs="http://www.w3.org/2001/XMLSchema">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/> 

 <xsl:param name="pTarget" select="'hello'"/>
 <xsl:param name="pReplacement" select="'welcome'"/>

 <xsl:variable name="vtargetLength" select=
 "string-length($pTarget)"/>

 <xsl:variable name="vUpper" select=
  "'ABCDEFGHIJKLMNOPQRSTUVWXYZ'"/>
 <xsl:variable name="vLower" select=
  "'abcdefghijklmnopqrstuvwxyz'"/>

 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="text()" name="replace">
  <xsl:param name="pText" select="."/>

  <xsl:variable name="vLowerText" select=
  "translate($pText,$vUpper,$vLower)"/>

  <xsl:choose>
   <xsl:when test=
   "not(contains(concat(' ', $vLowerText, ' '),
                 concat(' ',$pTarget,' ')
                 )
        )">
    <xsl:value-of select="$pText"/>
   </xsl:when>

   <xsl:otherwise>
    <xsl:variable name="vOffset" select=
    "string-length(
          substring-before(concat(' ', $vLowerText, ' '),
                           concat(' ', $pTarget,' ')
                           )
                   )"/>
    <xsl:value-of select="substring($pText, 1, $vOffset)"/>
    <xsl:value-of select="$pReplacement"/>

    <xsl:call-template name="replace">
      <xsl:with-param name="pText" select=
      "substring($pText, $vOffset + $vtargetLength+1)"/>
    </xsl:call-template>
   </xsl:otherwise>
  </xsl:choose> 
 </xsl:template>
</xsl:stylesheet>

, когда это преобразование применяется к предоставленному документу XML : 

<div>
 <p>
  Hello world!
 </p>
 <p> <a href="example.com"> Hello and Hello again this is an example</a></p>
</div>

желаемый, правильный результат получен : 

<div>
   <p>
  welcome world!
 </p>
   <p>
      <a href="example.com"> welcome and welcome again this is an example</a>
   </p>
</div>

Я предполагаю, что при сопоставлении и замене регистр не учитывается (т.е.hello "и" heLlo "должны быть заменены на" welcome ").Если требуется регистрозависимое соответствие, преобразование может быть значительно упрощено.

Решение XSLT 2.0 : 

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:xs="http://www.w3.org/2001/XMLSchema">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:param name="pTarget" select="'hello'"/>
 <xsl:param name="pReplacement" select="'welcome'"/>

 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="text()[matches(.,$pTarget, 'i')]">
   <xsl:variable name="vEnlargedRep" select=
   "replace(concat(' ',.,' '),
            concat(' ',$pTarget,' '),
            concat(' ',$pReplacement,' '),
             'i')"/>
    <xsl:variable name="vLen" select="string-length($vEnlargedRep)"/>

    <xsl:sequence select=
     "substring($vEnlargedRep,2, $vLen -2)"/>
 </xsl:template>
</xsl:stylesheet>

, когда применяется это преобразованиев предоставленном XML-документе (показанном выше) снова выдается желаемый, правильный результат : 

<div>
   <p>
  welcome world!
 </p>
   <p> 
      <a href="example.com"> welcome and welcome again this is an example</a>
   </p>
</div>

Пояснение : использование стандартных функций XPath 2.0 matches() и replace() с указанием в качестве третьего аргумента "i" - флаг для операции без учета регистра.

...