Как искажать изображения (или FXG) во Flex? - PullRequest
Новая
       44

Как искажать изображения (или FXG) во Flex?

4 голосов
/ 07 декабря 2011

Я хочу исказить изображения (или FXG) во Flex.

В основном просто хотите изменить края изображения, как на изображении ниже.Я знаю, как делать простые искажения, но не могу найти способ сделать это.

enter image description here

1 Ответ

3 голосов
/ 24 апреля 2012

Ответы были правильными ... что вам нужно, это DisplacementMapFilter !!

displacementImage должно быть серым в целом -> означает отсутствие искажений, и добавить белый и серый радиальный градиент для каждогонижний и верхний край, как это:

Distortion map for this very effect

The image i used to be distortet

Final result after distortion

И с картой вы идете так: 

package {
    import flash.display.BitmapData;
    import flash.display.BitmapDataChannel;
    import flash.display.Loader;
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.filters.DisplacementMapFilter;
    import flash.filters.DisplacementMapFilterMode;
    import flash.geom.Point;
    import flash.net.URLRequest;

    public class DistortImage extends Sprite
    {

        private var sourceImage:Loader;
        private var distortMap:Loader;

        public function DistortImage()
        {
            super();


        // Loading the Image to be distorted
            sourceImage = new Loader();
            var requ: URLRequest = new URLRequest("text.jpg");
            sourceImage.contentLoaderInfo.addEventListener(Event.COMPLETE, loadMap);
            sourceImage.load(requ);
        }

        private function loadMap( E:Event = null ):void{

        // loading distortion map ( grayscale )
            distortMap = new Loader();
            var requ: URLRequest = new URLRequest("distortMap.jpg");
            distortMap.contentLoaderInfo.addEventListener(Event.COMPLETE, applyDistortion);
            distortMap.load(requ);
        }
        private function applyDistortion( E:Event = null ):void{

        // get jpg as BitmapData
            var bmpData:BitmapData = new BitmapData( distortMap.content.width,distortMap.content.height);
            bmpData.draw(distortMap);

        // create the filter - notice gray(128,128,128) means no distortion white is negative black is positive distortion
            var offsetOfMap:Point = new Point(0,0);
            var redChannelCode:uint = BitmapDataChannel.RED; // is not important cause you just need oneway distortion 
            var yDistortion:int = 20; // strength

            var distortFilter:DisplacementMapFilter = new DisplacementMapFilter(bmpData,offsetOfMap,0,redChannelCode,0,yDistortion,DisplacementMapFilterMode.COLOR,0xffffff,0);

        // filters need to be included in an array to add on display Object
            var filters:Array = new Array();
            filters.push(distortFilter);

        // adding filter to image
            sourceImage.filters = filters;
            addChild(sourceImage);
        }
    }
}
...