Добавление массовых пользователей в Active Directory с помощью импорта .CSV?

Question

Привет и спасибо за просмотр моей проблемы.

Я новичок в AD и мне нужна помощь в импорте групповых пользователей в AD.

Вот ссылка на CSV, который я хочу импортировать; не волнуйтесь, это все случайные данные и личная информация не сохраняется.

http://www.mediafire.com/?s2j37lsps83o86s

Спасибо!

Answer 1

Обновлено:

Массовый импорт CSV-файлов с помощью PowerShell: http://www.morgantechspace.com/2014/04/Create-Bulk-AD-Users-from-CSV-using-Powershell-Script.html

VBScript:

' CreateBulkADUsersFromCSVFile.vbs
' Sample VBScript to create a AD Users from CSV file .
' Author: http://www.morgantechspace.com/
' ------------------------------------------------------' 
Option Explicit 

' Variables needed for LDAP connection 
Dim objRootLDAP 
Dim objContainer 

' Variables needed for CSV File Information
Dim varFileName
Dim objFSO
Dim objFile

' Holding variables for user information import from CSV file 
Dim varSamAccountName,varFirstName,varLastName
Dim newUserFields 

Dim objNewUser 
Dim varDomain 

Const ForReading = 1

' Modify this name to match your company's AD domain 
varDomain="workdomain.local" 

' Create a connection to the Active Directory Users container. 
Set objRootLDAP = GetObject("LDAP://rootDSE") 

' You can give your own OU like LDAP://OU=TestOU instead of LDAP://cn=Users
Set objContainer = GetObject("LDAP://cn=Users," & objRootLDAP.Get("defaultNamingContext")) 

' Specify the csv file full path.
varFileName = "C:\Users\Administrator\Desktop\NewUsers.csv"

' Open the file for reading.
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objFile = objFSO.OpenTextFile(varFileName, ForReading)

' Read the first line - csv columns -not needed for our proceess
objFile.ReadLine

' Skip the error while creating new user...(i.e- user already exists)
on error resume next

' Read the file and create new user.
Do Until objFile.AtEndOfStream
    ' Splits prioperty values.
    newUserFields = Split(objFile.ReadLine,",")
    varSamAccountName = newUserFields(0)
    varFirstName = newUserFields(1) 
    varLastName = newUserFields(2) 


' Create new User account 
Set objNewUser = objContainer.Create("User","cn="&varFirstName&" "&varLastName) 

objNewUser.put "sAMAccountName",lcase(varSamAccountName) 
objNewUser.put "givenName",varFirstName 
objNewUser.put "sn",varLastName 
objNewUser.put "UserPrincipalName",lcase(varSamAccountName)&"@"&varDomain 
objNewUser.put "DisplayName",varFirstName&" "&varLastName 
objNewUser.put "name",lcase(varSamAccountName) 
objNewUser.put "description","This user was created from csv file using vbscript"

objNewUser.SetInfo 
objNewUser.Put "pwdLastSet", 0 

' Enable the user account 
objNewUser.AccountDisabled = FALSE
objNewUser.SetInfo 
Loop

MsgBox("Active Directory users created successfully from CSV file using VBScript.")

WScript.Quit  

Answer 2

То, что вы запрашиваете, - это скрипт / программа для автоматического выполнения этой задачи. Не одобряется просто приходить и просить людей выполнять вашу работу за вас, так как этот сайт действительно ориентирован на людей, которым нужна помощь в чем-то, что они делают.

В идеале вы должны опубликовать свой вопрос с кодом, с которым вы работаете, и с ошибками; не просто попросить кого-нибудь написать программу для вас.

Я подозреваю, что если вы не измените вопрос, он будет / должен быть удален.