Как создать объект JS с методами и конструктором в ClojureScript

Question

Представьте себе, что задача состоит в том, чтобы создать некоторую служебную библиотеку в clojurescript, чтобы ее можно было использовать из JS.

Например, допустим, я хочу получить эквивалент:

    var Foo = function(a, b, c){
      this.a = a;
      this.b = b;
      this.c = c;    
    }

    Foo.prototype.bar = function(x){
      return this.a + this.b + this.c + x;
    }

    var x = new Foo(1,2,3);

    x.bar(3);           //  >>  9    

Один из способов добиться этого, с которым я пришел, это:

    (deftype Foo [a b c])   

    (set! (.bar (.prototype Foo)) 
      (fn [x] 
        (this-as this
          (+ (.a this) (.b this) (.c this) x))))

    (def x (Foo. 1 2 3))

    (.bar x 3)     ; >> 9

Вопрос: есть ли более элегантный / идиоматический способ вышесказанного в clojurescript?

Answer 1

Это было решено с помощью JIRA CLJS-83 путем добавления магического протокола «Объект» к deftype:

(deftype Foo [a b c]
  Object
  (bar [this x] (+ a b c x)))
(def afoo (Foo. 1 2 3))
(.bar afoo 3) ; >> 9

Answer 2

(defprotocol IFoo
  (bar [this x]))

(deftype Foo [a b c]
  IFoo
  (bar [_ x]
    (+ a b c x)))

(def afoo (Foo. 1 2 3))
(bar afoo 3) ; >> 9

Это идиоматический способ сделать это.