Ошибка STARTTLS при отправке электронной почты с использованием Indy в Delphi XE - PullRequest
Новая
       62

Ошибка STARTTLS при отправке электронной почты с использованием Indy в Delphi XE

3 голосов
/ 10 октября 2011

Я пытаюсь отправить электронное письмо из своего приложения, используя следующий код: 

  Var
  MailMessage : TIdMessage;
  SMTP        : TIdSMTP
   .
   .
   .
 //setup SMTP
 SMTP.Host := 'smtp.gmail.com';
 SMTP.Port := 25;
 //setup mail message
 MailMessage.From.Address := 'fromMe@gmail.com';
 MailMessage.Recipients.EMailAddresses := 'ToSomeOne@hotmail.com';
 MailMessage.Subject := 'Test';
 MailMessage.Body.Text := 'Hello, It is Just for test';

 SMTP.Connect;
 SMTP.Send(MailMessage);

Когда я его запускаю, выдается следующее сообщение об ошибке 

**ERROR: Must issue a STARTTLS command first. i29sm34080394wbp.22**

Как я могу решитьэто?

Ответы [ 3 ]

8 голосов
/ 11 октября 2011

Соединяя ответы, вы можете получить следующий код.Не забудьте, как Nathanial Woolls упомянули here, чтобы поместить библиотеки libeay32.dll и ssleay32.dll, например, из here в ваш проектпапку или путь от following places. 

uses
  IdMessage, IdSMTP, IdSSLOpenSSL, IdGlobal, IdExplicitTLSClientServerBase;

procedure SendEmail(const Recipients: string; const Subject: string; const Body: string);
var
  SMTP: TIdSMTP;
  Email: TIdMessage;
  SSLHandler: TIdSSLIOHandlerSocketOpenSSL;
begin
  SMTP := TIdSMTP.Create(nil);
  Email := TIdMessage.Create(nil);
  SSLHandler := TIdSSLIOHandlerSocketOpenSSL.Create(nil);

  try
    SSLHandler.MaxLineAction := maException;
    SSLHandler.SSLOptions.Method := sslvTLSv1;
    SSLHandler.SSLOptions.Mode := sslmUnassigned;
    SSLHandler.SSLOptions.VerifyMode := [];
    SSLHandler.SSLOptions.VerifyDepth := 0;

    SMTP.IOHandler := SSLHandler;
    SMTP.Host := 'smtp.gmail.com';
    SMTP.Port := 587;
    SMTP.Username := 'yourusername@gmail.com';
    SMTP.Password := 'yourpassword';
    SMTP.UseTLS := utUseExplicitTLS;

    Email.From.Address := 'yourusername@gmail.com';
    Email.Recipients.EmailAddresses := Recipients;
    Email.Subject := Subject;
    Email.Body.Text := Body;

    SMTP.Connect;
    SMTP.Send(Email);
    SMTP.Disconnect;

  finally
    SMTP.Free;
    Email.Free;
    SSLHandler.Free;
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  SendEmail('recipient@whatever.com', 'Subject', 'Body');
end;

Надеюсь, эта помощь

6 голосов
/ 10 октября 2011

smtp.gmail.com заставляет вас использовать зашифрованное соединение с использованием STARTTLS.

Indy 9 не поддерживает STARTTLS напрямую, но indy 10 поддерживает.

В Indy 10 перед подключением к серверу необходимо назначить IOHandler с включенным SSL, например TIdSSLIOHandlerSocketOpenSSL,

См .: http://www.indyproject.org/docsite/html/frames.html?frmname=topic&frmfile=TIdSSLIOHandlerSocketOpenSSL.html

Добавитьследующий код: 

var
...
SSLHandler: TIdSSLIOHandlerSocketOpenSSL;

SSLHandler:= TIdSSLIOHandlerSocketOpenSSL.Create(Form1);
SMTP.IOHandler:= SSLHandler;
SMTP.UseTLS:= utUseExplicitTLS;
SMTP.Username:= 'username';
SMTP.Password:= 'password';
SMTP.Port:= 587;

Если вы просто используете SMTP для незашифрованного обработчика SMTP (SMTP вашего провайдера), вы не столкнетесь с этой проблемой.

3 голосов
/ 10 октября 2011

Ошибка в том, что Gmail использует SSL и TLS.Вам нужно будет использовать обработчик SSL IO Indy, а также соответствующие библиотеки OpenSSL для вашей версии Indy..

...