Матричное умножение CUDA

Question

Я читал несколько веб-сайтов и даже использовал код NVIDA в качестве руководства, но я все еще получаю неправильный ответ. Основной запросит у пользователя размер, и отобразит A и B, а затем отобразит полученную матрицу C. Однако, скажем, я запускаю матрицу 2x2 для A и B, это мой пример вывода:

Matrix A
0.000000 8.000000
2.000000 2.000000


Matrix B
3.000000 1.000000
5.000000 7.000000


Matrix C (Results)
0.000000 9.000000
7.000000 4.000000

Но это неверно. Должно быть:

40.000 56.000
16.000 16.000

Я изменил его с десятичных на целые числа, чтобы его было легче проверить, и обнаружил, что это неверно. Я не понимаю, почему это было бы неправильно, особенно, хотя я взял это прямо из их примера кода.

#ifndef _MATRIXMUL_KERNEL_H_
#define _MATRIXMUL_KERNEL_H_

#include <stdio.h>

// Thread block size
#define BLOCK_SIZE 16
#define TILE_SIZE  16



// CUDA Kernel
__global__ void matrixMul( float* C, float* A, float* B, int wA, int wB)
{
    // Block index
    int bx = blockIdx.x;
    int by = blockIdx.y;

// Thread index
int tx = threadIdx.x;
int ty = threadIdx.y;

// Index of the first sub-matrix of A processed 
// by the block
int aBegin = wA * BLOCK_SIZE * by;

// Index of the last sub-matrix of A processed 
// by the block
int aEnd   = aBegin + wA - 1;

// Step size used to iterate through the 
// sub-matrices of A
int aStep  = BLOCK_SIZE;

// Index of the first sub-matrix of B processed 
// by the block
int bBegin = BLOCK_SIZE * bx;

// Step size used to iterate through the 
// sub-matrices of B
int bStep  = BLOCK_SIZE * wB;
float Csub=0;
// Loop over all the sub-matrices of A and B
// required to compute the block sub-matrix
for (int a = aBegin, b = bBegin; a <= aEnd; a += aStep, b += bStep) 
{
    // Declaration of the shared memory array As 
    // used to store the sub-matrix of A
    __shared__ float As[BLOCK_SIZE][BLOCK_SIZE];

    // Declaration of the shared memory array Bs 
    // used to store the sub-matrix of B
    __shared__ float Bs[BLOCK_SIZE][BLOCK_SIZE];

    // Load the matrices from global memory
    // to shared memory; each thread loads
    // one element of each matrix
    As[ty][tx] = A[a + wA * ty + tx];
    Bs[ty][tx] = B[b + wB * ty + tx];

    // Synchronize to make sure the matrices 
    // are loaded
    __syncthreads();

    // Multiply the two matrices together;
    // each thread computes one element
    // of the block sub-matrix
    for (int k = 0; k < BLOCK_SIZE; ++k)
        Csub += As[ty][k] * Bs[k][tx];

    // Synchronize to make sure that the preceding
    // computation is done before loading two new
    // sub-matrices of A and B in the next iteration
    __syncthreads();
}
// Write the block sub-matrix to device memory;
// each thread writes one element
int c = wB * BLOCK_SIZE * by + BLOCK_SIZE * bx;
C[c + wB * ty + tx] = Csub;
}

#endif // #ifndef _MATRIXMUL_KERNEL_H_

код хоста:

    //perform the calculation
    //setup execution parameters
    dim3 threads(BLOCK_SIZE, BLOCK_SIZE);
    dim3 grid(c.colSize / threads.x, c.rowSize / threads.y);

    //   execute the kernel
    matrixMul<<< grid, threads >>>(deviceMatrixC, deviceMatrixA, deviceMatrixB, a.colSize, b.colSize);

Спасибо за вашу помощь, Dan

Answer 1

Код, который вы используете неявно, требует, чтобы размер матриц был кратен размеру блока (в данном случае 16x16).Внутренний расчет продукта обрабатывает ширину плитки за раз, не проверяя доступ к памяти вне границ.По этой причине матрицы 2x2 не будут работать.

Если вы попробуете запустить ядро ​​со входом 16x16 (например, с нулевым заполнением регистра 2x2 до 16x16), вы сможете подтвердить результат.