Как сделать скриншот активного окна в Delphi? - PullRequest
Новая
       16

Как сделать скриншот активного окна в Delphi?

10 голосов
/ 19 марта 2009

Для полных снимков экрана я использую этот код: 

form1.Hide;
sleep(500);
bmp := TBitmap.Create;
bmp.Height := Screen.Height;
bmp.Width := Screen.Width;
DCDesk := GetWindowDC(GetDesktopWindow);
BitBlt(bmp.Canvas.Handle, 0, 0, Screen.Width, Screen.Height, DCDesk, 0, 0, SRCCOPY);
form1.Show ;
FileName := 'Screenshot_'+FormatDateTime('mm-dd-yyyy-hhnnss',now());
bmp.SaveToFile(Format('C:\Screenshots\%s.bmp', [FileName]));
ReleaseDC(GetDesktopWindow, DCDesk);
bmp.Free;

Как я могу преобразовать это, чтобы сделать скриншот только активного окна.

Ответы [ 8 ]

17 голосов
/ 19 марта 2009
  1. Прежде всего вы должны получить правильное окно. Как уже отмечал острый зуб, вы должны использовать GetForegroundWindow вместо GetDesktopWindow. Вы сделали это правильно в вашей улучшенной версии .
  2. Но тогда вам нужно изменить размер вашего растрового изображения до фактического размера DC / Window. Вы еще этого не сделали.
  3. А затем убедитесь, что вы не захватили какое-то полноэкранное окно!

Когда я выполнил ваш код, моя Delphi IDE была захвачена и, по умолчанию, в полноэкранном режиме, создала иллюзию полноэкранного скриншота. (Хотя ваш код в основном правильный)

Учитывая вышеописанные шаги, мне удалось создать скриншот из одного окна с вашим кодом.

Просто подсказка: вы можете GetDC вместо GetWindowDC, если вас интересует только область клиента. (Без оконных рамок)

РЕДАКТИРОВАТЬ: Вот что я сделал с вашим кодом:

Вы не должны использовать этот код! Посмотрите на улучшенную версию ниже. 

procedure TForm1.Button1Click(Sender: TObject);
const
  FullWindow = True; // Set to false if you only want the client area.
var
  hWin: HWND;
  dc: HDC;
  bmp: TBitmap;
  FileName: string;
  r: TRect;
  w: Integer;
  h: Integer;
begin
  form1.Hide;
  sleep(500);
  hWin := GetForegroundWindow;

  if FullWindow then
  begin
    GetWindowRect(hWin,r);
    dc := GetWindowDC(hWin) ;
  end else
  begin
    Windows.GetClientRect(hWin, r);
    dc := GetDC(hWin) ;
  end;

  w := r.Right - r.Left;
  h := r.Bottom - r.Top;

  bmp := TBitmap.Create;
  bmp.Height := h;
  bmp.Width := w;
  BitBlt(bmp.Canvas.Handle, 0, 0, w, h, DC, 0, 0, SRCCOPY);
  form1.Show ;
  FileName := 'Screenshot_'+FormatDateTime('mm-dd-yyyy-hhnnss',now());
  bmp.SaveToFile(Format('C:\Screenshots\%s.bmp', [FileName]));
  ReleaseDC(hwin, DC);
  bmp.Free;
end;

РЕДАКТИРОВАТЬ 2: В соответствии с просьбой я добавляю лучшую версию кода, но я сохраняю старую версию в качестве справки. Вы должны серьезно рассмотреть возможность использования этого вместо вашего исходного кода. Он будет вести себя намного лучше в случае ошибок. (Ресурсы очищены, ваша форма снова будет видна, ...) 

procedure TForm1.Button1Click(Sender: TObject);
const
  FullWindow = True; // Set to false if you only want the client area.
var
  Win: HWND;
  DC: HDC;
  Bmp: TBitmap;
  FileName: string;
  WinRect: TRect;
  Width: Integer;
  Height: Integer;
begin
  Form1.Hide;
  try
    Application.ProcessMessages; // Was Sleep(500);
    Win := GetForegroundWindow;

    if FullWindow then
    begin
      GetWindowRect(Win, WinRect);
      DC := GetWindowDC(Win);
    end else
    begin
      Windows.GetClientRect(Win, WinRect);
      DC := GetDC(Win);
    end;
    try
      Width := WinRect.Right - WinRect.Left;
      Height := WinRect.Bottom - WinRect.Top;

      Bmp := TBitmap.Create;
      try
        Bmp.Height := Height;
        Bmp.Width := Width;
        BitBlt(Bmp.Canvas.Handle, 0, 0, Width, Height, DC, 0, 0, SRCCOPY);
        FileName := 'Screenshot_' + 
          FormatDateTime('mm-dd-yyyy-hhnnss', Now());
        Bmp.SaveToFile(Format('C:\Screenshots\%s.bmp', [FileName]));
      finally
        Bmp.Free;
      end;
    finally
      ReleaseDC(Win, DC);
    end;
  finally
    Form1.Show;
  end;
end;
16 голосов
/ 19 марта 2009

Ваш код может быть намного проще. Когда вы решите, какую форму вы хотите сохранить, попробуйте использовать код, который я использую: 

procedure SaveFormBitmapToBMPFile( AForm : TCustomForm; AFileName : string = '' );
// Copies this form's bitmap to the specified file
var
  Bitmap: TBitMap;
begin
  Bitmap := AForm.GetFormImage;
  try
    Bitmap.SaveToFile( AFileName );
  finally
    Bitmap.Free;
  end;
end;
7 голосов
/ 31 марта 2009

Это объединяет все подходы, описанные до сих пор. Он также обрабатывает сценарии с несколькими мониторами.

Передайте вид скриншота, который вам нужен, и TJpegImage, и он назначит запрошенный скриншот этому изображению. 

///////////
uses
  Jpeg;

type  //define an ENUM to describe the possible screenshot types.
  TScreenShotType = (sstActiveWindow, sstActiveClientArea,
    sstPrimaryMonitor, sstDesktop);
///////////

procedure TfrmMain.GetScreenShot(shotType: TScreenShotType;
  var img: TJpegImage);
var
  w,h: integer;
  DC: HDC;
  hWin: Cardinal;
  r: TRect;
  tmpBmp: TBitmap;
begin
  hWin := 0;
  case shotType of
    sstActiveWindow:
      begin
        //only the active window
        hWin := GetForegroundWindow;
        dc := GetWindowDC(hWin);
        GetWindowRect(hWin,r);
        w := r.Right - r.Left;
        h := r.Bottom - r.Top;
      end;  //sstActiveWindow
    sstActiveClientArea:
      begin
        //only the active client area (active window minus title bars)
        hWin := GetForegroundWindow;
        dc := GetDC(hWin);
        GetWindowRect(hWin,r);
        w := r.Right - r.Left;
        h := r.Bottom - r.Top;
      end;  //sstActiveClientArea
    sstPrimaryMonitor:
      begin
        //only the primary monitor.  If 1 monitor, same as sstDesktop.
        hWin := GetDesktopWindow;
        dc := GetDC(hWin);
        w := GetDeviceCaps(DC,HORZRES);
        h := GetDeviceCaps(DC,VERTRES);
      end;  //sstPrimaryMonitor
    sstDesktop:
      begin
        //ENTIRE desktop (all monitors)
        dc := GetDC(GetDesktopWindow);
        w := Screen.DesktopWidth;
        h := Screen.DesktopHeight;
      end;  //sstDesktop
    else begin
      Exit;
    end;  //case else
  end;  //case

  //convert to jpg
  tmpBmp := TBitmap.Create;
  try
    tmpBmp.Width := w;
    tmpBmp.Height := h;
    BitBlt(tmpBmp.Canvas.Handle,0,0,tmpBmp.Width,
      tmpBmp.Height,DC,0,0,SRCCOPY);
    img.Assign(tmpBmp);
  finally
    ReleaseDC(hWin,DC);
    FreeAndNil(tmpBmp);
  end;  //try-finally
end;
5 голосов
/ 19 марта 2009

JCL снова приходит на помощь .. 

    hwnd := GetForegroundWindow;
    Windows.GetClientRect(hwnd, r);
    JclGraphics.ScreenShot(theBitmap, 0, 0, r.Right - r.Left, r.Bottom - r.Top, hwnd);

    // use theBitmap...
3 голосов
/ 31 марта 2009

Никто здесь не опубликовал хороший ответ. Решение, которое до сих пор предлагалось, заключалось в том, чтобы сделать снимок экрана, который «обрезается» в позиции целевого окна. Что если это окно находится за другим и в данный момент не отображается операционной системой? Вот почему вам нужно использовать эту функцию, представленную в Windows XP.

После быстрого Google, вот пример кода: http://delphi.about.com/od/delphitips2008/qt/print_window.htm

1 голос
/ 04 мая 2017

Спасибо за это полезное представление. Я подумал, что мог бы превратить предложенный код в единицу, чтобы использовать ее во всем приложении, вот код, который я запускаю на DX10.2 Tokyo. Обратите внимание на пример, следите за утечками памяти. 

unit ScreenCapture;
interface

uses Windows, Vcl.Controls, Vcl.StdCtrls, VCL.Graphics,VCL.Imaging.JPEG, VCL.Forms;

function getScreenCapture(  FullWindow: Boolean = True ) : TBitmap;

implementation

function getScreenCapture( FullWindow: Boolean ) : TBitmap;
var
  Win: HWND;
  DC: HDC;

  WinRect: TRect;
  Width: Integer;
  Height: Integer;

begin
  Result := TBitmap.Create;

  //Application.ProcessMessages; // Was Sleep(500);
  Win := GetForegroundWindow;

  if FullWindow then
  begin
    GetWindowRect(Win, WinRect);
    DC := GetWindowDC(Win);
  end
    else
  begin
    Windows.GetClientRect(Win, WinRect);
    DC := GetDC(Win);
  end;
  try
    Width := WinRect.Right - WinRect.Left;
    Height := WinRect.Bottom - WinRect.Top;

    Result.Height := Height;
    Result.Width := Width;
    BitBlt(Result.Canvas.Handle, 0, 0, Width, Height, DC, 0, 0, SRCCOPY);
  finally
    ReleaseDC(Win, DC);
  end;
end;
end.

Пример: 

//Any event or button click, screenCapture is a TBitmap
screenCapture := getScreenCapture();
try
  //Do some things with screen capture
  Image1.Picture.Graphic := screenCapture; 
finally 
  screenCapture.Free;
end;
0 голосов
/ 03 июня 2012

Самая короткая версия кода Брайана Фроста:

Screen.ActiveForm.GetFormImage.SaveToFile(Screen.ActiveForm.Caption+'.bmp');

Всего одна строка кода (снимок экрана активного окна в приложении MDI).

0 голосов
/ 19 марта 2009

Используйте GetForegroundWindow () вместо GetDesktopWindow ().

Вам нужно сохранить дескриптор, который возвращает GetForegroundWindow (), и передать сохраненное значение в ReleaseDC () - чтобы быть уверенным, что GetWindowDC () и ReleaseDC () вызываются точно для одного и того же окна в случае изменения активного окна между вызовами.

...