Сортировка переменной XSLT по дате

Question

Извините, если мое объяснение в последнем «вопросе» было немного грубым, я сделаю еще один снимок. Я действительно новичок в xsl.

Через серию подстрок я извлек датусохраняя его в переменной с именем $releasedate, я вывожу это с помощью <xsl:value-of select="$releasedate" />, который будет отображать дд / мм / гггг, например, 29/03/2010 в цикле «для каждого», как показано ниже.

Мой xml структурирован, как показано ниже,

<item>
<title>Title Goes Here</title>
<description>test goes here.....<b>Release Date:22/20/2010</b> more text</description>
</item>
<item>
<title>Title Goes Here</title>
<description>More test goes here.....<b>Release Date:22/20/2010</b> more text</description>
</item>

Я бы хотел отсортировать по значению того, что хранится в $ releaseate.Я думаю, может быть, это выглядело бы так ниже

<xsl:sort select="$releasedate" order="descending" />

Надеюсь, это имеет немного больше смысла, мои извинения еще раз за отсутствие у меня знаний в этом.1015 *

<xsl:for-each select="item">
    <xsl:sort select="pubDate"/>
    <xsl:if test="position() &lt; 5 ">
        <!-- grabs items 1 to 5 -->
        <xsl:variable name = "releasedatestart" >
            <xsl:value-of select="substring-after(description,'Release Date:&lt;/b&gt;')"/>
        </xsl:variable>
        <xsl:variable name = "releasedate" >
            <xsl:value-of select="substring-before($releasedatestart,'&lt;/div&gt;')"/>
        </xsl:variable>
        <xsl:variable name = "displaynamestart" >
            <xsl:value-of select="substring-after(description,'Display Name:&lt;/b&gt;')"/>
        </xsl:variable>
        <xsl:variable name = "displayname" >
            <xsl:value-of select="substring-before($displaynamestart,'&lt;/div&gt;')"/>
        </xsl:variable>
        <div style="margin:0px;background-color:#f2eff3;border:1px solid #ded6df;">
            <xsl:variable name = "start" >
                <xsl:value-of select="substring-after(description,'Description:&lt;/b&gt;')"/>
            </xsl:variable>
            <xsl:variable name = "title" >
                <xsl:value-of select="substring($start,0,100)"/>
            </xsl:variable>
            <xsl:variable name = "pagelink" >
                <xsl:value-of select="substring(link,1,61)"/>
            </xsl:variable>
            <xsl:variable name = "pageurl" >
                <xsl:value-of select="$pagelink"/>
                <xsl:value-of select="title"/>.aspx
            </xsl:variable>
            <div style="min-height:50px;">
                <div class="column" id="feeddate">
                    <xsl:value-of select="$releasedate" />
                </div>
                <div class="column" id="displayname">
                    <xsl:value-of select="$displayname" />
                </div>
                <div class="column" id="feedtitle">
                    <xsl:value-of select="$title" disable-output-escaping="yes"/>
                    <a>
                        <xsl:attribute name="href">
                            <xsl:value-of select="$pageurl" />
                        </xsl:attribute>
                        ..Read More
                    </a>
                </div>
            </div>
        </div>
    </xsl:if>
</xsl:for-each>

Answer 1

Это преобразование :

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="items">
  <items>
    <xsl:apply-templates>
      <xsl:sort select=
      "substring(substring-after(description, 'Release Date:'),7)"
       data-type="number" order="descending"/>
      <xsl:sort select=
      "substring(substring-after(description, 'Release Date:'),4,2)"
       data-type="number" order="descending"/>
      <xsl:sort select=
      "substring(substring-after(description, 'Release Date:'),1,2)"
       data-type="number" order="descending"/>
     </xsl:apply-templates>
  </items>
 </xsl:template>
</xsl:stylesheet>

применительно к этому документу :

<items>
    <item>
        <title>Title1</title>
        <description>text1 .....
            <b>Release Date:22/12/2010</b> more text
        </description>
    </item>
    <item>
        <title>Title Goes Here</title>
        <description>More test goes here.....
            <b>Release Date:23/12/2010</b> more text
        </description>
    </item>
</items>

дает требуемый, отсортированный результат :

<items>
   <item>
      <title>Title Goes Here</title>
      <description>More test goes here.....
            <b>Release Date:23/12/2010</b> more text
        </description>
   </item>
   <item>
      <title>Title1</title>
      <description>text1 .....
            <b>Release Date:22/12/2010</b> more text
        </description>
   </item>
</items>

Объяснение :

1. Использование substring-after() и substring().

2. Несколько <xsl:sort> детей <xsl:apply-templates>.

3. Преобразование идентичности.