Переименуйте вывод CPack - PullRequest
Новая
       11

Переименуйте вывод CPack

6 голосов
/ 08 марта 2012

Я хотел бы переименовать файл установщика, который создает CPack (v2.8.7), чтобы включить номер версии, полученный во время сборки из системы управления версиями.Похоже, что этого нельзя сделать, установив переменные CPACK_ *, потому что это происходит во время "cmake".

Что я хочу сделать, это запустить "(n) make package" и иметь установщикфайл должен быть создан без дальнейших команд.Два возможных подхода, которые мне известны, - это манипулирование переменными имен файлов CPack во время сборки и переименование окончательного вывода CPack.

Если использовать «include (CPack)» в файле CMakeLists.txt, то получается, чтоCPack всегда запускается последним, и у вас не может быть команды после сборки. В этом сообщении списка рассылки предполагается, что можно написать собственную цель для запуска CPack, но я не смог понять, как это сделать без создания бесконечной рекурсии.

Как это можно сделать?

Ответы [ 2 ]

5 голосов
/ 09 марта 2012

С небольшой помощью из списка рассылки CMake я понял, как это сделать, используя subversion.

CMakeLists.txt 

cmake_minimum_required(VERSION 2.8)
project(myapp)

add_executable(main main.cpp)
install(TARGETS main DESTINATION .)

add_custom_target(first ALL
    # update the working copy
    COMMAND ${Subversion_SVN_EXECUTABLE} update ${CMAKE_SOURCE_DIR}

    # generate cpackoptions.cmake at build time so we get the
    # most recent revision number
    COMMAND ${CMAKE_COMMAND}
    -DSOURCE_DIR=${CMAKE_SOURCE_DIR}
    -DBINARY_DIR=${CMAKE_BINARY_DIR}
    -Dproj_name=${CMAKE_PROJECT_NAME}
    -P ${CMAKE_SOURCE_DIR}/create-cpackoptions.cmake
    )

add_dependencies(main first)

set(CPACK_PROJECT_CONFIG_FILE ${CMAKE_BINARY_DIR}/CPackOptions.cmake)

include(CPack)

create-cpackoptions.cmake 

include(FindSubversion)
Subversion_WC_INFO(${SOURCE_DIR} ${proj_name})

set(revision ${${proj_name}_WC_REVISION})

configure_file(${SOURCE_DIR}/CPackOptions.cmake.in
    ${BINARY_DIR}/CPackOptions.cmake
    @ONLY)

cpackOptions.cmake.in 

set(CPACK_PACKAGE_FILE_NAME "@proj_name@-${CPACK_PACKAGE_VERSION}r@revision@-${CPACK_SYSTEM_NAME}")
4 голосов
/ 08 марта 2012

Почему бы не извлечь информацию о сборке из VCS во время cmake-time?Затем вы можете легко изменить CPACK_PACKAGE_FILE_NAME, указав свой номер версии.

Дополнительный бонус: когда вы делаете это во время CMake, вы можете, например, заполнить файл «Readme.txt» информацией git, используя CMake's configure_file и добавьте его в свой пакет.Или, возможно, используйте его для заполнения "config.h", который используется в ваших сборках.

Пример: в одном из моих собственных проектов, у меня есть небольшой кусок кода CMake, которыйнаходит Git и извлекает текущий хэш набора изменений из репозитория исходного кода.Возможно, это не лучший способ извлечения информации из Git, но он работает для меня ... 

# First try to find the git-executable
find_program( Git_EXECUTABLE NAMES git git.cmd PATHS
    ${Git_DIR}
    ENV PATHS
    $ENV{Git_DIR}
)
# Run "git log -n 1 --pretty="%h" for the current commit-hash
execute_process( COMMAND ${Git_EXECUTABLE} "log" "-n" "1" "--pretty=\"%h\"" 
                 WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR} 
                 OUTPUT_VARIABLE Git_Commit_Hash 
                 OUTPUT_STRIP_TRAILING_WHITESPACE
                 )
# and use a regex to strip quotes.
string( REGEX REPLACE "^\"(.*)\"$" "\\1" Git_Commit_Hash ${Git_Commit_Hash} )

Результатом будет переменная Git_Commit_Hash со значением хеша из 7 символов, которое используетсяпри настройке CPack: 

set( CPACK_PACKAGE_NAME "MyProject" )
message( STATUS "    CPack options: " ${CPACK_PACKAGE_NAME} )
message( STATUS "    Preparing CPACK: " )
message( STATUS "      and hash: ${Git_Commit_Hash}" )

set( CPACK_PACKAGE_FILE_NAME "${CPACK_PACKAGE_NAME}_${Git_Build_Version}_${CPACK_PACKAGE_VERSION}" )
...