Во Flex как создать, заполнить и отобразить растровое изображение? - PullRequest
Новая
       25

Во Flex как создать, заполнить и отобразить растровое изображение?

3 голосов
/ 23 апреля 2009

Начиная с полностью пустого приложения MXML: 

<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" 
    layout="absolute" >

</mx:Application>

Какой сценарий будет:

  • создать растровое изображение (это должен быть BitmapData объект?)
  • программно заполняет его данными (например, рисует круг) (есть ли более эффективный способ сделать это, чем повторный вызов BitmapData.SetPixel?)
  • отображать его в приложении (например, по центру в середине) (как я могу получить растровое изображение на экране? В примерах онлайн-флэш-памяти показано, что вызывается myBitmap=new Bitmap(myBitmapData), а затем myBitmap.AddChild, но это приводит к ошибке во Flex). 1015 *

??

ПРИМЕЧАНИЕ. Цель состоит не в том, чтобы нарисовать круг на экране, а в том, чтобы заполнить объект Bitmap (или BitmapData? Or ???) с помощью SetPixel (или ???), а затем вывести его содержимое на экран, как нужно было бы делать в приложении для обработки изображений или визуальных эффектов.

Ответы [ 2 ]

3 голосов
/ 23 апреля 2009

У вас есть несколько вариантов. Первый - изучить инфраструктуру Degrafa , в которой есть несколько действительно невероятных инструментов рисования, в противном случае вам нужно добавить блок скрипта и использовать API рисования AS3 в функции (в этом случае, вероятно, вызывается метод creationComplete: 

private function handleCreationComplete():void
{
    var component:UIComponent = new UIComponent(); //needed to add to the flex display list
    var myCircle:Sprite = new Sprite();
    myCircle.graphics.beginFill(0xFFFFFF,1)
    myCircle.graphics.drawCircle(100,100,50);
    component.addChild(myCircle);
    this.addChild(component);
}

Это не будет центрировать круг, но вы можете понять это.

вы можете использовать эту функцию, чтобы фактически получить растровое изображение из вышеуказанного UIComponent: 

private function getBitmapData( target : UIComponent ) : BitmapData
   {
    var bd : BitmapData = new BitmapData( target.width, target.height );
    var m : Matrix = new Matrix();
    bd.draw( target, m );
    return bd;
   }

из здесь .

2 голосов
/ 23 апреля 2009

Вот полный рабочий пример, который я смог создать на основе предложений Джоэла Хукса:

ФАЙЛ MXML (ards.mxml): 

<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute"
       creationComplete="onCreationComplete()">

<mx:Script source="ards_script.as" />

</mx:Application>

ФАЙЛ СКРИПТА (ards_script.as): 

import mx.core.UIComponent;

private function onCreationComplete():void
{
    // create a UIComponent and add it to the Flex display list
    var component:UIComponent = new UIComponent();
    component.width = this.width;
    component.height = this.height;
    component.x = 0;
    component.y = 0;
    this.addChild(component);

    // create a BitmapData object (basically an array of pixels) the same size as the screen    
    var bd : BitmapData = new BitmapData( component.width, component.height );

    // draw a green circle in the bitmap data
    var xCenter:int = component.width/2;
    var yCenter:int = component.height/2;
    var r:int = Math.min(xCenter,yCenter);
    var rSquare:int = r*r;
    var color:Number = 0x00ff00;
    for( var i:int=0; i<component.width; i++ )
    {
        for( var j:int=0; j<component.width; j++ )
        {
            var dX:int = i - xCenter;
            var dY:int = j - yCenter;
            var q:int = dX*dX + dY*dY;
            if( q < rSquare )
            {
                    bd.setPixel( i, j, color );
            }       
        }
    }

    // create a bitmap based on the data, and add it as a child to the UIComponent to be displayed
    // (if you try to add it directly to the Application, you get a runtime error)
    var bt:Bitmap = new Bitmap(bd);
    component.addChild(bt);    
}
...