Получите путем отражения значение свойства, у которого получатель имеет необязательное значение

Question

Я получаю несколько свойств элемента управления.Вот как я использовал для извлечения свойств (с pinfo типа PropertyInfo):

value = pinfo.GetValue(obj, nothing)

Это работало хорошо, но теперь я сталкиваюсь со свойством, которое имеет необязательное значение, и я получаю сообщение об ошибке, сообщающее мнечто количество параметров неверно.Поэтому я изменил свой код следующим образом:

Dim index As Object() = {Nothing}
value = pinfo.GetValue(obj, index)

На данный момент я не получил никакого сообщения об ошибке, но этот код не возвращает правильное значение.Это работает, только если я заменю Nothing значением по умолчанию, предоставленным средством доступа к свойству ...

Но я заранее не знаю, что это за значение по умолчанию!И этот код внутри функции , которая извлекает свойства, которые не имеют необязательных значений, поэтому я не могу изменить код, особенно для одного случая или другого ..

Есть идеи?Я работаю над .NET 2.0

---

РЕДАКТИРОВАТЬ: больше точности в случае, приводящем к проблеме

Вот пример свойства, приводящего к проблеме:

ReadOnly Property Foo(Optional ByVal Number As Integer = -1) As String
    Get
        If Number = -1 Then
            Return "Your number is the default number: " & Number
        Else
            Return "Your number is " & Number
        End If
    End Get
End Property

С этим свойством ни один из приведенных выше кодов не получает правильную строку.

Лучше всего было бы попробовать первый код общего назначения, перехватить соответствующее исключение, а затем динамически получить значение по умолчанию для параметра (в этом случае число) и его тип , чтобы я мог вызвать getValue с этим значением по умолчанию.

Итак, как мне получить значение по умолчанию для необязательного параметра?

Answer 1

Это работает с необязательными параметрами:

ReadOnly Property Foo(Optional name As String = Nothing) As String
    Get
        If name Is Nothing Then
            Return "Hello World"
        Else
            Return "Hello " & name
        End If
    End Get
End Property


Dim pinfo As Reflection.PropertyInfo = Me.GetType().GetProperty("Foo")
Dim value As Object = pinfo.GetValue(Me, New Object() {"Tim"})  ' Hello Tim '
value = pinfo.GetValue(Me, New Object(){Nothing})               ' Hello World '

Редактировать: Согласно вашему комментарию, целое число не работает, я пока не знаю, как получить значение по умолчаниюнеобязательный параметр в свойстве.Если вы знаете это, вы можете легко передать его, но в противном случае происходит следующее (обратите внимание на Int32.MinValue по умолчанию вместо 0):

ReadOnly Property Foo(Optional age As Int32 = Int32.MinValue) As String
    Get
        If age = Int32.MinValue Then
            Return "I don't know how old i am"
        Else
            Return String.Format("I am {0} years old", age)
        End If
    End Get
End Property

Dim pinfo As Reflection.PropertyInfo = Me.GetType.GetProperty("Foo")
Dim value As Object = pinfo.GetValue(Me, New Object() {38})  ' I am 38 years old '
value = pinfo.GetValue(Me, New Object() {Nothing})           ' I am 0 years old '
value = pinfo.GetValue(Me, New Object() {Int32.MinValue})    ' I don't know how old i am '

---

Edit2 : Благодаря @Rup теперь я знаю, что GetIndexParameters была недостающая часть.Таким образом, следующее должно работать для любого типа параметра.

Dim pinfo As Reflection.PropertyInfo = Me.GetType.GetProperty("Foo")
Dim parameters() As Reflection.ParameterInfo = pinfo.GetIndexParameters()
Dim params(parameters.Length - 1) As Object
For i As Int32 = 0 To parameters.Length - 1
    Dim paramInfo As Reflection.ParameterInfo = parameters(i)
    If paramInfo.IsOptional Then
        params(i) = paramInfo.DefaultValue
    Else
        If paramInfo.ParameterType.IsValueType Then
            params(i) = Activator.CreateInstance(paramInfo.ParameterType)
        Else
            params(i) = Nothing
        End If
    End If
Next
Dim value As Object = pinfo.GetValue(Me, params)

Answer 2

Попробуйте следующий пример. Убедитесь, что объект имеет значение null, затем активируйте его с помощью Activator. Следующая программа на C #.

class Program
{
    static void Main(string[] args)
    {
        Test testObj = null;
        testObj = testObj ?? Activator.CreateInstance<Test>();
        var ty = testObj.GetType().GetProperty("MyProperty").GetValue(testObj, null);

    }
}
public class Test
{
    public Test2 MyProperty { get; set; }
}
public class Test2
{
    public int Prty { get; set; }
}