AS3 / AIR: ошибка IOStream при попытке загрузить файлы - PullRequest
Новая
       16

AS3 / AIR: ошибка IOStream при попытке загрузить файлы

0 голосов
/ 26 января 2012

Я создаю приложение AIR, в котором пользователь перетаскивает файлы изображений на сцену, затем приложение загружает эти отброшенные изображения на сайт imgur.com, а затем возвращается со ссылками на изображения (в формате XML). ,

У меня две проблемы:

  1. программа успешно работает с очень маленьким файлом, однако при любом увеличении (1 МБ или более) я получаю ошибку IOStream 2023. Imgur поддерживает загрузку до 10 МБ, поэтому я знаю, что это должно быть что-то с моей стороны.

  2. Я хотел бы иметь возможность помещать несколько файлов изображений одновременно в программу и загружать их все (синхронно или асинхронно, это не имеет значения). Прямо сейчас программа выдает ошибки, когда я пытаюсь это сделать (что-то вроде байтового массива должно быть больше 0).

Ниже приведен код, который вызывает у меня проблемы. (спасибо за продвинутую помощь) 

private function doDragDrop(e:NativeDragEvent):void
{           
    trace("doDragDrop() called.");
    var dropFiles:Array = e.clipboard.getData(ClipboardFormats.FILE_LIST_FORMAT) as Array;
    for each (var file:File in dropFiles)
    {
        switch (file.extension.toLowerCase())
        {
            case "jpg" :
            case "jpeg" :
            case "gif" :
            case "png" :
            case "apng" :
            case "tiff" :
            case "bmp" :
            case "pdf" :
            case "xcf" :
            trace("file Extension Check = passed");
            addImage(file.nativePath);
                break;

            //error handling for non-supported filetypes
            default :
                trace("ERROR: Unsupported File Type Detected!");
        }
    }
}

private function addImage(nativePath:String):void
{
    trace("addImage() called.");
    trace("NativePath is: " + nativePath);
    //var file:File = new File(nativePath);
    var file:File = File.desktopDirectory.resolvePath(nativePath);
    var ba:ByteArray = new ByteArray();
    var stream:FileStream = new FileStream();
    stream.open(file, FileMode.READ);
    stream.readBytes(ba);
    stream.close();         
    var loader:Loader = new Loader();
    loader.contentLoaderInfo.addEventListener(Event.COMPLETE, fileLoaded);
    loader.loadBytes(ba);
}

private function fileLoaded(e:Event):void
{
    trace("fileLoaded() called.");
    var bitmap:Bitmap = Bitmap(e.target.content);
    var bitmapData:BitmapData = bitmap.bitmapData;
    var png:ByteArray = PNGEncoder.encode(bitmapData);

    urlLoader = new URLLoader();
    urlLoader.dataFormat = URLLoaderDataFormat.VARIABLES;
    urlLoader.addEventListener(Event.COMPLETE, onCookieSent);
    urlLoader.addEventListener(SecurityErrorEvent.SECURITY_ERROR, onSecurityError);
    urlLoader.addEventListener(IOErrorEvent.IO_ERROR, onIOError);

    var vars:String = "?key=" + API_KEY + "&name=name&title=title";
    var request:URLRequest = new URLRequest(UPLOAD_URL + vars);
    request.contentType = "application/octet-stream";
    request.method = URLRequestMethod.POST;
    request.data = png;
    urlLoader.load(request);
}

private function onCookieSent(e:Event):void
{
    trace("onCookieSent() called.");
    var res:XML = new XML(unescape(urlLoader.data));
    var resultsList:XMLList = res.links;
    trace(resultsList);
}

private function onIOError(e:IOErrorEvent):void 
{
    trace("ioErrorHandler: " + e);
    TweenLite.to(tv_mc, 2, {alpha:0.5, scaleX:1.0, scaleY:1.0, ease:Elastic.easeOut});
    // Handle error
}
private function onSecurityError(e:SecurityErrorEvent):void 
{
    trace("securityErrorHandler: " + e);
    TweenLite.to(tv_mc, 2, {alpha:0.5, scaleX:1.0, scaleY:1.0, ease:Elastic.easeOut});
    // handle error
}

//When the dragged object leaves the drop point, do this
private function doDragExit(e:NativeDragEvent):void
{
    trace("doDragExit() called.");
    TweenLite.to(tv_mc, 2, {alpha:0.5, scaleX:1.0, scaleY:1.0, ease:Elastic.easeOut});
}

1 Ответ

1 голос
/ 26 января 2012

после этого: 

var ba:ByteArray = new ByteArray();
var stream:FileStream = new FileStream();
stream.open(file, FileMode.READ);
stream.readBytes(ba);
stream.close();

у вас уже есть ByteArray файла / изображения.ты не можешь просто отправить это ... 

private function addImage(nativePath:String):void
{
    trace("addImage() called.");
    trace("NativePath is: " + nativePath);
    //var file:File = new File(nativePath);
    var file:File = File.desktopDirectory.resolvePath(nativePath);
    var ba:ByteArray = new ByteArray();
    var stream:FileStream = new FileStream();
    stream.open(file, FileMode.READ);
    stream.readBytes(ba);
    stream.close();         

    urlLoader = new URLLoader();
    urlLoader.dataFormat = URLLoaderDataFormat.VARIABLES;
    urlLoader.addEventListener(Event.COMPLETE, onCookieSent);
    urlLoader.addEventListener(SecurityErrorEvent.SECURITY_ERROR, onSecurityError);
    urlLoader.addEventListener(IOErrorEvent.IO_ERROR, onIOError);

    var vars:String = "?key=" + API_KEY + "&name=name&title=title";
    var request:URLRequest = new URLRequest(UPLOAD_URL + vars);
    request.contentType = "application/octet-stream";
    request.method = URLRequestMethod.POST;
    request.data = ba;
    urlLoader.load(request);
}
...