Как создать набор узлов из значений - PullRequest
Новая
       17

Как создать набор узлов из значений

3 голосов
/ 23 апреля 2009

Как мы можем создать набор узлов из значений ....

У меня n номеров 1,2,3 ....... n.

Я хочу создать набор узлов 

<MYNMUMS>
<MYNUM>1</MYNUM>
<MYNUM>2</MYNUM>
<MYNUM>3</MYNUM>
<MYNUM>4</MYNUM>
....
<MYNUM>N</MYNUM>
</MYNMUMS>

Ответы [ 2 ]

8 голосов
/ 25 апреля 2009

Так просто :

XSLT 1.0 решение :

Это преобразование: 

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

    <xsl:template match="/">
     <MyNums>
       <xsl:call-template name="generateNumNodes">
         <xsl:with-param name="pStart" select="1"/>
         <xsl:with-param name="pEnd" select="10"/>
       </xsl:call-template>
     </MyNums>
    </xsl:template>

    <xsl:template name="generateNumNodes">
      <xsl:param name="pStart"/>
      <xsl:param name="pEnd"/>

      <xsl:if test="$pEnd >= $pStart">
        <xsl:variable name="vNumNodes"
           select="$pStart -$pEnd+1"/>

        <xsl:choose>
          <xsl:when test="$vNumNodes = 1">
            <MyNum><xsl:value-of select="$pStart"/></MyNum>
          </xsl:when>
          <xsl:otherwise>
            <xsl:variable name="vHalf" select=
              "floor(($pStart+$pEnd) div 2)"/>
            <xsl:call-template name="generateNumNodes">
              <xsl:with-param name="pStart" select="$pStart"/>
              <xsl:with-param name="pEnd" select="$vHalf"/>
            </xsl:call-template>

            <xsl:call-template name="generateNumNodes">
              <xsl:with-param name="pStart" select="$vHalf+1"/>
              <xsl:with-param name="pEnd" select="$pEnd"/>
            </xsl:call-template>
          </xsl:otherwise>
        </xsl:choose>
      </xsl:if>
    </xsl:template>
</xsl:stylesheet>

при применении к любому документу XML (не используется), дает желаемый результат : 

<MyNums>
   <MyNum>1</MyNum>
   <MyNum>2</MyNum>
   <MyNum>3</MyNum>
   <MyNum>4</MyNum>
   <MyNum>5</MyNum>
   <MyNum>6</MyNum>
   <MyNum>7</MyNum>
   <MyNum>8</MyNum>
   <MyNum>9</MyNum>
   <MyNum>10</MyNum>
</MyNums>

Обратите внимание на следующее :

  1. Шаблон generateNumNodes вызывает себя рекурсивно .

  2. Эта рекурсия - это и время ( O(N) ), и пространство ( O(log2(N)) ), эффективное и практически переполняет стек - здесь нет SO!

  3. Вышеуказанная функция достигается путем реализации рекурсии в формате DVC (DiVide and Conquer) .

  4. В отличие от tail-recursion он будет успешно выполнен на любом совместимом процессоре XSLT .

  5. Максимальная глубина рекурсии, необходимая для генерации 1000000 (один миллион чисел), составляет всего 19 .

Решение XSLT 2.0 :

Еще более элементарно, без рекурсии , только с использованием оператора XPath 2.0 to : 

<xsl:stylesheet version="2.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
>
     <xsl:output omit-xml-declaration="yes" indent="yes"/>

    <xsl:template match="/">
        <MyNums>
          <xsl:for-each select="1 to 10">
            <MyNums>
              <xsl:sequence select="."/>
            </MyNums>
          </xsl:for-each>
        </MyNums>
    </xsl:template>
</xsl:stylesheet>
0 голосов
/ 23 апреля 2009

XSLT - это язык трансформации. Обычно он используется, когда у вас уже есть данные в форме документа XML, которые вы хотите преобразовать в другой документ (который может быть или не быть в формате XML).

Для задачи запуска с «необработанных» данных и создания представления XML XSLT не подходит.

Я предлагаю вам изучить различные языки, чтобы решить эту проблему.

...