Как мне расположить и определить размер выходных данных в панели манипуляции в Mathematica?

Question

Следующий код позволяет вам играть со значениями в мосте Уитстона. Вывод отображается справа от ползунков. Как сделать так, чтобы панель вывода ( expr ) появлялась где-то еще и как установить фиксированный размер? (Я могу найти только варианты для управления размером и положением элементов управления, но не для вывода в документах Manipulate.)

Manipulate[
 Evaluate[(10^Rx/(10^R3 + 10^Rx) - 10^R2/(10^R1 + 10^R2))*Vin] "V",
 {{R1, 5}, 1, 6, 0.01},
 Pane["R1  = " Dynamic[Round[10^R1] "\[CapitalOmega]"], 
  ImageMargins -> {{2.5, 0}, {3, 0}}], {{R2, 5}, 1, 6, 0.01},
 Pane["R2  = " Dynamic[Round[10^R2] "\[CapitalOmega]"], 
  ImageMargins -> {{2.5, 0}, {3, 0}}], {{R3, 5}, 1, 6, 0.01},
 Pane["R3  = " Dynamic[Round[10^R3] "\[CapitalOmega]"], 
  ImageMargins -> {{2.5, 0}, {3, 0}}],
 {{Rx, 5}, 1, 6, 0.01},
 Pane["Rx  = " Dynamic[Round[10^Rx] "\[CapitalOmega]"], 
  ImageMargins -> {{2.5, 0}, {3, 0}}],
 {{Vin, 2.5}, 0, VMax, Appearance -> "Open"}]

Answer 1

Ну, если вы можете расположить элементы управления относительно блока контента, то вы также позиционируете блок контента относительно элементов управления, не так ли?

Итак, ControlPlacement должен позаботиться о положении вашего ящика, а размещение в Pane позаботится о его размере (с ImageSize, хотя кажется, что он берет свой минимальный размер из контрольных размеров ).

VMax = 12;
Manipulate[
 Pane[ToString[(10^Rx/(10^R3 + 10^Rx) - 10^R2/(10^R1 + 10^R2))*Vin] <> 
   "V", ImageSize -> {500, 20}], {{R1, 5}, 1, 6, 0.01}, 
 Pane["R1  = " Dynamic[Round[10^R1] "\[CapitalOmega]"], 
  ImageMargins -> {{2.5, 0}, {3, 0}}], {{R2, 5}, 1, 6, 0.01}, 
 Pane["R2  = " Dynamic[Round[10^R2] "\[CapitalOmega]"], 
  ImageMargins -> {{2.5, 0}, {3, 0}}], {{R3, 5}, 1, 6, 0.01}, 
 Pane["R3  = " Dynamic[Round[10^R3] "\[CapitalOmega]"], 
  ImageMargins -> {{2.5, 0}, {3, 0}}], {{Rx, 5}, 1, 6, 0.01}, 
 Pane["Rx  = " Dynamic[Round[10^Rx] "\[CapitalOmega]"], 
  ImageMargins -> {{2.5, 0}, {3, 0}}], {{Vin, 2.5}, 0, VMax, 
  Appearance -> "Open"}, ControlPlacement -> Bottom]

РЕДАКТИРОВАТЬ Изменено [CapitalOmega] на \[CapitalOmega]. Спасибо Велисарию.

Новая картинка. Спасибо, волшебник.