Как создать следующий файл или папку в серии файлов с последовательным номером?

Question

Извините за плохой титул, но это лучшее, что я мог сделать! : D

У меня есть скрипт, который создает новый проект при каждом вызове указанной функции.

Каждый проект должен храниться в отдельной папке с названием проекта. Но если вы не укажете имя, скрипт просто назовет его «новый проектX», где X - прогрессивное число.

Со временем пользователь может переименовывать папки или удалять некоторые из них, поэтому при каждом запуске скрипта он проверяет наименьшее доступное число (не используемое другой папкой) и создает соответствующую папку.

Теперь мне удалось создать программу, которая, как мне кажется, работает как хотелось бы, но я хотел бы услышать от вас, если все в порядке или что-то не так, что я не могу обнаружить, учитывая мою неопытность в языке.

    while ( defined( $file = readdir $projects_dir ) )
    {
        # check for files whose name start with "new project"
        if ( $file =~ m/^new project/i )
        {
            push( @files, $file );
        }
    }

    # remove letters from filenames, only the number is left
    foreach $file ( @files )
    {
        $file =~ s/[a-z]//ig;
    }

    @files = sort { $a <=> $b } @files;

    # find the smallest number available
    my $smallest_number = 0;

    foreach $file ( @files )
    {
        if ( $smallest_number != $file )
        {
            last;
        }
        $smallest_number += 1;
    }

    print "Smallest number is $smallest_number";

Answer 1

Вот базовый подход для решения такой проблемы:

sub next_available_dir {
    my $n = 1;
    my $d;
    $n ++ while -e ($d = "new project$n");
    return $d;
}

my $project_dir = next_available_dir();
mkdir $project_dir;

Если вы хотите использовать шаблон именования, который прекрасно сочетается с функцией автоматического увеличения строки * в Perl *, вы можете еще больше упростить код, устраняя необходимость в $n. Например, newproject000.

Answer 2

Я думаю, я бы использовал что-то вроде:

use strict;
use warnings;

sub new_project_dir
{
    my($base) = @_;
    opendir(my $dh, $base) || die "Failed to open directory $base for reading";
    my $file;
    my @numbers;
    while ($file = readdir $dh)
    {
        $numbers[$1] = 1 if ($file =~ m/^new project(\d+)$/)
    }
    closedir($dh) || die "Failed to close directory $base";
    my $i;
    my $max = $#numbers;
    for ($i = 0; $i < $max; $i++)
    {
        next if (defined $numbers[$i]);
        # Directory did not exist when we scanned the directory
        # But maybe it was created since then!
        my $dir = "new project$i";
        next unless mkdir "$base/$dir";
        return $dir;
    }
    # All numbers from 0..$max were in use...so try adding new numbers...
    while ($i < $max + 100)
    {
        my $dir = "new project$i";
        $i++;
        next unless mkdir "$base/$dir";
        return $dir;
    }
    # Still failed - give in...
    die "Something is amiss - all directories 0..$i in use?";
}

Тестовый код:

my $basedir = "base";
mkdir $basedir unless -d $basedir;

for (my $j = 0; $j < 10; $j++)
{
    my $dir = new_project_dir($basedir);
    print "Create: $dir\n";
    if ($j % 3 == 2)
    {
        my $k = int($j / 2);
        my $o = "new project$k";
        rmdir "$basedir/$o";
        print "Remove: $o\n";
    }
}

Answer 3

Попробуйте это:

#!/usr/bin/env perl

use strict;
use warnings;

# get the current list of files
# see `perldoc -f glob` for details.
my @files = glob( 'some/dir/new\\ project*' );

# set to first name, in case there are none others
my $next_file = 'new project1';

# check for others
if( @files ){

  # a Schwartian transform
  @files = map  { $_->[0]                                     }  # get original
           sort { $a->[1] <=> $b->[1]                         }  # sort by second field which are numbers
           map  { [ $_, do{ ( my $n = $_ ) =~ s/\D//g; $n } ] }  # create an anonymous array with original value and the second field nothing but digits
           @files;

  # last file name is the biggest
  $next_file = $files[-1];

  # add one to it
  $next_file =~ s/(.*)(\d+)$/$1.($2+1)/e;
}

print "next file: $next_file\n";

Answer 4

Само по себе ничего плохого, но это огромный код для достижения одной цели (получите минимальный индекс каталогов.

Основной модуль, пара подсистем и несколько преобразований Шварца сделают код болеегибкий:

use strict;
use warnings;
use List::Util 'min';

sub num { $_[0] =~ s|\D+||g } # 'new project4' -> '4', 'new1_project4' -> '14' (!)

sub min_index {

    my ( $dir, $filter ) = @_;

    $filter = qr/./ unless defined $filter; # match all if no filter specified

    opendir my $dirHandle, $dir or die $!;

    my $lowest_index = min                 # get the smallest ...
                        map  { num($_)   }  # ... numerical value ...
                         grep {    -d     }  # ... from all directories ...
                          grep { /$filter/ }  # ... that match the filter ...
                           readdir $dirHandle; # ... from the directory contents
    $lowest_index++ while grep { $lowest_index == num( $_ ) } readdir $dirhandle;
    return $lowest_index;
}

# Ready to use!

my $index = min_index ( 'some/dir' , qr/^new project/ );

my $new_project_name = "new project $index";