Delphi: Canvas.FillRect в представлении списка - PullRequest
Новая
       67

Delphi: Canvas.FillRect в представлении списка

0 голосов
/ 08 июля 2011

При изменении текста подэлемента представления списка мне нужно почистить и заполнить целый ряд: 

procedure TForm1.ListViewDrawItem(Sender: TCustomListView;
  Item: TListItem; Rect: TRect; State: TOwnerDrawState);
begin
  if Item.SubItems[2]='Done'
   then
  begin
    Sender.Canvas.Font.Color := clBlack;
    Sender.Canvas.Brush.Color := clGreen;
    Sender.Canvas.Brush.Style := bsSolid;
    Sender.Canvas.FillRect(Rect);
  end;
end;

Но Sender.Canvas. FillRect (Rect) заполнит толькоRect of SubItem.Как заполнить целый ряд?

Вопрос задается на основе Delphi: как рисовать маленькие значки в представлении списка на CustomDrawItem

Спасибо!

1 Ответ

5 голосов
/ 08 июля 2011

Во-первых, если у вас есть три столбца, это Caption, SubItems[0] и SubItems[1], помните?Нет SubItems[2]!

Во всяком случае, это очень просто.Вам нужна только очень и очень маленькая модификация старого кода. 

procedure TForm1.ListView1DrawItem(Sender: TCustomListView; Item: TListItem;
  Rect: TRect; State: TOwnerDrawState);
var
  i: Integer;
  x1, x2: integer;
  r: TRect;
  S: string;
const
  DT_ALIGN: array[TAlignment] of integer = (DT_LEFT, DT_RIGHT, DT_CENTER);
begin
  if SameText(Item.SubItems[1], 'done') then
  begin
    Sender.Canvas.Font.Color := clBlack;
    Sender.Canvas.Brush.Color := clLime;
  end
  else
    if Odd(Item.Index) then
    begin
      Sender.Canvas.Font.Color := clBlack;
      Sender.Canvas.Brush.Color := $F6F6F6;
    end
    else
    begin
      Sender.Canvas.Font.Color := clBlack;
      Sender.Canvas.Brush.Color := clWhite;
    end;
  Sender.Canvas.Brush.Style := bsSolid;
  Sender.Canvas.FillRect(Rect);
  x1 := 0;
  x2 := 0;
  r := Rect;
  Sender.Canvas.Brush.Style := bsClear;
  Sender.Canvas.Draw(3, r.Top + (r.Bottom - r.Top - bm.Height) div 2, bm);
  for i := 0 to ListView1.Columns.Count - 1 do
  begin
    inc(x2, ListView1.Columns[i].Width);
    r.Left := x1;
    r.Right := x2;
    if i = 0 then
    begin
      S := Item.Caption;
      r.Left := bm.Width + 6;
    end
    else
      S := Item.SubItems[i - 1];
    DrawText(Sender.Canvas.Handle,
      S,
      length(S),
      r,
      DT_SINGLELINE or DT_ALIGN[ListView1.Columns[i].Alignment] or
        DT_VCENTER or DT_END_ELLIPSIS);
    x1 := x2;
  end;
end;

Снимок экрана http://privat.rejbrand.se/TListViewCustomDrawIconSel.png

В частности, обратите внимание, что я использую clLime вместо clGreen, потому что clBlack текст на clGreen фоне выглядит ужасно!Вы можете рассмотреть clWhite текст на clGreen фоне, однако:

Снимок экрана http://privat.rejbrand.se/TListViewCustomDrawIconSel2.png

Обновление в ответ на комментарии:

Чтобы изменить третий столбец представления списка, не нужно просто делать 

procedure TForm1.FormClick(Sender: TObject);
begin
  ListView1.Items[3].SubItems[1] := 'Done';
end;

Действительно, Windows не знает, что данные одного столбца влияют на внешний вид всей строки! Самое простое исправление - сказать Windows перекрасить весь элемент управления, когда вы изменили значение Лучше: просто попросите Windows перерисовать текущую строку: 

procedure TForm1.FormClick(Sender: TObject);
begin
  ListView1.Items[3].SubItems[1] := 'Done';
  ListView1.Items[3].Update;
end;
...