пользовательская проверка Grails - PullRequest
Новая
       18

пользовательская проверка Grails

7 голосов
/ 10 апреля 2011

Обычно для домена Grails или класса команд вы объявляете свои ограничения, и платформа добавляет метод validate(), который проверяет, является ли каждое из этих ограничений действительным для текущего экземпляра, например, 

class Adult {

  String name
  Integer age

  void preValidate() { 
    // Implementation omitted
  }

  static constraints = {
    name(blank: false)
    age(min: 18)
  }
}

def p = new Person(name: 'bob', age: 21)
p.validate()

В моем случае я хочу убедиться, что preValidate всегда выполняется перед проверкой класса. Я мог бы добиться этого, добавив метод 

def customValidate() {
  preValidate()
  validate()
}

Но тогда каждый, кто использует этот класс, должен помнить, чтобы вызывать customValidate вместо validate. Я тоже не могу этого сделать 

def validate() {
  preValidate()
  super.validate()
}

Потому что validate не является методом родительского класса (он добавляется метапрограммированием). Есть ли другой способ достичь моей цели?

Ответы [ 2 ]

2 голосов
/ 25 мая 2011

Вы можете достичь своей цели с помощью события beforeValidate (). Это описано в 1.3.6 Замечаниях по выпуску .

2 голосов
/ 11 апреля 2011

Этого можно добиться, используя собственную версию проверки метакласса, когда в вашем доменном / командном классе есть метод preValidate (). Нечто похожее на код ниже в вашем BootStrap.groovy может работать для вас: 

class BootStrap {

    def grailsApplication   // Set via dependency injection

    def init = { servletContext ->

        for (artefactClass in grailsApplication.allArtefacts) {
            def origValidate = artefactClass.metaClass.getMetaMethod('validate', [] as Class[])
            if (!origValidate) {
                continue
            }

            def preValidateMethod = artefactClass.metaClass.getMetaMethod('preValidate', [] as Class[])
            if (!preValidateMethod) {
                continue
            }

            artefactClass.metaClass.validate = {
                preValidateMethod.invoke(delegate)
                origValidate.invoke(delegate)
            }
        }
    }

    def destroy = {
    }
}
...