Сортировать AS3 XMLList в порядке документов - PullRequest
Новая
       12

Сортировать AS3 XMLList в порядке документов

0 голосов
/ 22 сентября 2011

В ActionScript 3 есть способ сортировки узлов (экземпляров типа XML) в XMLList в порядке документов (как определено в спецификации XDM ; "Неформально, порядок документов - это порядок в какие узлы появляются в сериализации XML документа ")? Альтернативно, есть ли способ сравнить положение документа двух узлов?

Вот небольшой пример того, что я имею в виду. В реальном случае список создается гораздо более сложным процессом и может иметь сотни узлов. 

var x:XML = <a><b/><b/></a>;
var b0:XML = x.b[0];
var b1:XML = x.b[1];
var l:XMLList = new XMLList();
l += b1;
l += b0;
var sl:XMLList = documentSortFunction(l);
assertTrue(sl[0] === b0);

Я не уверен, что у меня есть большая надежда здесь, так как кажется, что ECMA-357 (E4X) на самом деле не имеет концепции документа, а тем более порядка документов.

1 Ответ

0 голосов
/ 28 сентября 2011

Ну, вот набросок ответа, который я придумал. Это еще не было проверено, но я решил записать его, прежде чем забуду.

Идея состоит в том, чтобы реализовать функцию для генерации строки для узла, чтобы порядок строк был таким же, как порядок узлов. 

protected function generateSortID(n:XML):String
{
    var ret:String = '';
    while (n != null && n.childIndex() > -1)
    {
        var s:String = '' + n.childIndex();
        ret = '0000000'.substring(s.length) + s + '!' + ret;
        n = n.parent();
    }
    return ret;
}

protected function compareNodePair(a:Array, b:Array):int
{
    var ai:String = a[0];
    var bi:String = b[0];
    if (ai < bi)
        return -1;
    else if (ai > bi)
        return 1;
    else
        return 0;
}

// all nodes in input list must be part of the same document.
protected function documentSortFunction(l:XMLList):XMLList
{
    var augArr:Array = [];
    for (var il:String in l)
        augArr.push([generateSortID(l[il]), l[il]]);
    augArr.sort(compareNodePair);
    var ret:XMLList = new XMLList();
    for (var ia:String in augArr)
        ret += augArr[ia][1];
    return ret;
}
...