Добавление простого атрибута XSLT

Question

Я хочу сделать действительно простой XSLT для моего XML-документа, который имеет такую ​​структуру:

<XML>
    <TAG1 attribute1="A">
        <IRRELEVANT />
        <TAG2 attribute2="B" attribute3="34" />
    </TAG1>
</XML>

И я пытаюсь сделать XSLT, который делает следующее:

1. Скопируйте все
2. Если TAG2 @ attribute1 = "A" AND TAG2 @ attribute2 = "B" AND нет TAG2 @ attribute4, то добавьте @ attribute4 в TAG2 и получите его значение равным значению TAG2 @ attribute3

Моя неудачная попытка приведена ниже. Я получаю ошибку "xsl: attribute: невозможно добавить атрибуты к элементу, если к нему уже добавлены дочерние элементы."

Спасибо!

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0"  
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:param name="newDocumentHeader" />

   <!-- copy idiom copying ALL nodes -->
   <xsl:template match="node()|@*">
      <xsl:copy>
         <xsl:apply-templates select="node() | @*" />
      </xsl:copy>
   </xsl:template>

   <!-- override for special case -->
   <xsl:template match="TAG1[@attribute1='A']/TAG2[@attribute2='B'][not(@attribute4)]">
        <xsl:attribute name="attribute4">
        <xsl:value-of select="@attribute3" />
        </xsl:attribute>
    </xsl:template>

</xsl:stylesheet>

Answer 1

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

    <xsl:template match="node() | @*">
        <xsl:copy>
            <xsl:apply-templates select="node() | @*" />
        </xsl:copy>
    </xsl:template>

    <xsl:template match="TAG1[@attribute1 = 'A']/TAG2[@attribute2= 'B' ][not(@attribute4)]">
        <xsl:copy>
            <xsl:attribute name="attribute4">
                <xsl:value-of select="@attribute3" />
            </xsl:attribute>
            <xsl:apply-templates  select="node() | @*"/>
        </xsl:copy>

    </xsl:template>

</xsl:stylesheet>

Результат:

<XML>
    <TAG1 attribute1="A">
        <IRRELEVANT />
        <TAG2 attribute4="34" attribute2="B" attribute3="34" />
    </TAG1>
</XML>

Answer 2

Чего не хватает в вашем XSLT-коде, это просто копия соответствующего элемента.Однако в вашем случае ( Простое добавление атрибута XSLT ) вы можете напрямую переопределить attribute3 узел:

<xsl:template match="TAG1[@attribute1='A']
         /TAG2[@attribute2='B' and not(@attribute4)]
          /@attribute3">
    <xsl:copy-of select="."/>
    <xsl:attribute name="attribute4">
        <xsl:value-of select="." />
    </xsl:attribute>
</xsl:template>

Интегрированный в текущее преобразование, производит:

<XML>
    <TAG1 attribute1="A">
        <IRRELEVANT></IRRELEVANT>
        <TAG2 attribute2="B" attribute3="34" attribute4="34"></TAG2>
    </TAG1>
</XML>