Как преобразовать определенный атрибут в элемент в сложном XML

Question

В моем предыдущем вопросе я спросил, как преобразовать определенный атрибут в элемент в простом XML. Теперь у меня есть более сложный ввод. Мне нужно преобразовать атрибут «запрос» в элемент. Комплексный ввод:

<?xml version="1.0" encoding="UTF-8" standalone="yes"?>
<filter query="select" name="hello" description="world">
    <certification>WFA</certification>
    <uuid>fd5d9f15-f6d9-4e71-aaf4-024aaaa627f2</uuid>
    <parameters>
        <parameter type="STRING" name="name" label="name">
            <description>Some name</description>
        </parameter>
    </parameters>
    <returned-attributes>
        <returned-attribute>id</returned-attribute>
    </returned-attributes>
</filter>

Мой вывод желаний выглядит так:

<?xml version="1.0" encoding="UTF-8" standalone="yes"?>
<filter name="hello" description="world">
    <certification>WFA</certification>
    <uuid>fd5d9f15-f6d9-4e71-aaf4-024aaaa627f2</uuid>
    <query>select<query/>
    <parameters>
        <parameter type="STRING" name="name" label="name">
            <description>Some name</description>
        </parameter>
    </parameters>
    <returned-attributes>
        <returned-attribute>id</returned-attribute>
    </returned-attributes>
</filter>

Я использую следующий XSLT:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:strip-space elements="*"/>
    <xsl:output indent="yes"/>

    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>

    <!-- match the filter element -->
    <xsl:template match="filter">
        <xsl:choose>
            <xsl:when test="/filter/@query">
                <!-- output a filter element -->
                <xsl:element name="filter">

                    <!-- add the name attribute, using the source name attribute value -->
                    <xsl:attribute name="name">
                        <xsl:value-of select="@name"/>
                    </xsl:attribute>

                    <!-- add the description attribute (if found), using the source name attribute value -->
                    <xsl:choose>
                        <xsl:when test="/filter/@description">
                            <xsl:attribute name="description">
                                <xsl:value-of select="@description"/>
                            </xsl:attribute>
                        </xsl:when>
                    </xsl:choose>

                    <!-- add the query as child element, using the source query attribute value -->
                    <xsl:element name="query">
                        <xsl:value-of select="@query"/>
                    </xsl:element>

                    <!-- add all common elements -->
                    <xsl:element name="certification">
                        <xsl:value-of select="certification"/>
                    </xsl:element>
                    <xsl:element name="uuid">
                        <xsl:value-of select="uuid"/>
                    </xsl:element>

                    <!-- copy parameters -->
                    <xsl:copy>
                        <xsl:apply-templates select="/filter/parameters"/>
                    </xsl:copy>

                    <!-- copy attributes -->
                    <xsl:copy>
                        <xsl:apply-templates select="/filter/returned-attributes"/>
                    </xsl:copy>
                </xsl:element>
            </xsl:when>
            <xsl:otherwise>
                <xsl:copy>
                    <xsl:apply-templates select="@*|node()"/>
                </xsl:copy>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>

</xsl:stylesheet>

Преобразование работает, но мне кажется сложным. Обратите внимание, что я использую логику if / else, потому что мой вход может содержать «старый» (не преобразованный) и «новые» (преобразованные) XML-файлы.

Пожалуйста, сообщите. Заранее спасибо.

Answer 1

Вот краткое и простое решение :

<xsl:stylesheet version="1.0"
     xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
     <xsl:output omit-xml-declaration="yes" indent="yes"/>
     <xsl:strip-space elements="*"/>

     <xsl:template match="node()|@*">
         <xsl:copy>
           <xsl:apply-templates select="node()|@*"/>
         </xsl:copy>
     </xsl:template>

     <xsl:template match="parameters">
         <xsl:apply-templates select="/filter/@query" mode="build"/>
         <xsl:copy>
           <xsl:apply-templates select="node()|@*"/>
         </xsl:copy>
     </xsl:template>
     <xsl:template match="/filter/@query"/>

     <xsl:template match="/filter/@query" mode="build">
         <query><xsl:value-of select="."/></query>
     </xsl:template>
</xsl:stylesheet>

когда это преобразование применяется к предоставленному документу XML :

<filter query="select" name="hello" description="world">
    <certification>WFA</certification>
    <uuid>fd5d9f15-f6d9-4e71-aaf4-024aaaa627f2</uuid>
    <parameters>
        <parameter type="STRING" name="name" label="name">
            <description>Some name</description>
        </parameter>
    </parameters>
    <returned-attributes>
        <returned-attribute>id</returned-attribute>
    </returned-attributes>
</filter>

желаемый, правильный результат получается :

<filter name="hello" description="world">
   <certification>WFA</certification>
   <uuid>fd5d9f15-f6d9-4e71-aaf4-024aaaa627f2</uuid>
   <query>select</query>
   <parameters>
      <parameter type="STRING" name="name" label="name">
         <description>Some name</description>
      </parameter>
   </parameters>
   <returned-attributes>
      <returned-attribute>id</returned-attribute>
   </returned-attributes>
</filter>

Answer 2

Это должно сработать:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

   <!-- copy all content other than the query attribute -->
   <xsl:template match="node()|@*">
        <xsl:copy>
            <xsl:apply-templates select="node()|@*[not(name()='query')]"/>
        </xsl:copy>
   </xsl:template>

   <!-- match uuid so that we can insert query after -->
   <xsl:template match="uuid">
      <xsl:copy>
         <xsl:apply-templates select="@*|node()"/>
       </xsl:copy>
       <!-- add our query element -->
       <xsl:element name="query">
         <!-- navigate up one level to reach the query attribute -->
         <xsl:value-of select="../@query"/>
       </xsl:element>     
   </xsl:template>
</xsl:stylesheet>

Быстрый совет для вас, узнайте о преобразовании личности и как оно работает.